Quick ICRS, epoch J2000.0, to CIRS transformation, given precomputed star-independent astrometry parameters plus a list of light- deflecting bodies.
Use of this routine is appropriate when efficiency is important and where many star positions are to be transformed for one date. The star-independent parameters can be obtained by calling one of the routines APCI[13], APCG[13], APCO[13] or APCS[13].
If the only light-deflecting body to be taken into account is the Sun, the ATCIQ routine can be used instead. If in addition the parallax and proper motions are zero, the ATCIQZ routine can be used.
Status: support routine.
Star data for an epoch other than J2000.0 (for example from the Hipparcos catalog, which has an epoch of J1991.25) will require a preliminary call to PMSAFE before use.
The proper motion in RA is dRA/dt rather than cos(Dec)*dRA/dt.
The array B contains N entries, one for each body to be considered. If N = 0, no gravitational light deflection will be applied, not even for the Sun.
The array B should include an entry for the Sun as well as for any planet or other body to be taken into account. The entries should be in the order in which the light passes the body.
In the entry in the B array for body I, the mass parameter B(1,I) can, as required, be adjusted in order to allow for such effects as quadrupole field.
The deflection limiter parameter B(2,I) is phi^2/2, where phi is the angular separation (in radians) between star and body at which limiting is applied. As phi shrinks below the chosen threshold, the deflection is artificially reduced, reaching zero for phi = 0. Example values suitable for a terrestrial observer, together with masses, are as follows:
body I B(1,I) B(2,I)
Sun 1D0 6D-6
Jupiter 0.00095435D0 3D-9
Saturn 0.00028574D0 3D-10
For efficiency, validation of the B array is omitted. The supplied masses must be greater than zero, the position and velocity vectors must be right, and the deflection limiter greater than zero.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=wp), | intent(in) | :: | rc | ICRS RA at J2000.0 (radians, Note 1) |
||
| real(kind=wp), | intent(in) | :: | dc | ICRS Dec at J2000.0 (radians, Note 1) |
||
| real(kind=wp), | intent(in) | :: | pr | RA proper motion (radians/year; Note 2) |
||
| real(kind=wp), | intent(in) | :: | pd | Dec proper motion (radians/year) |
||
| real(kind=wp), | intent(in) | :: | px | parallax (arcsec) |
||
| real(kind=wp), | intent(in) | :: | rv | radial velocity (km/s, +ve if receding) |
||
| real(kind=wp), | intent(in), | dimension(30) | :: | astrom | star-independent astrometry parameters: (1) PM time interval (SSB, Julian years) (2-4) SSB to observer (vector, au) (5-7) Sun to observer (unit vector) (8) distance from Sun to observer (au) (9-11) v: barycentric observer velocity (vector, c) (12) sqrt(1-|v|^2): reciprocal of Lorenz factor (13-21) bias-precession-nutation matrix (22) longitude + s' (radians) (23) polar motion xp wrt local meridian (radians) (24) polar motion yp wrt local meridian (radians) (25) sine of geodetic latitude (26) cosine of geodetic latitude (27) magnitude of diurnal aberration vector (28) "local" Earth rotation angle (radians) (29) refraction constant A (radians) (30) refraction constant B (radians) |
|
| integer, | intent(in) | :: | n | number of bodies (Note 3) |
||
| real(kind=wp), | intent(in), | dimension(8,n) | :: | b | data for each of the NB bodies (Notes 3,4): (1,I) mass of the body (solar masses, Note 5) (2,I) deflection limiter (Note 6) (3-5,I) barycentric position of the body (au) (6-8,I) barycentric velocity of the body (au/day) |
|
| real(kind=wp), | intent(out) | :: | ri | CIRS RA (radians) |
||
| real(kind=wp), | intent(out) | :: | di | CIRS Dec (radians) |
subroutine ATCIQN ( rc, dc, pr, pd, px, rv, astrom, n, b, &
ri, di )
implicit none
real(wp),intent(in) :: rc !! ICRS RA at J2000.0 (radians, Note 1)
real(wp),intent(in) :: dc !! ICRS Dec at J2000.0 (radians, Note 1)
real(wp),intent(in) :: pr !! RA proper motion (radians/year; Note 2)
real(wp),intent(in) :: pd !! Dec proper motion (radians/year)
real(wp),intent(in) :: px !! parallax (arcsec)
real(wp),intent(in) :: rv !! radial velocity (km/s, +ve if receding)
real(wp),dimension(30),intent(in) :: astrom !! star-independent astrometry parameters:
!! (1) PM time interval (SSB, Julian years)
!! (2-4) SSB to observer (vector, au)
!! (5-7) Sun to observer (unit vector)
!! (8) distance from Sun to observer (au)
!! (9-11) v: barycentric observer velocity (vector, c)
!! (12) sqrt(1-|v|^2): reciprocal of Lorenz factor
!! (13-21) bias-precession-nutation matrix
!! (22) longitude + s' (radians)
!! (23) polar motion xp wrt local meridian (radians)
!! (24) polar motion yp wrt local meridian (radians)
!! (25) sine of geodetic latitude
!! (26) cosine of geodetic latitude
!! (27) magnitude of diurnal aberration vector
!! (28) "local" Earth rotation angle (radians)
!! (29) refraction constant A (radians)
!! (30) refraction constant B (radians)
integer,intent(in) :: n !! number of bodies (Note 3)
real(wp),dimension(8,n),intent(in) :: b !! data for each of the NB bodies (Notes 3,4):
!! (1,I) mass of the body (solar masses, Note 5)
!! (2,I) deflection limiter (Note 6)
!! (3-5,I) barycentric position of the body (au)
!! (6-8,I) barycentric velocity of the body (au/day)
real(wp),intent(out) :: ri !! CIRS RA (radians)
real(wp),intent(out) :: di !! CIRS Dec (radians)
real(wp) :: pco(3), pnat(3), ppr(3), pi(3), w
! Proper motion and parallax, giving BCRS coordinate direction.
call PMPX ( rc, dc, pr, pd, px, rv, astrom(1), astrom(2), &
pco )
! Light deflection, giving BCRS natural direction.
call LDN ( n, b, astrom(2), pco, pnat )
! Aberration, giving GCRS proper direction.
call AB (pnat, astrom(9), astrom(8), astrom(12), ppr )
! Bias-precession-nutation, giving CIRS proper direction.
call RXP ( astrom(13), ppr, pi )
! CIRS RA,Dec.
call C2S ( pi, w, di )
ri = ANP ( w )
end subroutine ATCIQN