Quick ICRS, epoch J2000.0, to CIRS transformation, given precomputed star-independent astrometry parameters.
Use of this routine is appropriate when efficiency is important and where many star positions are to be transformed for one date. The star-independent parameters can be obtained by calling one of the routines APCI[13], APCG[13], APCO[13] or APCS[13].
If the parallax and proper motions are zero the ATCIQZ routine can be used instead.
Status: support routine.
All the vectors are with respect to BCRS axes.
Star data for an epoch other than J2000.0 (for example from the Hipparcos catalog, which has an epoch of J1991.25) will require a preliminary call to PMSAFE before use.
The proper motion in RA is dRA/dt rather than cos(Dec)*dRA/dt.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=wp), | intent(in) | :: | rc | ICRS RA at J2000.0 (radians) |
||
| real(kind=wp), | intent(in) | :: | dc | ICRS Dec at J2000.0 (radians) |
||
| real(kind=wp), | intent(in) | :: | pr | RA proper motion (radians/year; Note 3) |
||
| real(kind=wp), | intent(in) | :: | pd | Dec proper motion (radians/year) |
||
| real(kind=wp), | intent(in) | :: | px | parallax (arcsec) |
||
| real(kind=wp), | intent(in) | :: | rv | radial velocity (km/s, +ve if receding) |
||
| real(kind=wp), | intent(in), | dimension(30) | :: | astrom | star-independent astrometry parameters: (1) PM time interval (SSB, Julian years) (2-4) SSB to observer (vector, au) (5-7) Sun to observer (unit vector) (8) distance from Sun to observer (au) (9-11) v: barycentric observer velocity (vector, c) (12) sqrt(1-|v|^2): reciprocal of Lorenz factor (13-21) bias-precession-nutation matrix (22) longitude + s' (radians) (23) polar motion xp wrt local meridian (radians) (24) polar motion yp wrt local meridian (radians) (25) sine of geodetic latitude (26) cosine of geodetic latitude (27) magnitude of diurnal aberration vector (28) "local" Earth rotation angle (radians) (29) refraction constant A (radians) (30) refraction constant B (radians) |
|
| real(kind=wp), | intent(out) | :: | ri | CIRS RA (radians) |
||
| real(kind=wp), | intent(out) | :: | di | CIRS Dec (radians) |
subroutine ATCIQ ( rc, dc, pr, pd, px, rv, astrom, ri, di )
implicit none
real(wp),intent(in) :: rc !! ICRS RA at J2000.0 (radians)
real(wp),intent(in) :: dc !! ICRS Dec at J2000.0 (radians)
real(wp),intent(in) :: pr !! RA proper motion (radians/year; Note 3)
real(wp),intent(in) :: pd !! Dec proper motion (radians/year)
real(wp),intent(in) :: px !! parallax (arcsec)
real(wp),intent(in) :: rv !! radial velocity (km/s, +ve if receding)
real(wp),dimension(30),intent(in) :: astrom !! star-independent astrometry parameters:
!! (1) PM time interval (SSB, Julian years)
!! (2-4) SSB to observer (vector, au)
!! (5-7) Sun to observer (unit vector)
!! (8) distance from Sun to observer (au)
!! (9-11) v: barycentric observer velocity (vector, c)
!! (12) sqrt(1-|v|^2): reciprocal of Lorenz factor
!! (13-21) bias-precession-nutation matrix
!! (22) longitude + s' (radians)
!! (23) polar motion xp wrt local meridian (radians)
!! (24) polar motion yp wrt local meridian (radians)
!! (25) sine of geodetic latitude
!! (26) cosine of geodetic latitude
!! (27) magnitude of diurnal aberration vector
!! (28) "local" Earth rotation angle (radians)
!! (29) refraction constant A (radians)
!! (30) refraction constant B (radians)
real(wp),intent(out) :: ri !! CIRS RA (radians)
real(wp),intent(out) :: di !! CIRS Dec (radians)
real(wp) :: pco(3), pnat(3), ppr(3), pi(3), w
! Proper motion and parallax, giving BCRS coordinate direction.
call PMPX ( rc, dc, pr, pd, px, rv, astrom(1), astrom(2), &
pco )
! Light deflection by the Sun, giving BCRS natural direction.
call LDSUN ( pco, astrom(5), astrom(8), pnat )
! Aberration, giving GCRS proper direction.
call AB (pnat, astrom(9), astrom(8), astrom(12), ppr )
! Bias-precession-nutation, giving CIRS proper direction.
call RXP ( astrom(13), ppr, pi )
! CIRS RA,Dec.
call C2S ( pi, w, di )
ri = ANP ( w )
end subroutine ATCIQ