problem_11 Program

Uses

  • program~~problem_11~~UsesGraph program~problem_11 problem_11 iso_fortran_env iso_fortran_env program~problem_11->iso_fortran_env module~aoc_utilities aoc_utilities program~problem_11->module~aoc_utilities module~aoc_utilities->iso_fortran_env

Calls

program~~problem_11~~CallsGraph program~problem_11 problem_11 proc~clock_end aoc_utilities::clock%clock_end program~problem_11->proc~clock_end proc~clock_start aoc_utilities::clock%clock_start program~problem_11->proc~clock_start proc~go~6 problem_11::go program~problem_11->proc~go~6 interface~manhatten_distance aoc_utilities::manhatten_distance proc~go~6->interface~manhatten_distance proc~read_file_to_char_array aoc_utilities::read_file_to_char_array proc~go~6->proc~read_file_to_char_array proc~manhatten_distance_64 aoc_utilities::manhatten_distance_64 interface~manhatten_distance->proc~manhatten_distance_64 proc~number_of_lines_in_file aoc_utilities::number_of_lines_in_file proc~read_file_to_char_array->proc~number_of_lines_in_file proc~read_line aoc_utilities::read_line proc~read_file_to_char_array->proc~read_line

Functions

function go(expansion_factor)

Arguments

Type IntentOptional Attributes Name
integer(kind=ip), intent(in) :: expansion_factor

Return Value integer(kind=ip)


Source Code

program problem_11

use iso_fortran_env
use aoc_utilities

implicit none

call clk%tic()

write(*,*) '11a: ', go(2_ip)
write(*,*) '11b: ', go(1000000_ip)

call clk%toc('11')

contains

integer(ip) function go(expansion_factor)
    integer(ip),intent(in) :: expansion_factor

    integer :: i, j, nrows, ncols, n_galaxies, n, k
    character(len=1),dimension(:,:),allocatable :: array
    integer(ip),dimension(:,:),allocatable :: idists
    integer(ip),dimension(:),allocatable :: igal, jgal
    integer(ip),dimension(:,:),allocatable :: ix,iy

    ! array = read_file_to_char_array('inputs/day11_test.txt')
    array = read_file_to_char_array('inputs/day11.txt')
    nrows = size(array,1); ncols = size(array,2)
    n_galaxies = count(array=='#')

    ! track the real indices after expansion
    ix = transpose(spread([(i, i=1,ncols)], 1, nrows)) ! row indices
    iy =           spread([(i, i=1,nrows)], 1, ncols)  ! col indices
    igal = pack(ix, array=='#') ! indices of galaxies
    jgal = pack(iy, array=='#')

    ! expand the array, keeping track of the new row indices
    do i = 1, nrows ! add rows if necessary
        if (all(array(i,:)=='.')) ix(i:,:) = ix(i:,:) + expansion_factor-1 ! new row
    end do
    do j = 1, ncols ! add cols if necessary
        if (all(array(:,j)=='.')) iy(:,j:) = iy(:,j:) + expansion_factor-1 ! new column
    end do

    ! now compute all the distances:
    allocate(idists(n_galaxies, n_galaxies)); idists = 0
    do i = 1, n_galaxies
        do j = 1, n_galaxies
            if (j<=i) cycle ! only need the lower diagonal
            idists(i,j) = manhatten_distance(ix(igal(i),jgal(i)),iy(igal(i),jgal(i)),&
                                             ix(igal(j),jgal(j)),iy(igal(j),jgal(j)))
        end do
    end do

    go = sum(idists)

end function go

end program problem_11