json_value_remove Subroutine

Jacob Williams
9/9/2014
Source File

Variables

parent previous next destroy_it

Source Code

All Procedures

add_variables_to_input annotate_invalid_json compact_real_string default_comp_ucs4 default_join_ucs4 destroy_json_data escape_string get_current_line_from_file_sequential get_current_line_from_file_stream initialize_json_file integer_to_string json_add json_check_for_errors json_clear_exceptions json_count json_create_array json_create_double json_create_integer json_create_logical json_create_null json_create_object json_create_string json_destroy json_failed json_file json_file_destroy json_file_get_double json_file_get_double_vec json_file_get_integer json_file_get_integer_vec json_file_get_logical json_file_get_logical_vec json_file_get_object json_file_get_root json_file_get_string json_file_get_string_vec json_file_load json_file_load_from_string json_file_move_pointer json_file_print_1 json_file_print_2 json_file_print_to_console json_file_print_to_string json_file_update_integer json_file_update_logical json_file_update_real json_file_update_string json_file_update_string_name_ascii json_file_update_string_val_ascii json_file_variable_info json_get json_get_array json_get_array_with_path json_get_by_path json_get_child json_get_double json_get_double_vec json_get_double_vec_with_path json_get_double_with_path json_get_integer json_get_integer_vec json_get_integer_vec_with_path json_get_integer_with_path json_get_logical json_get_logical_vec json_get_logical_vec_with_path json_get_logical_with_path json_get_string json_get_string_vec json_get_string_vec_with_path json_get_string_with_path json_info json_initialize json_parse json_parse_file json_parse_string json_print json_print_1 json_print_2 json_print_error_message json_print_to_string json_remove json_remove_if_present json_throw_exception json_traverse json_update json_update_double json_update_integer json_update_logical json_update_string json_update_string_name_ascii json_update_string_val_ascii json_value_add_double json_value_add_double_vec json_value_add_integer json_value_add_integer_vec json_value_add_logical json_value_add_logical_vec json_value_add_member json_value_add_string json_value_add_string_name_ascii json_value_add_string_val_ascii json_value_add_string_vec json_value_add_string_vec_name_ascii json_value_add_string_vec_val_ascii json_value_create json_value_create_array json_value_create_double json_value_create_integer json_value_create_logical json_value_create_null json_value_create_object json_value_create_string json_value_destroy json_value_get_by_index json_value_get_by_name_chars json_value_print json_value_remove json_value_remove_if_present json_value_to_string parse_array parse_for_chars parse_number parse_object parse_string parse_value pop_char push_char read_file real_to_string rename string_to_double string_to_integer test_1 test_10 test_11 test_12 test_13 test_14 test_2 test_3 test_4 test_5 test_6 test_7 test_8 test_9 throw_exception to_array to_double to_integer to_logical to_null to_object to_string to_uni to_uni_vec to_unicode ucs4_comp_default ucs4_join_default valid_json_hex wrap_json_file_get_double wrap_json_file_get_double_vec wrap_json_file_get_integer wrap_json_file_get_integer_vec wrap_json_file_get_logical wrap_json_file_get_logical_vec wrap_json_file_get_object wrap_json_file_get_string wrap_json_file_get_string_vec wrap_json_file_load_from_string wrap_json_file_update_integer wrap_json_file_update_logical wrap_json_file_update_real wrap_json_file_update_string wrap_json_file_variable_info wrap_json_get_array_with_path wrap_json_get_by_path wrap_json_get_double_vec_with_path wrap_json_get_double_with_path wrap_json_get_integer_vec_with_path wrap_json_get_integer_with_path wrap_json_get_logical_vec_with_path wrap_json_get_logical_with_path wrap_json_get_string_vec_with_path wrap_json_get_string_with_path wrap_json_parse_string wrap_json_throw_exception wrap_json_update_double wrap_json_update_integer wrap_json_update_logical wrap_json_update_string wrap_json_value_add_double wrap_json_value_add_double_vec wrap_json_value_add_integer wrap_json_value_add_integer_vec wrap_json_value_add_logical wrap_json_value_add_logical_vec wrap_json_value_add_string wrap_json_value_add_string_vec wrap_json_value_create_array wrap_json_value_create_double wrap_json_value_create_integer wrap_json_value_create_logical wrap_json_value_create_null wrap_json_value_create_object wrap_json_value_create_string wrap_json_value_get_by_name_chars wrap_json_value_remove_if_present

private subroutine json_value_remove(me, destroy)

Arguments

Type	Intent	Optional	Attributes		Name
type(json_value),	intent(inout),		pointer	::	me
logical(kind=LK),	intent(in),	optional		::	destroy	If destroy is not present, it is also destroyed. If destroy is present and true, it is destroyed. If destroy is present and false, it is not destroyed.

Description

Remove a json_value (and all its children) from a linked-list structure, preserving the rest of the structure.

Examples

To extract an object from one JSON structure, and add it to another:

     type(json_value),pointer :: json1,json2,p
     logical :: found
     !create and populate json1 and json2
     call json_get(json1,'name',p,found)  ! get pointer to name element of json1
     call json_remove(p,destroy=.false.)  ! remove it from json1 (don't destroy)
     call json_add(json2,p)               ! add it to json2

To remove an object from a JSON structure (and destroy it):

     type(json_value),pointer :: json1,p
     logical :: found
     !create and populate json1
     call json_get(json1,'name',p,found)  ! get pointer to name element of json1
     call json_remove(p)                  ! remove and destroy it

History

Jacob Williams : 12/28/2014 : added destroy optional argument.

Variables

Type	Visibility	Attributes		Name
type(json_value),	public,	pointer	::	parent
type(json_value),	public,	pointer	::	previous
type(json_value),	public,	pointer	::	next
logical(kind=LK),	public		::	destroy_it

Source Code

    subroutine json_value_remove(me,destroy)

    implicit none

    type(json_value),pointer        :: me
    logical(LK),intent(in),optional :: destroy  !! If destroy is not present, it is also destroyed.
                                                !! If destroy is present and true, it is destroyed.
                                                !! If destroy is present and false, it is not destroyed.

    type(json_value),pointer :: parent,previous,next
    logical(LK) :: destroy_it

    if (associated(me)) then

        !optional input argument:
        if (present(destroy)) then
            destroy_it = destroy
        else
            destroy_it = .true.
        end if

        if (associated(me%parent)) then

            parent => me%parent

            if (associated(me%next)) then

                !there are later items in the list:

                next => me%next
                nullify(me%next)

                if (associated(me%previous)) then
                    !there are earlier items in the list
                    previous => me%previous
                    previous%next => next
                    next%previous => previous
                else
                    !this is the first item in the list
                    parent%children => next
                    nullify(next%previous)
                end if

            else

                if (associated(me%previous)) then
                    !there are earlier items in the list:
                    previous => me%previous
                    nullify(previous%next)
                    parent%tail => previous
                else
                    !this is the only item in the list:
                    nullify(parent%children)
                    nullify(parent%tail)
                end if

            end if

            parent%n_children = parent%n_children - 1

        end if

        if (destroy_it) call json_value_destroy(me)

    end if

    end subroutine json_value_remove