json_get_path Subroutine

private subroutine json_get_path(json, p, path, found, use_alt_array_tokens, path_sep)

Returns the path to a JSON object that is part of a linked list structure.

The path returned would be suitable for input to json_get_by_path and related routines.

Note

If an error occurs (which in this case means a malformed JSON structure) then an exception will be thrown, unless found is present, which will be set to false. path will be a blank string.

Note

If json%path_mode/=1, then the use_alt_array_tokens and path_sep inputs are ignored if present.

Note

http://goessner.net/articles/JsonPath/ (path_mode=3) does not specify whether or not the keys should be escaped (this routine assumes not, as does http://jsonpath.com). Also, we are using Fortran-style 1-based array indices, not 0-based, to agree with the assumption in path_mode=1

Type Bound

json_core

Arguments

Type IntentOptional Attributes Name
class(json_core), intent(inout) :: json
type(json_value), intent(in), pointer :: p

a JSON linked list object
character(kind=CK, len=:), intent(out), allocatable :: path

path to the variable
logical(kind=LK), intent(out), optional :: found

true if there were no problems
logical(kind=LK), intent(in), optional :: use_alt_array_tokens

if true, then ‘()’ are used for array elements otherwise, ‘[]’ are used [default] (only used if path_mode=1)
character(kind=CK, len=1), intent(in), optional :: path_sep

character to use for path separator (otherwise use json%path_separator) (only used if path_mode=1)

Calls

