Convert B1950.0 FK4 star catalog data to J2000.0 FK5.
Status: support routine.
This routine converts a star's catalog data from the old FK4 (Bessel-Newcomb) system to the later IAU 1976 FK5 (Fricke) system.
The proper motions in RA are dRA/dt rather than cos(Dec)*dRA/dt, and are per year rather than per century.
The conversion is somewhat complicated, for several reasons:
Change of standard epoch from B1950.0 to J2000.0.
An intermediate transition date of 1984 January 1.0 TT.
A change of precession model.
Change of time unit for proper motion (tropical to Julian).
FK4 positions include the E-terms of aberration, to simplify the hand computation of annual aberration. FK5 positions assume a rigorous aberration computation based on the Earth's barycentric velocity.
The E-terms also affect proper motions, and in particular cause objects at large distances to exhibit fictitious proper motions.
The algorithm is based on Smith et al. (1989) and Yallop et al. (1989), which presented a matrix method due to Standish (1982) as developed by Aoki et al. (1983), using Kinoshita's development of Andoyer's post-Newcomb precession. The numerical constants from Seidelmann (1992) are used canonically.
Conversion from B1950.0 FK4 to J2000.0 FK5 only is provided for. Conversions for different epochs and equinoxes would require additional treatment for precession, proper motion and E-terms.
In the FK4 catalog the proper motions of stars within 10 degrees of the poles do not embody differential E-terms effects and should, strictly speaking, be handled in a different manner from stars outside these regions. However, given the general lack of homogeneity of the star data available for routine astrometry, the difficulties of handling positions that may have been determined from astrometric fields spanning the polar and non-polar regions, the likelihood that the differential E-terms effect was not taken into account when allowing for proper motion in past astrometry, and the undesirability of a discontinuity in the algorithm, the decision has been made in this SOFA algorithm to include the effects of differential E-terms on the proper motions for all stars, whether polar or not. At epoch J2000.0, and measuring "on the sky" rather than in terms of RA change, the errors resulting from this simplification are less than 1 milliarcsecond in position and 1 milliarcsecond per century in proper motion.
Aoki, S. et al., 1983, "Conversion matrix of epoch B1950.0 FK4-based positions of stars to epoch J2000.0 positions in accordance with the new IAU resolutions". Astron.Astrophys. 128, 263-267.
Seidelmann, P.K. (ed), 1992, "Explanatory Supplement to the Astronomical Almanac", ISBN 0-935702-68-7.
Smith, C.A. et al., 1989, "The transformation of astrometric catalog systems to the equinox J2000.0". Astron.J. 97, 265.
Standish, E.M., 1982, "Conversion of positions and proper motions from B1950.0 to the IAU system at J2000.0". Astron.Astrophys., 115, 1, 20-22.
Yallop, B.D. et al., 1989, "Transformation of mean star places from FK4 B1950.0 to FK5 J2000.0 using matrices in 6-space". Astron.J. 97, 274.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=wp), | intent(in) | :: | r1950 | B1950.0 RA (rad) |
||
| real(kind=wp), | intent(in) | :: | d1950 | B1950.0 Dec (rad) |
||
| real(kind=wp), | intent(in) | :: | dr1950 | B1950.0 proper motions (rad/trop.yr) |
||
| real(kind=wp), | intent(in) | :: | dd1950 | B1950.0 proper motions (rad/trop.yr) |
||
| real(kind=wp), | intent(in) | :: | p1950 | parallax (arcsec) |
||
| real(kind=wp), | intent(in) | :: | v1950 | radial velocity (km/s, +ve = moving away) |
||
| real(kind=wp), | intent(out) | :: | r2000 | J2000.0 RA (rad) |
||
| real(kind=wp), | intent(out) | :: | d2000 | J2000.0 Dec (rad) |
||
| real(kind=wp), | intent(out) | :: | dr2000 | J2000.0 proper motions (rad/Jul.yr) |
||
| real(kind=wp), | intent(out) | :: | dd2000 | J2000.0 proper motions (rad/Jul.yr) |
||
| real(kind=wp), | intent(out) | :: | p2000 | parallax (arcsec) |
||
| real(kind=wp), | intent(out) | :: | v2000 | radial velocity (km/s, +ve = moving away) |
subroutine FK425 ( r1950, d1950, &
dr1950, dd1950, p1950, v1950, &
r2000, d2000, &
dr2000, dd2000, p2000, v2000 )
implicit none
real(wp),intent(in) :: r1950 !! B1950.0 RA (rad)
real(wp),intent(in) :: d1950 !! B1950.0 Dec (rad)
real(wp),intent(in) :: dr1950 !! B1950.0 proper motions (rad/trop.yr)
real(wp),intent(in) :: dd1950 !! B1950.0 proper motions (rad/trop.yr)
real(wp),intent(in) :: p1950 !! parallax (arcsec)
real(wp),intent(in) :: v1950 !! radial velocity (km/s, +ve = moving away)
real(wp),intent(out) :: r2000 !! J2000.0 RA (rad)
real(wp),intent(out) :: d2000 !! J2000.0 Dec (rad)
real(wp),intent(out) :: dr2000 !! J2000.0 proper motions (rad/Jul.yr)
real(wp),intent(out) :: dd2000 !! J2000.0 proper motions (rad/Jul.yr)
real(wp),intent(out) :: p2000 !! parallax (arcsec)
real(wp),intent(out) :: v2000 !! radial velocity (km/s, +ve = moving away)
! Radians per year to arcsec per century
real(wp),parameter :: pmf = 100.0_wp*60.0_wp*60.0_wp*360.0_wp/d2pi
! Small number to avoid arithmetic problems
real(wp),parameter :: tiny = 1e-30_wp
! Miscellaneous
real(wp) :: r, d, ur, ud, px, rv, pxvf, w, rd
integer :: l, k, j, i
! Pv-vectors
real(wp) :: r0(3,2), pv1(3,2), pv2(3,2), pv3(3,2)
! Functions
!
! CANONICAL CONSTANTS (Seidelmann 1992)
!
! Km per sec to AU per tropical century
! = 86400 * 36524.2198782 / 149597870.7
real(wp),parameter :: vf = 21.095_wp
! Constant pv-vector (cf. Seidelmann 3.591-2, vectors A and Adot)
real(wp),dimension(3,2),parameter :: a = reshape([&
-1.62557e-6_wp, -0.31919e-6_wp, -0.13843e-6_wp, &
+1.245e-3_wp, -1.580e-3_wp, -0.659e-3_wp ], [3,2])
! 3x2 matrix of pv-vectors (cf. Seidelmann 3.591-4, matrix M)
real(wp),dimension(3,2,3,2),parameter :: em = reshape([&
+0.9999256782_wp, -0.0111820611_wp, -0.0048579477_wp, &
+0.00000242395018_wp, -0.00000002710663_wp, -0.00000001177656_wp, &
+0.0111820610_wp, +0.9999374784_wp, -0.0000271765_wp, &
+0.00000002710663_wp, +0.00000242397878_wp, -0.00000000006587_wp, &
+0.0048579479_wp, -0.0000271474_wp, +0.9999881997_wp, &
+0.00000001177656_wp, -0.00000000006582_wp, +0.00000242410173_wp, &
-0.000551_wp, -0.238565_wp, +0.435739_wp, &
+0.99994704_wp, -0.01118251_wp, -0.00485767_wp, &
+0.238514_wp, -0.002667_wp, -0.008541_wp, &
+0.01118251_wp, +0.99995883_wp, -0.00002718_wp, &
-0.435623_wp, +0.012254_wp, +0.002117_wp, &
+0.00485767_wp, -0.00002714_wp, +1.00000956_wp ], [3,2,3,2])
! The FK4 data (units radians and arcsec per tropical century).
r = r1950
d = d1950
ur = dr1950*pmf
ud = dd1950*pmf
px = p1950
rv = v1950
! Express as a pv-vector.
pxvf = px*vf
w = rv*pxvf
call S2PV ( r, d, 1.0_wp, ur, ud, w, r0 )
! Allow for E-terms (cf. Seidelmann 3.591-2).
call PVMPV ( r0, a, pv1 )
call PDP ( r0, a, w )
call SXP ( w, r0, pv2 )
call PDP ( r0, a(1:3,2), w )
call SXP ( w, r0, pv2(1,2) )
call PVPPV ( pv1, pv2, pv3 )
! Convert pv-vector to Fricke system (cf. Seidelmann 3.591-3).
do l = 1,2
do k=1,3
w = 0.0_wp
do j=1,2
do i=1,3
w = w + em(i,j,k,l)*pv3(i,j)
end do
end do
pv1(k,l) = w
end do
end do
! Revert to catalog form.
call PV2S ( pv1, r, d, w, ur, ud, rd )
if ( px>tiny ) then
rv = rd/pxvf
px = px/w
end if
! Return the results.
r2000 = ANP(r)
d2000 = d
dr2000 = ur/pmf
dd2000 = ud/pmf
v2000 = rv
p2000 = px
end subroutine FK425