FK45Z Subroutine

  1. astro_module.f90
  2. astro_module
  3. FK45Z

public subroutine FK45Z(r1950, d1950, bepoch, r2000, d2000)

Convert a B1950.0 FK4 star position to J2000.0 FK5, assuming zero proper motion in the FK5 system.

Status: support routine.

This routine converts a star's catalog data from the old FK4 (Bessel-Newcomb) system to the later IAU 1976 FK5 (Fricke) system, in such a way that the FK5 proper motion is zero. Because such a star has, in general, a non-zero proper motion in the FK4 system, the routine requires the epoch at which the position in the FK4 system was determined.

Notes

  1. The epoch BEPOCH is strictly speaking Besselian, but if a Julian epoch is supplied the result will be affected only to a negligible extent.

  2. The method is from Appendix 2 of Aoki et al. (1983), but using the constants of Seidelmann (1992). See the routine FK425 for a general introduction to the FK4 to FK5 conversion.

  3. Conversion from equinox B1950.0 FK4 to equinox J2000.0 FK5 only is provided for. Conversions for different starting and/or ending epochs would require additional treatment for precession, proper motion and E-terms.

  4. In the FK4 catalog the proper motions of stars within 10 degrees of the poles do not embody differential E-terms effects and should, strictly speaking, be handled in a different manner from stars outside these regions. However, given the general lack of homogeneity of the star data available for routine astrometry, the difficulties of handling positions that may have been determined from astrometric fields spanning the polar and non-polar regions, the likelihood that the differential E-terms effect was not taken into account when allowing for proper motion in past astrometry, and the undesirability of a discontinuity in the algorithm, the decision has been made in this SOFA algorithm to include the effects of differential E-terms on the proper motions for all stars, whether polar or not. At epoch 2000.0, and measuring "on the sky" rather than in terms of RA change, the errors resulting from this simplification are less than 1 milliarcsecond in position and 1 milliarcsecond per century in proper motion.

References

  • Aoki, S. et al., 1983, "Conversion matrix of epoch B1950.0 FK4-based positions of stars to epoch J2000.0 positions in accordance with the new IAU resolutions". Astron.Astrophys. 128, 263-267.

  • Seidelmann, P.K. (ed), 1992, "Explanatory Supplement to the Astronomical Almanac", ISBN 0-935702-68-7.

History

  • IAU SOFA revision: 2018 January 11

Arguments

TypeIntentOptionalAttributesName
real(kind=wp), intent(in) :: r1950

B1950.0 FK4 RA at epoch (rad)
real(kind=wp), intent(in) :: d1950

B1950.0 FK4 Dec at epoch (rad)
real(kind=wp), intent(in) :: bepoch

Besselian epoch (e.g. 1979.3D0)
real(kind=wp), intent(out) :: r2000

J2000.0 FK5 RA (rad)
real(kind=wp), intent(out) :: d2000

J2000.0 FK5 Dec (rad)

Calls

proc~~fk45z~~CallsGraph proc~fk45z FK45Z proc~pdp PDP proc~fk45z->proc~pdp proc~epb2jd EPB2JD proc~fk45z->proc~epb2jd proc~pvu PVU proc~fk45z->proc~pvu proc~c2s C2S proc~fk45z->proc~c2s proc~ppsp PPSP proc~fk45z->proc~ppsp proc~s2c S2C proc~fk45z->proc~s2c proc~pmp PMP proc~fk45z->proc~pmp proc~epj EPJ proc~fk45z->proc~epj proc~anp ANP proc~fk45z->proc~anp proc~pvu->proc~ppsp

Contents

Source Code

FK45Z

Source Code

    subroutine FK45Z ( r1950, d1950, bepoch, r2000, d2000 )

    implicit none

    real(wp),intent(in) :: r1950 !! B1950.0 FK4 RA at epoch (rad)
    real(wp),intent(in) :: d1950 !! B1950.0 FK4 Dec at epoch (rad)
    real(wp),intent(in) :: bepoch !! Besselian epoch (e.g. 1979.3D0)
    real(wp),intent(out) :: r2000 !! J2000.0 FK5 RA (rad)
    real(wp),intent(out) :: d2000 !! J2000.0 FK5 Dec (rad)

    !  Radians per year to arcsec per century
    real(wp),parameter :: pmf = 100.0_wp*60.0_wp*60.0_wp*360.0_wp/d2pi

    !  Position and position+velocity vectors
    real(wp) :: r0(3), a1(3), p1(3), p2(3), pv1(3,2), pv2(3,2)

    !  Miscellaneous
    real(wp) :: w, djm0, djm
    integer :: k, j, i

    !  Functions
    !
    !  CANONICAL CONSTANTS
    !

    !  Vectors A and Adot (Seidelmann 3.591-2)
    real(wp),dimension(3),parameter :: a  = [-1.62557e-6_wp,  -0.31919e-6_wp, -0.13843e-6_wp]
    real(wp),dimension(3),parameter :: ad = [+1.245e-3_wp,    -1.580e-3_wp,   -0.659e-3_wp]

    !  3x2 matrix of p-vectors (cf. Seidelmann 3.591-4, matrix M)
    real(wp),dimension(3,3,2),parameter :: em = reshape([&
       +0.9999256782_wp,     -0.0111820611_wp,     -0.0048579477_wp, &
       +0.0111820610_wp,     +0.9999374784_wp,     -0.0000271765_wp, &
       +0.0048579479_wp,     -0.0000271474_wp,     +0.9999881997_wp, &
       -0.000551_wp,         -0.238565_wp,         +0.435739_wp, &
       +0.238514_wp,         -0.002667_wp,         -0.008541_wp, &
       -0.435623_wp,         +0.012254_wp,         +0.002117_wp ], [3,3,2])

    !  Spherical coordinates to p-vector.
    call S2C ( r1950, d1950, r0 )

    !  Adjust p-vector A to give zero proper motion in FK5.
    w = ( bepoch - 1950.0_wp ) / pmf
    call PPSP ( a, w, ad, a1 )

    !  Remove E-terms.
    call PDP ( r0, a1, w )
    call PPSP ( a1, -w, r0, p1 )
    call PMP ( r0, p1, p2 )

    !  Convert to Fricke system pv-vector (cf. Seidelmann 3.591-3).
    do k = 1,2
       do j=1,3
          w = 0.0_wp
          do i=1,3
             w = w + em(i,j,k)*p2(i)
          end do
          pv1(j,k) = w
       end do
    end do

    !  Allow for fictitious proper motion.
    call EPB2JD ( bepoch, djm0, djm )
    w = ( EPJ(djm0,djm) - 2000.0_wp ) / pmf
    call PVU ( w, pv1, pv2 )

    !  Revert to spherical coordinates.
    call C2S ( pv2, w, d2000 )
    r2000 = ANP ( w )

    end subroutine FK45Z