proc~~json_get_path~~CallsGraph proc~json_get_path json_core%json_get_path none~info~2 json_core%info proc~json_get_path->none~info~2 none~throw_exception json_core%throw_exception proc~json_get_path->none~throw_exception proc~encode_rfc6901 encode_rfc6901 proc~json_get_path->proc~encode_rfc6901 proc~integer_to_string integer_to_string proc~json_get_path->proc~integer_to_string proc~json_clear_exceptions json_core%json_clear_exceptions proc~json_get_path->proc~json_clear_exceptions proc~json_info json_core%json_info none~info~2->proc~json_info proc~json_info_by_path json_core%json_info_by_path none~info~2->proc~json_info_by_path proc~json_throw_exception json_core%json_throw_exception none~throw_exception->proc~json_throw_exception proc~replace_string replace_string proc~encode_rfc6901->proc~replace_string proc~json_info->none~throw_exception proc~json_info_by_path->none~info~2 none~get~2 json_core%get proc~json_info_by_path->none~get~2 proc~json_get_alloc_string_vec json_core%json_get_alloc_string_vec none~get~2->proc~json_get_alloc_string_vec proc~json_get_alloc_string_vec_by_path json_core%json_get_alloc_string_vec_by_path none~get~2->proc~json_get_alloc_string_vec_by_path proc~json_get_array json_core%json_get_array none~get~2->proc~json_get_array proc~json_get_array_by_path json_core%json_get_array_by_path none~get~2->proc~json_get_array_by_path proc~json_get_by_path json_core%json_get_by_path none~get~2->proc~json_get_by_path proc~json_get_integer json_core%json_get_integer none~get~2->proc~json_get_integer proc~json_get_integer_by_path json_core%json_get_integer_by_path none~get~2->proc~json_get_integer_by_path proc~json_get_integer_vec json_core%json_get_integer_vec none~get~2->proc~json_get_integer_vec proc~json_get_integer_vec_by_path json_core%json_get_integer_vec_by_path none~get~2->proc~json_get_integer_vec_by_path proc~json_get_logical json_core%json_get_logical none~get~2->proc~json_get_logical proc~json_get_logical_by_path json_core%json_get_logical_by_path none~get~2->proc~json_get_logical_by_path proc~json_get_logical_vec json_core%json_get_logical_vec none~get~2->proc~json_get_logical_vec proc~json_get_logical_vec_by_path json_core%json_get_logical_vec_by_path none~get~2->proc~json_get_logical_vec_by_path proc~json_get_real json_core%json_get_real none~get~2->proc~json_get_real proc~json_get_real32 json_core%json_get_real32 none~get~2->proc~json_get_real32 proc~json_get_real32_by_path json_core%json_get_real32_by_path none~get~2->proc~json_get_real32_by_path proc~json_get_real32_vec json_core%json_get_real32_vec none~get~2->proc~json_get_real32_vec proc~json_get_real32_vec_by_path json_core%json_get_real32_vec_by_path none~get~2->proc~json_get_real32_vec_by_path proc~json_get_real_by_path json_core%json_get_real_by_path none~get~2->proc~json_get_real_by_path proc~json_get_real_vec json_core%json_get_real_vec none~get~2->proc~json_get_real_vec proc~json_get_real_vec_by_path json_core%json_get_real_vec_by_path none~get~2->proc~json_get_real_vec_by_path proc~json_get_string json_core%json_get_string none~get~2->proc~json_get_string proc~json_get_string_by_path json_core%json_get_string_by_path none~get~2->proc~json_get_string_by_path proc~json_get_string_vec json_core%json_get_string_vec none~get~2->proc~json_get_string_vec proc~json_get_string_vec_by_path json_core%json_get_string_vec_by_path none~get~2->proc~json_get_string_vec_by_path proc~json_get_alloc_string_vec->none~get~2 none~string_info json_core%string_info proc~json_get_alloc_string_vec->none~string_info proc~json_get_alloc_string_vec_by_path->none~throw_exception proc~json_get_alloc_string_vec_by_path->proc~json_clear_exceptions proc~json_get_alloc_string_vec_by_path->none~get~2 proc~flag_not_found flag_not_found proc~json_get_alloc_string_vec_by_path->proc~flag_not_found proc~json_get_array->none~throw_exception proc~json_get_array_by_path->none~throw_exception proc~json_get_array_by_path->proc~json_clear_exceptions proc~json_get_array_by_path->none~get~2 proc~json_get_by_path->none~throw_exception proc~json_get_by_path->proc~integer_to_string proc~json_get_by_path->proc~json_clear_exceptions proc~json_get_by_path_default json_core%json_get_by_path_default proc~json_get_by_path->proc~json_get_by_path_default proc~json_get_by_path_jsonpath_bracket json_core%json_get_by_path_jsonpath_bracket proc~json_get_by_path->proc~json_get_by_path_jsonpath_bracket proc~json_get_by_path_rfc6901 json_core%json_get_by_path_rfc6901 proc~json_get_by_path->proc~json_get_by_path_rfc6901 proc~json_get_integer->none~throw_exception proc~string_to_integer string_to_integer proc~json_get_integer->proc~string_to_integer proc~json_get_integer_by_path->none~throw_exception proc~json_get_integer_by_path->proc~json_clear_exceptions proc~json_get_integer_by_path->none~get~2 proc~json_get_integer_by_path->proc~flag_not_found proc~json_get_integer_vec->none~get~2 proc~json_get_integer_vec_by_path->none~throw_exception proc~json_get_integer_vec_by_path->proc~json_clear_exceptions proc~json_get_integer_vec_by_path->none~get~2 proc~json_get_integer_vec_by_path->proc~flag_not_found proc~json_get_logical->none~throw_exception proc~json_get_logical_by_path->none~throw_exception proc~json_get_logical_by_path->proc~json_clear_exceptions proc~json_get_logical_by_path->none~get~2 proc~json_get_logical_by_path->proc~flag_not_found proc~json_get_logical_vec->none~get~2 proc~json_get_logical_vec_by_path->none~throw_exception proc~json_get_logical_vec_by_path->proc~json_clear_exceptions proc~json_get_logical_vec_by_path->none~get~2 proc~json_get_logical_vec_by_path->proc~flag_not_found proc~json_get_real->none~throw_exception proc~string_to_real string_to_real proc~json_get_real->proc~string_to_real proc~json_get_real32->none~get~2 proc~json_get_real32_by_path->none~get~2 proc~json_get_real32_vec->none~get~2 proc~json_get_real32_vec_by_path->none~get~2 proc~json_get_real_by_path->none~throw_exception proc~json_get_real_by_path->proc~json_clear_exceptions proc~json_get_real_by_path->none~get~2 proc~json_get_real_by_path->proc~flag_not_found proc~json_get_real_vec->none~get~2 proc~json_get_real_vec_by_path->none~throw_exception proc~json_get_real_vec_by_path->proc~json_clear_exceptions proc~json_get_real_vec_by_path->none~get~2 proc~json_get_real_vec_by_path->proc~flag_not_found proc~json_get_string->none~throw_exception proc~json_get_string->proc~integer_to_string proc~escape_string escape_string proc~json_get_string->proc~escape_string proc~real_to_string real_to_string proc~json_get_string->proc~real_to_string proc~json_get_string_by_path->none~throw_exception proc~json_get_string_by_path->proc~json_clear_exceptions proc~json_get_string_by_path->none~get~2 proc~json_get_string_by_path->proc~flag_not_found proc~json_get_string_vec->none~get~2 proc~json_get_string_vec_by_path->none~throw_exception proc~json_get_string_vec_by_path->proc~json_clear_exceptions proc~json_get_string_vec_by_path->none~get~2 proc~json_get_string_vec_by_path->proc~flag_not_found proc~json_string_info json_core%json_string_info none~string_info->proc~json_string_info proc~valid_json_hex valid_json_hex proc~escape_string->proc~valid_json_hex proc~json_get_by_path_default->none~throw_exception proc~json_get_by_path_default->proc~json_clear_exceptions proc~json_get_by_path_default->proc~string_to_integer none~add~2 json_core%add proc~json_get_by_path_default->none~add~2 none~get_child json_core%get_child proc~json_get_by_path_default->none~get_child proc~json_value_create json_value_create proc~json_get_by_path_default->proc~json_value_create proc~to_array json_core%to_array proc~json_get_by_path_default->proc~to_array proc~to_null json_core%to_null proc~json_get_by_path_default->proc~to_null proc~to_object json_core%to_object proc~json_get_by_path_default->proc~to_object proc~json_get_by_path_jsonpath_bracket->none~throw_exception proc~json_get_by_path_jsonpath_bracket->proc~json_clear_exceptions proc~json_get_by_path_jsonpath_bracket->proc~string_to_integer proc~json_get_by_path_jsonpath_bracket->none~add~2 proc~json_get_by_path_jsonpath_bracket->none~get_child proc~convert json_core%convert proc~json_get_by_path_jsonpath_bracket->proc~convert proc~json_get_by_path_jsonpath_bracket->proc~json_value_create proc~json_get_by_path_jsonpath_bracket->proc~to_null proc~json_get_by_path_rfc6901->none~throw_exception proc~json_get_by_path_rfc6901->proc~json_clear_exceptions proc~json_get_by_path_rfc6901->proc~string_to_integer proc~json_get_by_path_rfc6901->none~get_child proc~decode_rfc6901 decode_rfc6901 proc~json_get_by_path_rfc6901->proc~decode_rfc6901 proc~compact_real_string compact_real_string proc~real_to_string->proc~compact_real_string proc~json_value_add_integer json_core%json_value_add_integer none~add~2->proc~json_value_add_integer proc~json_value_add_integer_vec json_core%json_value_add_integer_vec none~add~2->proc~json_value_add_integer_vec proc~json_value_add_logical json_core%json_value_add_logical none~add~2->proc~json_value_add_logical proc~json_value_add_logical_vec json_core%json_value_add_logical_vec none~add~2->proc~json_value_add_logical_vec proc~json_value_add_member json_core%json_value_add_member none~add~2->proc~json_value_add_member proc~json_value_add_null json_core%json_value_add_null none~add~2->proc~json_value_add_null proc~json_value_add_real json_core%json_value_add_real none~add~2->proc~json_value_add_real proc~json_value_add_real32 json_core%json_value_add_real32 none~add~2->proc~json_value_add_real32 proc~json_value_add_real32_vec json_core%json_value_add_real32_vec none~add~2->proc~json_value_add_real32_vec proc~json_value_add_real_vec json_core%json_value_add_real_vec none~add~2->proc~json_value_add_real_vec proc~json_value_add_string json_core%json_value_add_string none~add~2->proc~json_value_add_string proc~json_value_add_string_vec json_core%json_value_add_string_vec none~add~2->proc~json_value_add_string_vec proc~json_value_get_child json_core%json_value_get_child none~get_child->proc~json_value_get_child proc~json_value_get_child_by_index json_core%json_value_get_child_by_index none~get_child->proc~json_value_get_child_by_index proc~json_value_get_child_by_name json_core%json_value_get_child_by_name none~get_child->proc~json_value_get_child_by_name proc~convert->none~info~2 proc~convert->none~throw_exception none~create_array json_core%create_array proc~convert->none~create_array none~create_null json_core%create_null proc~convert->none~create_null none~create_object json_core%create_object proc~convert->none~create_object proc~json_value_replace json_core%json_value_replace proc~convert->proc~json_value_replace proc~decode_rfc6901->proc~replace_string proc~json_string_info->none~info~2 proc~json_string_info->none~throw_exception proc~json_string_info->proc~json_clear_exceptions proc~json_string_info->none~get~2 proc~destroy_json_data destroy_json_data proc~to_array->proc~destroy_json_data proc~to_null->proc~destroy_json_data proc~to_object->proc~destroy_json_data proc~json_value_create_array json_core%json_value_create_array none~create_array->proc~json_value_create_array proc~json_value_create_null json_core%json_value_create_null none~create_null->proc~json_value_create_null proc~json_value_create_object json_core%json_value_create_object none~create_object->proc~json_value_create_object proc~json_value_add_integer->none~add~2 none~create_integer json_core%create_integer proc~json_value_add_integer->none~create_integer proc~json_value_add_integer_vec->none~add~2 proc~json_value_add_integer_vec->none~create_array proc~json_value_add_logical->none~add~2 none~create_logical json_core%create_logical proc~json_value_add_logical->none~create_logical proc~json_value_add_logical_vec->none~add~2 proc~json_value_add_logical_vec->none~create_array proc~json_value_add_member->none~info~2 proc~json_value_add_member->none~throw_exception proc~json_value_add_null->none~add~2 proc~json_value_add_null->none~create_null proc~json_value_add_real->none~add~2 none~create_real~2 json_core%create_real proc~json_value_add_real->none~create_real~2 proc~json_value_add_real32->none~add~2 proc~json_value_add_real32_vec->none~add~2 proc~json_value_add_real_vec->none~add~2 proc~json_value_add_real_vec->none~create_array proc~json_value_add_string->none~add~2 none~create_string json_core%create_string proc~json_value_add_string->none~create_string proc~json_value_add_string_vec->none~add~2 proc~json_value_add_string_vec->none~create_array proc~json_value_get_child->none~throw_exception proc~json_value_get_child_by_index->none~throw_exception proc~json_value_get_child_by_index->proc~json_clear_exceptions proc~json_value_get_child_by_name->none~throw_exception proc~json_value_get_child_by_name->proc~json_clear_exceptions proc~name_equal json_core%name_equal proc~json_value_get_child_by_name->proc~name_equal none~insert_after json_core%insert_after proc~json_value_replace->none~insert_after proc~json_value_remove json_core%json_value_remove proc~json_value_replace->proc~json_value_remove proc~json_value_create_integer json_core%json_value_create_integer none~create_integer->proc~json_value_create_integer proc~json_value_create_logical json_core%json_value_create_logical none~create_logical->proc~json_value_create_logical proc~json_value_create_real32 json_core%json_value_create_real32 none~create_real~2->proc~json_value_create_real32 proc~json_value_create_string json_core%json_value_create_string none~create_string->proc~json_value_create_string proc~json_value_insert_after json_core%json_value_insert_after none~insert_after->proc~json_value_insert_after proc~json_value_insert_after_child_by_index json_core%json_value_insert_after_child_by_index none~insert_after->proc~json_value_insert_after_child_by_index proc~json_value_create_array->proc~json_value_create proc~json_value_create_array->proc~to_array proc~json_value_create_null->proc~json_value_create proc~json_value_create_null->proc~to_null proc~json_value_create_object->proc~json_value_create proc~json_value_create_object->proc~to_object none~destroy~3 json_core%destroy proc~json_value_remove->none~destroy~3 proc~name_strings_equal json_core%name_strings_equal proc~name_equal->proc~name_strings_equal proc~destroy_json_core json_core%destroy_json_core none~destroy~3->proc~destroy_json_core proc~json_value_destroy json_core%json_value_destroy none~destroy~3->proc~json_value_destroy proc~json_value_create_integer->proc~json_value_create proc~to_integer json_core%to_integer proc~json_value_create_integer->proc~to_integer proc~json_value_create_logical->proc~json_value_create proc~to_logical json_core%to_logical proc~json_value_create_logical->proc~to_logical proc~json_value_create_real32->none~create_real~2 proc~json_value_create_string->proc~json_value_create proc~to_string json_core%to_string proc~json_value_create_string->proc~to_string proc~json_value_insert_after_child_by_index->none~get_child proc~json_value_insert_after_child_by_index->none~insert_after proc~lowercase_string lowercase_string proc~name_strings_equal->proc~lowercase_string proc~json_value_destroy->proc~destroy_json_data proc~json_value_destroy->none~destroy~3 proc~to_integer->proc~destroy_json_data proc~to_logical->proc~destroy_json_data proc~to_string->proc~destroy_json_data

