json_parse_file Subroutine

private subroutine json_parse_file(json, file, p, unit, close_unit_if_open)

Parse the JSON file and populate the json_value tree.

Inputs

The inputs can be:

  • file & unit : the specified unit is used to read JSON from file. [note if unit is already open, then the filename is ignored]
  • file : JSON is read from file using internal unit number

Example

    type(json_core) :: json
    type(json_value),pointer :: p
    call json%load(file='myfile.json', p=p)

History

  • Jacob Williams : 01/13/2015 : added read from string option.

  • Izaak Beekman : 03/08/2015 : moved read from string to separate subroutine, and error annotation to separate subroutine.

    calls will automatically be cleared.

Type Bound

json_core

Arguments

Type IntentOptional Attributes Name
class(json_core), intent(inout) :: json
character(kind=CDK, len=*), intent(in) :: file

JSON file name
type(json_value), pointer :: p

output structure
integer(kind=IK), intent(in), optional :: unit

file unit number (/= 0)
logical(kind=LK), intent(in), optional :: close_unit_if_open

if true, close unit if it was already open [defaults to true]

Calls

proc~~json_parse_file~~CallsGraph proc~json_parse_file json_core%json_parse_file none~throw_exception json_core%throw_exception proc~json_parse_file->none~throw_exception proc~annotate_invalid_json json_core%annotate_invalid_json proc~json_parse_file->proc~annotate_invalid_json proc~json_check_all_for_duplicate_keys json_core%json_check_all_for_duplicate_keys proc~json_parse_file->proc~json_check_all_for_duplicate_keys proc~json_initialize json_core%json_initialize proc~json_parse_file->proc~json_initialize proc~json_parse_end json_core%json_parse_end proc~json_parse_file->proc~json_parse_end proc~json_prepare_parser json_core%json_prepare_parser proc~json_parse_file->proc~json_prepare_parser proc~json_value_create json_value_create proc~json_parse_file->proc~json_value_create proc~json_throw_exception json_core%json_throw_exception none~throw_exception->proc~json_throw_exception proc~wrap_json_throw_exception json_core%wrap_json_throw_exception none~throw_exception->proc~wrap_json_throw_exception proc~get_current_line_from_file_sequential json_core%get_current_line_from_file_sequential proc~annotate_invalid_json->proc~get_current_line_from_file_sequential proc~get_current_line_from_file_stream json_core%get_current_line_from_file_stream proc~annotate_invalid_json->proc~get_current_line_from_file_stream proc~integer_to_string integer_to_string proc~annotate_invalid_json->proc~integer_to_string proc~json_traverse json_core%json_traverse proc~json_check_all_for_duplicate_keys->proc~json_traverse proc~json_initialize->none~throw_exception proc~json_initialize->proc~integer_to_string proc~json_clear_exceptions json_core%json_clear_exceptions proc~json_initialize->proc~json_clear_exceptions proc~json_parse_end->none~throw_exception proc~pop_char json_core%pop_char proc~json_parse_end->proc~pop_char proc~json_traverse->none~throw_exception proc~wrap_json_throw_exception->none~throw_exception interface~to_unicode to_unicode proc~wrap_json_throw_exception->interface~to_unicode proc~to_uni to_uni interface~to_unicode->proc~to_uni proc~to_uni_vec to_uni_vec interface~to_unicode->proc~to_uni_vec

Called by

proc~~json_parse_file~~CalledByGraph proc~json_parse_file json_core%json_parse_file none~load~2 json_core%load none~load~2->proc~json_parse_file proc~json_file_load json_file%json_file_load proc~json_file_load->none~load~2

Source Code

    subroutine json_parse_file(json, file, p, unit, close_unit_if_open)

    implicit none

    class(json_core),intent(inout)       :: json
    character(kind=CDK,len=*),intent(in) :: file  !! JSON file name
    type(json_value),pointer             :: p     !! output structure
    integer(IK),intent(in),optional      :: unit  !! file unit number (/= 0)
    logical(LK),intent(in),optional      :: close_unit_if_open !! if true, close unit if it was already open [defaults to true]

    integer(IK) :: iunit   !! file unit actually used
    integer(IK) :: istat   !! iostat flag
    logical(LK) :: is_open !! if the file is already open
    logical(LK) :: has_duplicate  !! if checking for duplicate keys
    character(kind=CK,len=:),allocatable :: path !! path to any duplicate key
    logical(LK) :: unit_was_open  !! track if unit was already open
    logical(LK) :: close_if_open  !! local copy of `close_unit_if_open`

    if (present(close_unit_if_open)) then
        close_if_open = close_unit_if_open
    else
        close_if_open = .true.  ! default (original) behavior
    end if

    ! clear any exceptions and initialize:
    call json%initialize()
    call json%prepare_parser()

    if ( present(unit) ) then

        if (unit==0) then
            call json%throw_exception('Error in json_parse_file: unit number must not be 0.')
            return
        end if

        iunit = unit

        ! check to see if the file is already open
        ! if it is, then use it, otherwise open the file with the name given.
        inquire(unit=iunit, opened=is_open, iostat=istat)
        unit_was_open = (istat==0 .and. is_open)
        if (.not. unit_was_open) then
           ! open the file
            open (  unit        = iunit, &
                    file        = file, &
                    status      = 'OLD', &
                    action      = 'READ', &
                    form        = form_spec, &
                    access      = access_spec, &
                    iostat      = istat &
                    FILE_ENCODING )
            close_if_open = .true.  ! we opened it, so we should close it later
        else
            ! if the file is already open, then we need to make sure
            ! that it is open with the correct form/access/etc...
        end if

    else

        ! open the file with a new unit number:
        open (  newunit     = iunit, &
                file        = file, &
                status      = 'OLD', &
                action      = 'READ', &
                form        = form_spec, &
                access      = access_spec, &
                iostat      = istat &
                FILE_ENCODING )
        close_if_open = .true.  ! we opened it, so we should close it later

    end if

    if (istat==0) then

        if (use_unformatted_stream) then
            ! save the file size to be read:
            inquire(unit=iunit, size=json%filesize, iostat=istat)
        end if

        ! create the value and associate the pointer
        call json_value_create(p)

        ! Note: the name of the root json_value doesn't really matter,
        !  but we'll allocate something here just in case.
        p%name = trim(file)  !use the file name

        ! parse as a value
        call json%parse_value(unit=iunit, str=CK_'', value=p)
        call json%parse_end(unit=iunit, str=CK_'')

        ! check for errors:
        if (json%exception_thrown) then
            call json%annotate_invalid_json(iunit,CK_'')
        else
            if (.not. json%allow_duplicate_keys) then
                call json%check_for_duplicate_keys(p,has_duplicate,path=path)
                if (.not. json%exception_thrown) then
                    if (has_duplicate) then
                        call json%throw_exception('Error in json_parse_file: '//&
                                                  'Duplicate key found: '//path)
                    end if
                end if
            end if
        end if

        ! close the file only if we opened it, or if user specified to close it
        if (.not. unit_was_open .or. close_if_open) then
            close(unit=iunit, iostat=istat)
            if (istat /= 0 .and. .not. json%exception_thrown) then
                call json%throw_exception('Error closing file')
            end if
        end if

    else

        call json%throw_exception('Error in json_parse_file: Error opening file: '//trim(file))
        nullify(p)

    end if

    end subroutine json_parse_file