dlsoda Subroutine

public subroutine dlsoda(f, Neq, Y, T, Tout, Itol, Rtol, Atol, Itask, Istate, Iopt, Rwork, Lrw, Iwork, Liw, jac, Jt)

Synopsis

DLSODA solves the initial value problem for stiff or nonstiff systems of first order ODEs of the form

     dy/dt = f(t,y),  or, in component form,
     dy(i)/dt = f(i) = f(i,t,y(1),y(2),...,y(NEQ)) (i = 1,...,NEQ).

with automatic method switching for stiff and nonstiff problems.

This a variant version of the DLSODE package. It switches automatically between stiff and nonstiff methods. This means that the user does not have to determine whether the problem is stiff or not, and the solver will automatically choose the appropriate method. It always starts with the nonstiff method.

Summary of Usage

Communication between the user and the DLSODA package, for normal situations, is summarized here. This summary describes only a subset of the full set of options available. See the full description for details, including alternative treatment of the Jacobian matrix, optional inputs and outputs, nonstandard options, and instructions for special situations. See also the example problem (with program and output) following this summary.

Section A.

First provide a subroutine of the form:

               SUBROUTINE F (NEQ, T, Y, YDOT)
               DOUBLE PRECISION T, Y(*), YDOT(*)

which supplies the vector function f by loading YDOT(i) with f(i).

Section B.

Write a main program which calls Subroutine DLSODA once for each point at which answers are desired. This should also provide for possible use of logical unit 6 for output of error messages by DLSODA. On the first call to DLSODA, supply arguments as follows:

F

name of subroutine for right-hand side vector f. This name must be declared External in calling program.

NEQ

number of first order ODEs.

Y

array of initial values, of length NEQ.

T

the initial value of the independent variable.

TOUT

first point where output is desired (.ne. T).

ITOL

1 or 2 according as ATOL (below) is a single or multi-value array.

RTOL

relative tolerance parameter (scalar).

ATOL

absolute tolerance parameter (array). the estimated local error in y(i) will be controlled so as to be less than

        EWT(i) = RTOL*ABS(Y(i)) + ATOL     if ITOL = 1, or
        EWT(i) = RTOL*ABS(Y(i)) + ATOL(i)  if ITOL = 2.

Thus the local error test passes if, in each component, either the absolute error is less than ATOL (or ATOL(i)), or the relative error is less than RTOL.

Use RTOL = 0.0 for pure absolute error control, and use ATOL = 0.0 (or ATOL(i) = 0.0) for pure relative error control. Caution: actual (global) errors may exceed these local tolerances, so choose them conservatively.

ITASK

1 for normal computation of output values of y at t = TOUT.

ISTATE

integer flag (input and output). Set ISTATE = 1.

IOPT

0 to indicate no optional inputs used.

RWORK

real work array of length at least:

         22 + NEQ * MAX(16, NEQ + 9).

See also Section E below.

LRW

declared length of RWORK (in user’s dimension).

IWORK

integer work array of length at least 20 + NEQ.

LIW

declared length of IWORK (in user’s dimension).

JAC

name of subroutine for Jacobian matrix. Use a dummy name. See also Section E below.

JT

Jacobian type indicator. Set JT = 2. See also Section E below. Note that the main program must declare arrays Y, RWORK, IWORK, and possibly ATOL.

Section C.

The output from the first call (or any call) is:

Y

array of computed values of y(t) vector.

T

corresponding value of independent variable (normally TOUT).

ISTATE

Status values are returned in ISTATE:

Section D.

To continue the integration after a successful return, simply reset TOUT and call DLSODA again. No other parameters need be reset.

Section E.

Note: If and when DLSODA regards the problem as stiff, and switches methods accordingly, it must make use of the NEQ by NEQ Jacobian matrix, J = df/dy. For the sake of simplicity, the inputs to DLSODA recommended in Section B above cause DLSODA to treat J as a full matrix, and to approximate it internally by difference quotients. Alternatively, J can be treated as a band matrix (with great potential reduction in the size of the RWORK array). Also, in either the full or banded case, the user can supply J in closed form, with a routine whose name is passed as the JAC argument. These alternatives are described in the paragraphs on RWORK, JAC, and JT in the full description of the call sequence below.

Example Problem.