Called by

proc~~json_get_path~~CalledByGraph proc~json_get_path json_core%json_get_path none~get_path json_core%get_path none~get_path->proc~json_get_path proc~json_check_children_for_duplicate_keys json_core%json_check_children_for_duplicate_keys proc~json_check_children_for_duplicate_keys->none~get_path proc~wrap_json_get_path wrap_json_get_path proc~wrap_json_get_path->none~get_path

Source Code

    subroutine json_get_path(json, p, path, found, use_alt_array_tokens, path_sep)

    implicit none

    class(json_core),intent(inout)                   :: json
    type(json_value),pointer,intent(in)              :: p     !! a JSON linked list object
    character(kind=CK,len=:),allocatable,intent(out) :: path  !! path to the variable
    logical(LK),intent(out),optional                 :: found !! true if there were no problems
    logical(LK),intent(in),optional :: use_alt_array_tokens   !! if true, then '()' are used for array elements
                                                              !! otherwise, '[]' are used [default]
                                                              !! (only used if `path_mode=1`)
    character(kind=CK,len=1),intent(in),optional :: path_sep  !! character to use for path separator
                                                              !! (otherwise use `json%path_separator`)
                                                              !! (only used if `path_mode=1`)

    character(kind=CK,len=:),allocatable       :: name         !! variable name
    character(kind=CK,len=:),allocatable       :: parent_name  !! variable's parent name
    character(kind=CK,len=max_integer_str_len) :: istr         !! for integer to string conversion
                                                               !! (array indices)
    type(json_value),pointer :: tmp            !! for traversing the structure
    type(json_value),pointer :: element        !! for traversing the structure
    integer(IK)              :: var_type       !! JSON variable type flag
    integer(IK)              :: i              !! counter
    integer(IK)              :: n_children     !! number of children for parent
    logical(LK)              :: use_brackets   !! to use '[]' characters for arrays
    logical(LK)              :: parent_is_root !! if the parent is the root
    character(kind=CK,len=1) :: array_start    !! for `path_mode=1`, the character to start arrays
    character(kind=CK,len=1) :: array_end      !! for `path_mode=1`, the character to end arrays
    logical                  :: consecutive_arrays      !! check for array of array case
    integer(IK)              :: parents_parent_var_type !! `var_type` for parent's parent

    !optional input:
    if (present(use_alt_array_tokens)) then
        use_brackets = .not. use_alt_array_tokens
    else
        use_brackets = .true.
    end if

    if (json%path_mode==1_IK) then
        if (use_brackets) then
            array_start = start_array
            array_end   = end_array
        else
            array_start = start_array_alt
            array_end   = end_array_alt
        end if
    end if

    ! initialize:
    consecutive_arrays = .false.

    if (associated(p)) then

        !traverse the structure via parents up to the root
        tmp => p
        do

            if (.not. associated(tmp)) exit !finished

            !get info about the current variable:
            call json%info(tmp,name=name)
            if (json%path_mode==2_IK) then
                name = encode_rfc6901(name)
            end if

            ! if tmp a child of an object, or an element of an array
            if (associated(tmp%parent)) then

                !get info about the parent:
                call json%info(tmp%parent,var_type=var_type,&
                               n_children=n_children,name=parent_name)
                if (json%path_mode==2_IK) then
                    parent_name = encode_rfc6901(parent_name)
                end if
                if (associated(tmp%parent%parent)) then
                    call json%info(tmp%parent%parent,var_type=parents_parent_var_type)
                    consecutive_arrays = parents_parent_var_type == json_array .and. &
                                         var_type == json_array
                else
                    consecutive_arrays = .false.
                end if

                select case (var_type)
                case (json_array)

                    !get array index of this element:
                    element => tmp%parent%children
                    do i = 1, n_children
                        if (.not. associated(element)) then
                            call json%throw_exception('Error in json_get_path: '//&
                                                      'malformed JSON structure. ',found)
                            exit
                        end if
                        if (associated(element,tmp)) then
                            exit
                        else
                            element => element%next
                        end if
                        if (i==n_children) then ! it wasn't found (should never happen)
                            call json%throw_exception('Error in json_get_path: '//&
                                                      'malformed JSON structure. ',found)
                            exit
                        end if
                    end do
                    select case(json%path_mode)
                    case(3_IK)
                        ! JSONPath "bracket-notation"
                        ! example: `$['key'][1]`
                        ! [note: this uses 1-based indices]
                        call integer_to_string(i,int_fmt,istr)
                        if (consecutive_arrays) then
                            call add_to_path(start_array//trim(adjustl(istr))//end_array,CK_'')
                        else
                            call add_to_path(start_array//single_quote//parent_name//&
                                             single_quote//end_array//&
                                             start_array//trim(adjustl(istr))//end_array,CK_'')
                        end if
                    case(2_IK)
                        ! rfc6901
                        ! Example: '/key/0'
                        call integer_to_string(i-1_IK,int_fmt,istr) ! 0-based index
                        if (consecutive_arrays) then
                            call add_to_path(trim(adjustl(istr)))
                        else
                            call add_to_path(parent_name//slash//trim(adjustl(istr)))
                        end if
                    case(1_IK)
                        ! default
                        ! Example: `key[1]`
                        call integer_to_string(i,int_fmt,istr)
                        if (consecutive_arrays) then
                            call add_to_path(array_start//trim(adjustl(istr))//array_end,path_sep)
                        else
                            call add_to_path(parent_name//array_start//&
                                             trim(adjustl(istr))//array_end,path_sep)
                        end if
                    end select

                    if (.not. consecutive_arrays) tmp => tmp%parent  ! already added parent name

                case (json_object)

                    if (.not. consecutive_arrays) then
                        ! idea is not to print the array name if
                        ! it was already printed with the array

                        !process parent on the next pass
                        select case(json%path_mode)
                        case(3_IK)
                            call add_to_path(start_array//single_quote//name//&
                                            single_quote//end_array,CK_'')
                        case default
                            call add_to_path(name,path_sep)
                        end select

                    end if

                case default

                    call json%throw_exception('Error in json_get_path: '//&
                                              'malformed JSON structure. '//&
                                              'A variable that is not an object '//&
                                              'or array should not have a child.',found)
                    exit

                end select

            else
                !the last one:
                select case(json%path_mode)
                case(3_IK)
                    call add_to_path(start_array//single_quote//name//&
                                     single_quote//end_array,CK_'')
                case default
                    call add_to_path(name,path_sep)
                end select
            end if

            if (associated(tmp%parent)) then
                !check if the parent is the root:
                parent_is_root = (.not. associated(tmp%parent%parent))
                if (parent_is_root) exit
            end if

            !go to parent:
            tmp => tmp%parent

        end do

    else
        call json%throw_exception('Error in json_get_path: '//&
                                  'input pointer is not associated',found)
    end if

    !for errors, return blank string:
    if (json%exception_thrown .or. .not. allocated(path)) then
        path = CK_''
    else
        select case (json%path_mode)
        case(3_IK)
            ! add the outer level object identifier:
            path = root//path
        case(2_IK)
            ! add the root slash:
            path = slash//path
        end select
    end if

    !optional output:
    if (present(found)) then
        if (json%exception_thrown) then
            found = .false.
            call json%clear_exceptions()
        else
            found = .true.
        end if
    end if

    contains

        subroutine add_to_path(str,path_sep)
        !! prepend the string to the path
        implicit none
        character(kind=CK,len=*),intent(in) :: str  !! string to prepend to `path`
        character(kind=CK,len=*),intent(in),optional :: path_sep
            !! path separator (default is '.').
            !! (ignored if `json%path_mode/=1`)

        select case (json%path_mode)
        case(3_IK)
            ! in this case, the options are ignored
            if (.not. allocated(path)) then
                path = str
            else
                path = str//path
            end if
        case(2_IK)
            ! in this case, the options are ignored
            if (.not. allocated(path)) then
                path = str
            else
                path = str//slash//path
            end if
        case(1_IK)
            ! default path format
            if (.not. allocated(path)) then
                path = str
            else
                ! shouldn't add the path_sep for cases like x[1][2]
                ! [if current is an array element, and the previous was
                ! also an array element] so check for that here:
                if (.not. ( str(len(str):len(str))==array_end .and. &
                            path(1:1)==array_start )) then
                    if (present(path_sep)) then
                        ! use user specified:
                        path = str//path_sep//path
                    else
                        ! use the default:
                        path = str//json%path_separator//path
                    end if
                else
                    path = str//path
                end if
            end if
        end select

        end subroutine add_to_path

    end subroutine json_get_path