The following is a simple example problem, with the coding needed for its solution by DLSODA. The problem is from chemical kinetics, and consists of the following three rate equations:

     dy1/dt = -.04*y1 + 1.e4*y2*y3
     dy2/dt = .04*y1 - 1.e4*y2*y3 - 3.e7*y2**2
     dy3/dt = 3.e7*y2**2

on the interval from t = 0.0 to t = 4.e10, with initial conditions

     y1 = 1.0, y2 = y3 = 0.  The problem is stiff.

The following coding solves this problem with DLSODA, printing results at t = .4, 4., …, 4.e10. It uses ITOL = 2, and ATOL much smaller for y2 than y1 or y3 because y2 has much smaller values. At the end of the run, statistical quantities of interest are printed (see optional outputs in the full description below).

 program dlsoda_ex
 use m_odepack
 implicit none
 external fex
 external jdum
 integer,parameter            ::  dp=kind(0.0d0)
 real(kind=dp),dimension(3)   ::  atol,y
 integer                      ::  iopt,iout,istate,itask
 integer                      ::  itol,jt,liw,lrw,neq
 integer,dimension(23)        ::  iwork
 real(kind=dp)                ::  rtol,t,tout
 real(kind=dp),dimension(70)  ::  rwork

    neq = 3
    y(1) = 1.
    y(2) = 0.
    y(3) = 0.
    t = 0.
    tout = .4
    itol = 2
    rtol = 1.D-4
    atol(1) = 1.D-6
    atol(2) = 1.D-10
    atol(3) = 1.D-6
    itask = 1
    istate = 1
    iopt = 0
    lrw = 70
    liw = 23
    jt = 2
    do iout = 1,12
       call dlsoda(fex,[neq],y,t,tout,itol,[rtol],atol,itask,istate,iopt,&
                 & rwork,lrw,iwork,liw,jdum,jt)
       write (6,99010) t,y(1),y(2),y(3)
       99010 format (' At t =',d12.4,'   Y =',3D14.6)
       if ( istate<0 ) then
          write (6,99020) istate
          99020 format (///' Error halt.. ISTATE =',i3)
          stop 1
       else
          tout = tout*10.
       endif
    enddo
    write (6,99030) iwork(11),iwork(12),iwork(13),iwork(19),        &
                  & rwork(15)
    99030 format (/' No. steps =',i4,'  No. f-s =',i4,'  No. J-s =',      &
                 &i4/' Method last used =',i2,'   Last switch was at t =',&
                & d12.4)

 end program dlsoda_ex

 subroutine jdum()
 implicit none
 end subroutine jdum

 subroutine fex(Neq,T,Y,Ydot)
 implicit none
 integer,parameter :: dp=kind(0.0d0)

 integer                                   ::  Neq
 real(kind=dp)                             ::  T
 real(kind=dp),intent(in),dimension(3)     ::  Y
 real(kind=dp),intent(inout),dimension(3)  ::  Ydot

    Ydot(1) = -.04*Y(1) + 1.D4*Y(2)*Y(3)
    Ydot(3) = 3.D7*Y(2)*Y(2)
    Ydot(2) = -Ydot(1) - Ydot(3)
 end subroutine fex

The output of this program (on a CDC-7600 in single precision) is as follows:

   At t =  4.0000e-01   y =  9.851712e-01  3.386380e-05  1.479493e-02
   At t =  4.0000e+00   Y =  9.055333e-01  2.240655e-05  9.444430e-02
   At t =  4.0000e+01   Y =  7.158403e-01  9.186334e-06  2.841505e-01
   At t =  4.0000e+02   Y =  4.505250e-01  3.222964e-06  5.494717e-01
   At t =  4.0000e+03   Y =  1.831975e-01  8.941774e-07  8.168016e-01
   At t =  4.0000e+04   Y =  3.898730e-02  1.621940e-07  9.610125e-01
   At t =  4.0000e+05   Y =  4.936363e-03  1.984221e-08  9.950636e-01
   At t =  4.0000e+06   Y =  5.161831e-04  2.065786e-09  9.994838e-01
   At t =  4.0000e+07   Y =  5.179817e-05  2.072032e-10  9.999482e-01
   At t =  4.0000e+08   Y =  5.283401e-06  2.113371e-11  9.999947e-01
   At t =  4.0000e+09   Y =  4.659031e-07  1.863613e-12  9.999995e-01
   At t =  4.0000e+10   Y =  1.404280e-08  5.617126e-14  1.000000e+00

   No. steps = 361  No. f-s = 693  No. J-s =  64
   Method last used = 2   Last switch was at t =  6.0092e-03

Full description of user interface to DLSODA.

The user interface to DLSODA consists of the following parts.

1. The call sequence to Subroutine DLSODA, which is a driver routine for the solver. This includes descriptions of both the call sequence arguments and of user-supplied routines. following these descriptions is a description of optional inputs available through the call sequence, and then a description of optional outputs (in the work arrays).

2. Descriptions of other routines in the DLSODA package that may be (optionally) called by the user. These provide the ability to alter error message handling, save and restore the internal Common, and obtain specified derivatives of the solution y(t).

3. Descriptions of Common blocks to be declared in overlay or similar environments, or to be saved when doing an interrupt of the problem and continued solution later.

4. Description of a subroutine in the DLSODA package, which the user may replace with his/her own version, if desired. this relates to the measurement of errors.

Part 1. Call Sequence.

The call sequence parameters used for input only are

 F, NEQ, TOUT, ITOL, RTOL, ATOL, ITASK, IOPT, LRW, LIW, JAC, JT,

and those used for both input and output are

 Y, T, ISTATE.

The work arrays RWORK and IWORK are also used for conditional and optional inputs and optional outputs. (The term output here refers to the return from Subroutine DLSODA to the user’s calling program.)

The legality of input parameters will be thoroughly checked on the initial call for the problem, but not checked thereafter unless a change in input parameters is flagged by ISTATE = 3 on input.

The descriptions of the call arguments are as follows:

F

the name of the user-supplied subroutine defining the ODE system. The system must be put in the first-order form dy/dt = f(t,y), where f is a vector-valued function of the scalar t and the vector y. Subroutine F is to compute the function f. It is to have the form

      SUBROUTINE F (NEQ, T, Y, YDOT)
      DOUBLE PRECISION T, Y(*), YDOT(*)

where NEQ, T, and Y are input, and the array YDOT = f(t,y) is output. Y and YDOT are arrays of length NEQ. Subroutine F should not alter Y(1),…,Y(NEQ). F must be declared External in the calling program.

Subroutine F may access user-defined quantities in NEQ(2),… and/or in Y(NEQ(1)+1),… if NEQ is an array (dimensioned in F) and/or Y has length exceeding NEQ(1). See the descriptions of NEQ and Y below.

If quantities computed in the F routine are needed externally to DLSODA, an extra call to F should be made for this purpose, for consistent and accurate results. If only the derivative dy/dt is needed, use DINTDY instead.

NEQ

the size of the ODE system (number of first order ordinary differential equations). Used only for input. NEQ may be decreased, but not increased, during the problem. If NEQ is decreased (with ISTATE = 3 on input), the remaining components of Y should be left undisturbed, if these are to be accessed in F and/or JAC.

Normally, NEQ is a single value, and it is generally referred to as a scalar in this user interface description. However, NEQ must be an array, with NEQ(1) set to the system size. (The DLSODA package accesses only NEQ(1).) In either case, this parameter is passed as the NEQ argument in all calls to F and JAC. Hence, if it is an multi-value array, locations NEQ(2),… may be used to store other integer data and pass it to F and/or JAC. Subroutines F and/or JAC must include NEQ in a Dimension statement in that case.

Y

a real array for the vector of dependent variables, of length NEQ or more. Used for both input and output on the first call (ISTATE = 1), and only for output on other calls. On the first call, Y must contain the vector of initial values. On output, Y contains the computed solution vector, evaluated at T. If desired, the Y array may be used for other purposes between calls to the solver.

This array is passed as the Y argument in all calls to F and JAC. Hence its length may exceed NEQ, and locations Y(NEQ+1),… may be used to store other real data and pass it to F and/or JAC. (The DLSODA package accesses only Y(1),…,Y(NEQ).)

T

the independent variable. On input, T is used only on the first call, as the initial point of the integration. on output, after each call, T is the value at which a computed solution Y is evaluated (usually the same as TOUT). on an error return, T is the farthest point reached.

TOUT

the next value of t at which a computed solution is desired. Used only for input.

When starting the problem (ISTATE = 1), TOUT may be equal to T for one call, then should .ne. T for the next call. For the initial t, an input value of TOUT .ne. T is used in order to determine the direction of the integration (i.e. the algebraic sign of the step sizes) and the rough scale of the problem. Integration in either direction (forward or backward in t) is permitted.

If ITASK = 2 or 5 (one-step modes), TOUT is ignored after the first call (i.e. the first call with TOUT .ne. T). Otherwise, TOUT is required on every call.

If ITASK = 1, 3, or 4, the values of TOUT need not be monotone, but a value of TOUT which backs up is limited to the current internal T interval, whose endpoints are TCUR - HU and TCUR (see optional outputs, below, for TCUR and HU).

ITOL

an indicator for the type of error control. See description below under ATOL. Used only for input.

RTOL

a relative error tolerance parameter, an array of length NEQ. See description below under ATOL. Input only.

ATOL

an absolute error tolerance parameter, an array of length NEQ. Input only.

The input parameters ITOL, RTOL, and ATOL determine the error control performed by the solver. The solver will control the vector E = (E(i)) of estimated local errors in y, according to an inequality of the form

  max-norm of ( E(i)/EWT(i) )   .le.   1,

where EWT = (EWT(i)) is a vector of positive error weights. The values of RTOL and ATOL should all be non-negative. The following table gives the types (single/mult-value array) of RTOL and ATOL, and the corresponding form of EWT(i).

Even when these parameters are a single value, it needs to be an array in the user’s calling program, or passed as a temporary array (ie. use “[NEQ]” on the call if NEQ is a scalar).

If none of the above choices (with ITOL, RTOL, and ATOL fixed throughout the problem) is suitable, more general error controls can be obtained by substituting a user-supplied routine for the setting of EWT. See Part 4 below.

If global errors are to be estimated by making a repeated run on the same problem with smaller tolerances, then all components of RTOL and ATOL (i.e. of EWT) should be scaled down uniformly.

ITASK

an index specifying the task to be performed. Input only. ITASK has the following values and meanings.

Note: If ITASK = 4 or 5 and the solver reaches TCRIT (within roundoff), it will return T = TCRIT (exactly) to indicate this (unless ITASK = 4 and TOUT comes before TCRIT, in which case answers at t = TOUT are returned first).

ISTATE

an index used for input and output to specify the the state of the calculation.

On input, the values of ISTATE are as follows:

Note: A preliminary call with TOUT = T is not counted as a first call here, as no initialization or checking of input is done. (Such a call is sometimes useful for the purpose of outputting the initial conditions.) Thus the first call for which TOUT .ne. T requires ISTATE = 1 on input.

On output, ISTATE has the following values and meanings.

Note: Since the normal output value of ISTATE is 2, it does not need to be reset for normal continuation. Also, since a negative input value of ISTATE will be regarded as illegal, a negative output value requires the user to change it, and possibly other inputs, before calling the solver again.

IOPT

an integer flag to specify whether or not any optional inputs are being used on this call. Input only. The optional inputs are listed separately below. IOPT = 0 means no optional inputs are being used. default values will be used in all cases. IOPT = 1 means one or more optional inputs are being used.

RWORK

a real array (double precision) for work space, and (in the first 20 words) for conditional and optional inputs and optional outputs.

As DLSODA switches automatically between stiff and nonstiff methods, the required length of RWORK can change during the problem. Thus the RWORK array passed to DLSODA can either have a static (fixed) length large enough for both methods, or have a dynamic (changing) length altered by the calling program in response to output from DLSODA.

Fixed Length Case

   If the RWORK length is to be fixed, it should be at least
        MAX (LRN, LRS),
   where LRN and LRS are the RWORK lengths required when the
   current method is nonstiff or stiff, respectively.

   The separate RWORK length requirements LRN and LRS are
   as follows:
   IF NEQ is constant and the maximum method orders have
   their default values, then
      LRN = 20 + 16*NEQ,
      LRS = 22 + 9*NEQ + NEQ**2           if JT = 1 or 2,
      LRS = 22 + 10*NEQ + (2*ML+MU)*NEQ   if JT = 4 or 5.
   Under any other conditions, LRN and LRS are given by:
      LRN = 20 + NYH*(MXORDN+1) + 3*NEQ,
      LRS = 20 + NYH*(MXORDS+1) + 3*NEQ + LMAT,
   where
      NYH    = the initial value of NEQ,
      MXORDN = 12, unless a smaller value is given as an
               optional input,
      MXORDS = 5, unless a smaller value is given as an
               optional input,
      LMAT   = length of matrix work space:
      LMAT   = NEQ**2 + 2              if JT = 1 or 2,
      LMAT   = (2*ML + MU + 1)*NEQ + 2 if JT = 4 or 5.

Dynamic Length Case

If the length of RWORK is to be dynamic, then it should be at least LRN or LRS, as defined above, depending on the current method.

Initially, it must be at least LRN (since DLSODA starts with the nonstiff method).

On any return from DLSODA, the optional output MCUR indicates the current method. If MCUR differs from the value it had on the previous return, or if there has only been one call to DLSODA and MCUR is now 2, then DLSODA has switched methods during the last call, and the length of RWORK should be reset (to LRN if MCUR = 1, or to LRS if MCUR = 2). (An increase in the RWORK length is required if DLSODA returned ISTATE = -7, but not otherwise.)

After resetting the length, call DLSODA with ISTATE = 3 to signal that change.

LRW

the length of the array RWORK, as declared by the user. (This will be checked by the solver.)

IWORK

an integer array for work space. As DLSODA switches automatically between stiff and nonstiff methods, the required length of IWORK can change during problem, between LIS = 20 + NEQ and LIN = 20, respectively. Thus the IWORK array passed to DLSODA can either have a fixed length of at least 20 + NEQ, or have a dynamic length of at least LIN or LIS, depending on the current method. The comments on dynamic length under RWORK above apply here. Initially, this length need only be at least LIN = 20 .

The first few words of IWORK are used for conditional and optional inputs and optional outputs.

The following 2 words in IWORK are conditional inputs:

   IWORK(1) = ML
   IWORK(2) = MU

These are the lower and upper half-bandwidths, respectively, of the banded Jacobian, excluding the main diagonal. The band is defined by the matrix locations (i,j) with i-ML .le. j .le. i+MU. ML and MU must satisfy 0 .le. ML,MU .le. NEQ-1. These are required if JT is 4 or 5, and ignored otherwise. ML and MU may in fact be the band parameters for a matrix to which df/dy is only approximately equal.

LIW

the length of the array IWORK, as declared by the user. (This will be checked by the solver.)

Note: The base addresses of the work arrays must not be altered between calls to DLSODA for the same problem. The contents of the work arrays must not be altered between calls, except possibly for the conditional and optional inputs, and except for the last 3*NEQ words of RWORK. The latter space is used for internal scratch space, and so is available for use by the user outside DLSODA between calls, if desired (but not for use by F or JAC).

JAC

the name of the user-supplied routine to compute the Jacobian matrix, df/dy, if JT = 1 or 4. The JAC routine is optional, but if the problem is expected to be stiff much of the time, you are encouraged to supply JAC, for the sake of efficiency. (Alternatively, set JT = 2 or 5 to have DLSODA compute df/dy internally by difference quotients.) If and when DLSODA uses df/dy, it treats this NEQ by NEQ matrix either as full (JT = 1 or 2), or as banded (JT = 4 or 5) with half-bandwidths ML and MU (discussed under IWORK above). In either case, if JT = 1 or 4, the JAC routine must compute df/dy as a function of the scalar t and the vector y. It is to have the form

     SUBROUTINE JAC (NEQ, T, Y, ML, MU, PD, NROWPD)
     DOUBLE PRECISION T, Y(*), PD(NROWPD,*)

where NEQ, T, Y, ML, MU, and NROWPD are input and the array PD is to be loaded with partial derivatives (elements of the Jacobian matrix) on output. PD must be given a first dimension of NROWPD. T and Y have the same meaning as in Subroutine F.

In the full matrix case (JT = 1), ML and MU are ignored, and the Jacobian is to be loaded into PD in columnwise manner, with df(i)/dy(j) loaded into PD(i,j).

In the band matrix case (JT = 4), the elements within the band are to be loaded into PD in columnwise manner, with diagonal lines of df/dy loaded into the rows of PD. Thus df(i)/dy(j) is to be loaded into PD(i-j+MU+1,j). ML and MU are the half-bandwidth parameters (see IWORK). The locations in PD in the two triangular areas which correspond to nonexistent matrix elements can be ignored or loaded arbitrarily, as they are overwritten by DLSODA.

JAC need not provide df/dy exactly. A crude approximation (possibly with a smaller bandwidth) will do.

In either case, PD is preset to zero by the solver, so that only the nonzero elements need be loaded by JAC. Each call to JAC is preceded by a call to F with the same arguments NEQ, T, and Y. Thus to gain some efficiency, intermediate quantities shared by both calculations may be saved in a user Common block by F and not recomputed by JAC, if desired. Also, JAC may alter the Y array, if desired. JAC must be declared External in the calling program.

Subroutine JAC may access user-defined quantities in NEQ(2),… and/or in Y(NEQ(1)+1),… if NEQ is an array (dimensioned in JAC) and/or Y has length exceeding NEQ(1). See the descriptions of NEQ and Y above.

JT

Jacobian type indicator. Used only for input. JT specifies how the Jacobian matrix df/dy will be treated, if and when DLSODA requires this matrix. JT has the following values and meanings:

If JT = 1 or 4, the user must supply a Subroutine JAC (the name is arbitrary) as described above under JAC. If JT = 2 or 5, a dummy argument can be used.

Optional Inputs.

The following is a list of the optional inputs provided for in the call sequence. (See also Part 2.) For each such input variable, this table lists its name as used in this documentation, its location in the call sequence, its meaning, and the default value. The use of any of these inputs requires IOPT = 1, and in that case all of these inputs are examined. A value of zero for any of these optional inputs will cause the default value to be used. Thus to use a subset of the optional inputs, simply preload locations 5 to 10 in RWORK and IWORK to 0.0 and 0 respectively, and then set those of interest to nonzero values.

Optional Outputs.

As optional additional output from DLSODA, the variables listed below are quantities related to the performance of DLSODA which are available to the user. These are communicated by way of the work arrays, but also have internal mnemonic names as shown. except where stated otherwise, all of these outputs are defined on any successful return from DLSODA, and on any return with ISTATE = -1, -2, -4, -5, or -6. On an illegal input return (ISTATE = -3), they will be unchanged from their existing values (if any), except possibly for TOLSF, LENRW, and LENIW. On any error return, outputs relevant to the error will be defined, as noted below.

The following two arrays are segments of the RWORK array which may also be of interest to the user as optional outputs. For each array, the table below gives its internal name, its base address in RWORK, and its description.

Part 2. Other Routines Callable.

The following are optional calls which the user may make to gain additional capabilities in conjunction with DLSODA. (The routines XSETUN and XSETF are designed to conform to the SLATEC error handling package.)

The detailed instructions for using DINTDY are as follows:

The form of the call is:

   CALL DINTDY (T, K, RWORK(21), NYH, DKY, IFLAG)

The input parameters are:

T

value of independent variable where answers are desired (normally the same as the T last returned by DLSODA). For valid results, T must lie between TCUR - HU and TCUR. (See optional outputs for TCUR and HU.)

K

integer order of the derivative desired. K must satisfy 0 .le. K .le. NQCUR, where NQCUR is the current order (see optional outputs). The capability corresponding to K = 0, i.e. computing y(T), is already provided by DLSODA directly. Since NQCUR .ge. 1, the first derivative dy/dt is always available with DINTDY.

RWORK(21)

the base address of the history array YH.

NYH

column length of YH, equal to the initial value of NEQ.

The output parameters are:

DKY

a real array of length NEQ containing the computed value of the K-th derivative of y(t).

IFLAG

integer flag, returned as 0 if K and T were legal, -1 if K was illegal, and -2 if T was illegal. On an error return, a message is also written.

Part 3. Interrupting and Continuing

If the solution of a given problem by DLSODA is to be interrupted and then later continued, such as when restarting an interrupted run or alternating between two or more problems, the user should save, following the return from the last DLSODA call prior to the interruption, the contents of the call sequence variables and state and later restore these values before the next DLSODA call for that problem. To save and restore the current state, use Subroutine DSRCMA (see Part 2 above).

Part 4. Optionally Replaceable Solver Routines.

Below is a description of a routine in the DLSODA package which relates to the measurement of errors, and can be replaced by a user-supplied version, if desired. However, since such a replacement may have a major impact on performance, it should be done only when absolutely necessary, and only with great caution. (Note: The means by which the package version of a routine is superseded by the user’s version may be system-dependent.)

DEWSET

The following subroutine is called just before each internal integration step, and sets the array of error weights, EWT, as described under ITOL/RTOL/ATOL above:

     Subroutine DEWSET (NEQ, ITOL, RTOL, ATOL, YCUR, EWT)

where NEQ, ITOL, RTOL, and ATOL are as in the DLSODA call sequence, YCUR contains the current dependent variable vector, and EWT is the array of weights set by DEWSET.

If the user supplies this subroutine, it must return in EWT(i) (i = 1,…,NEQ) a positive quantity suitable for comparing errors in y(i) to. The EWT array returned by DEWSET is passed to the DMNORM routine, and also used by DLSODA in the computation of the optional output IMXER, and the increments for difference quotient Jacobians.

In the user-supplied version of DEWSET, it may be desirable to use the current values of derivatives of y. Derivatives up to order NQ are available from the history array YH, described above under optional outputs. In DEWSET, YH is identical to the YCUR array, extended to NQ + 1 columns with a column length of NYH and scale factors of H**j/factorial(j). On the first call for the problem, given by NST = 0, NQ is 1 and H is temporarily set to 1.0. NYH is the initial value of NEQ. The quantities NQ, H, and NST can be obtained by including in DEWSET the statements:

     DOUBLE PRECISION RLS
     COMMON /DLS001/ RLS(218),ILS(37)
     NQ = ILS(33)
     NST = ILS(34)
     H = RLS(212)

Thus, for example, the current value of dy/dt can be obtained as YCUR(NYH+i)/H (i=1,…,NEQ) (and the division by H is unnecessary when NST = 0).

Pedigree:

DLSODA is derived from the Livermore Solver for Ordinary Differential Equations package ODEPACK, and is based on the 12 November 2003 version in double precision.

Authors:

    Alan C. Hindmarsh
    Center for Applied Scientific Computing, L-561
    Lawrence Livermore National Laboratory
    Livermore, CA 94551

and

    Linda R. Petzold
    Univ. of California at Santa Barbara
    Dept. of Computer Science
    Santa Barbara, CA 93106

References:

1. Alan C. Hindmarsh, ODEPACK, A Systematized Collection of ODE Solvers, in Scientific Computing, R. S. Stepleman et al. (Eds.), North-Holland, Amsterdam, 1983, pp. 55-64.
2. Linda R. Petzold, Automatic Selection of Methods for Solving Stiff and Nonstiff Systems of Ordinary Differential Equations, Siam J. Sci. Stat. Comput. 4 (1983), pp. 136-148.

Other routines in the DLSODA package.

In addition to Subroutine DLSODA, the DLSODA package includes the following subroutines and function routines:

DINTDY

computes an interpolated value of the y vector at t = TOUT.

DSTODA

is the core integrator, which does one step of the integration and the associated error control.

DCFODE

sets all method coefficients and test constants.

DPRJA

computes and preprocesses the Jacobian matrix J = df/dy and the Newton iteration matrix P = I - h*l0*J.

DSOLSY

manages solution of linear system in chord iteration.

DEWSET

sets the error weight vector EWT before each step.

DMNORM

computes the weighted max-norm of a vector.

DFNORM

computes the norm of a full matrix consistent with the weighted max-norm on vectors.

DBNORM

computes the norm of a band matrix consistent with the weighted max-norm on vectors.

DSRCMA

is a user-callable routine to save and restore the contents of the internal Common blocks.

DGEFA and DGESL

are routines from LINPACK for solving full systems of linear algebraic equations.

DGBFA and DGBSL

are routines from LINPACK for solving banded linear systems.

XERRWD, XSETUN, XSETF, and IXSAV

handle the printing of all error messages and warnings. XERRWD is machine-dependent.

Note: DMNORM, DFNORM, DBNORM, and IXSAV are function routines. All the others are subroutines.

Arguments