Convert J2000.0 FK5 star catalog data to B1950.0 FK4.
Status: support routine.
The proper motions in RA are dRA/dt rather than cos(Dec)*dRA/dt, and are per year rather than per century.
The conversion is somewhat complicated, for several reasons:
Change of standard epoch from J2000.0 to B1950.0.
An intermediate transition date of 1984 January 1.0 TT.
A change of precession model.
Change of time unit for proper motion (Julian to tropical).
FK4 positions include the E-terms of aberration, to simplify the hand computation of annual aberration. FK5 positions assume a rigorous aberration computation based on the Earth's barycentric velocity.
The E-terms also affect proper motions, and in particular cause objects at large distances to exhibit fictitious proper motions.
The algorithm is based on Smith et al. (1989) and Yallop et al. (1989), which presented a matrix method due to Standish (1982) as developed by Aoki et al. (1983), using Kinoshita's development of Andoyer's post-Newcomb precession. The numerical constants from Seidelmann (1992) are used canonically.
In the FK4 catalog the proper motions of stars within 10 degrees of the poles do not embody differential E-terms effects and should, strictly speaking, be handled in a different manner from stars outside these regions. However, given the general lack of homogeneity of the star data available for routine astrometry, the difficulties of handling positions that may have been determined from astrometric fields spanning the polar and non-polar regions, the likelihood that the differential E-terms effect was not taken into account when allowing for proper motion in past astrometry, and the undesirability of a discontinuity in the algorithm, the decision has been made in this SOFA algorithm to include the effects of differential E-terms on the proper motions for all stars, whether polar or not. At epoch J2000.0, and measuring "on the sky" rather than in terms of RA change, the errors resulting from this simplification are less than 1 milliarcsecond in position and 1 milliarcsecond per century in proper motion.
Aoki, S. et al., 1983, "Conversion matrix of epoch B1950.0 FK4-based positions of stars to epoch J2000.0 positions in accordance with the new IAU resolutions". Astron.Astrophys. 128, 263-267.
Seidelmann, P.K. (ed), 1992, "Explanatory Supplement to the Astronomical Almanac", ISBN 0-935702-68-7.
Smith, C.A. et al., 1989, "The transformation of astrometric catalog systems to the equinox J2000.0". Astron.J. 97, 265.
Standish, E.M., 1982, "Conversion of positions and proper motions from B1950.0 to the IAU system at J2000.0". Astron.Astrophys., 115, 1, 20-22.
Yallop, B.D. et al., 1989, "Transformation of mean star places from FK4 B1950.0 to FK5 J2000.0 using matrices in 6-space". Astron.J. 97, 274.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=wp), | intent(in) | :: | r2000 | J2000.0 RA (rad) |
||
| real(kind=wp), | intent(in) | :: | d2000 | J2000.0 Dec (rad) |
||
| real(kind=wp), | intent(in) | :: | dr2000 | J2000.0 proper motions (rad/Jul.yr) |
||
| real(kind=wp), | intent(in) | :: | dd2000 | J2000.0 proper motions (rad/Jul.yr) |
||
| real(kind=wp), | intent(in) | :: | p2000 | parallax (arcsec) |
||
| real(kind=wp), | intent(in) | :: | v2000 | radial velocity (km/s, +ve = moving away) |
||
| real(kind=wp), | intent(out) | :: | r1950 | B1950.0 RA (rad) |
||
| real(kind=wp), | intent(out) | :: | d1950 | B1950.0 Dec (rad) |
||
| real(kind=wp), | intent(out) | :: | dr1950 | B1950.0 proper motions (rad/trop.yr) |
||
| real(kind=wp), | intent(out) | :: | dd1950 | B1950.0 proper motions (rad/trop.yr) |
||
| real(kind=wp), | intent(out) | :: | p1950 | parallax (arcsec) |
||
| real(kind=wp), | intent(out) | :: | v1950 | radial velocity (km/s, +ve = moving away) |
subroutine FK524 ( r2000, d2000, &
dr2000, dd2000, p2000, v2000, &
r1950, d1950, &
dr1950, dd1950, p1950, v1950 )
implicit none
real(wp),intent(in) :: r2000 !! J2000.0 RA (rad)
real(wp),intent(in) :: d2000 !! J2000.0 Dec (rad)
real(wp),intent(in) :: dr2000 !! J2000.0 proper motions (rad/Jul.yr)
real(wp),intent(in) :: dd2000 !! J2000.0 proper motions (rad/Jul.yr)
real(wp),intent(in) :: p2000 !! parallax (arcsec)
real(wp),intent(in) :: v2000 !! radial velocity (km/s, +ve = moving away)
real(wp),intent(out) :: r1950 !! B1950.0 RA (rad)
real(wp),intent(out) :: d1950 !! B1950.0 Dec (rad)
real(wp),intent(out) :: dr1950 !! B1950.0 proper motions (rad/trop.yr)
real(wp),intent(out) :: dd1950 !! B1950.0 proper motions (rad/trop.yr)
real(wp),intent(out) :: p1950 !! parallax (arcsec)
real(wp),intent(out) :: v1950 !! radial velocity (km/s, +ve = moving away)
! Radians per year to arcsec per century
real(wp),parameter :: pmf = 100.0_wp*60.0_wp*60.0_wp*360.0_wp/d2pi
! Small number to avoid arithmetic problems
real(wp),parameter :: tiny = 1.0e-30_wp
! Miscellaneous
real(wp) :: r, d, ur, ud, px, rv, pxvf, w, wr, rd
integer :: l, k, j, i
! Vectors, p and pv
real(wp) :: r0(3,2), r1(3,2), p1(3), p2(3), p3(3), pv(3,2)
! Functions
!
! CANONICAL CONSTANTS (Seidelmann 1992)
!
! Km per sec to AU per tropical century
! = 86400 * 36524.2198782 / 149597870
real(wp),parameter :: vf = 21.095_wp
! Constant pv-vector (cf. Seidelmann 3.591-2, vectors A and Adot)
real(wp),dimension(3,2),parameter :: a = reshape([ -1.62557e-6_wp, &
-0.31919e-6_wp, &
-0.13843e-6_wp, & ! WARNING: there is some gfortran compiler bug here
1.245e-3_wp, &
-1.580e-3_wp, &
-0.659e-3_wp ], [3,2])
! 3x2 matrix of pv-vectors (cf. Seidelmann 3.592-1, matrix M^-1)
real(wp),dimension(3,2,3,2),parameter :: emi = reshape([&
+0.9999256795_wp, +0.0111814828_wp, +0.0048590039_wp, &
-0.00000242389840_wp, -0.00000002710544_wp, -0.00000001177742_wp, &
-0.0111814828_wp, +0.9999374849_wp, -0.0000271771_wp, &
+0.00000002710544_wp, -0.00000242392702_wp, +0.00000000006585_wp, &
-0.0048590040_wp, -0.0000271557_wp, +0.9999881946_wp, &
+0.00000001177742_wp, +0.00000000006585_wp, -0.00000242404995_wp, &
-0.000551_wp, +0.238509_wp, -0.435614_wp, &
+0.99990432_wp, +0.01118145_wp, +0.00485852_wp, &
-0.238560_wp, -0.002667_wp, +0.012254_wp, &
-0.01118145_wp, +0.99991613_wp, -0.00002717_wp, &
+0.435730_wp, -0.008541_wp, +0.002117_wp, &
-0.00485852_wp, -0.00002716_wp, +0.99996684_wp ], [3,2,3,2])
! The FK5 data (units radians and arcsec per Julian century).
r = r2000
d = d2000
ur = dr2000*pmf
ud = dd2000*pmf
px = p2000
rv = v2000
! Express as a pv-vector.
pxvf = px*vf
w = rv*pxvf
call S2PV ( r, d, 1.0_wp, ur, ud, w, r0 )
! Convert pv-vector to Bessel-Newcomb system (cf. Seidelmann 3.592-1).
do l = 1,2
do k=1,3
w = 0.0_wp
do j=1,2
do i=1,3
w = w + emi(i,j,k,l)*r0(i,j)
end do
end do
r1(k,l) = w
end do
end do
! Apply E-terms (equivalent to Seidelmann 3.592-3, two iterations).
! Direction.
call PM ( r1, wr )
call PDP ( r1, a, w )
call SXP ( w, r1, p1 )
call SXP ( wr, a, p2 )
call PMP ( p2, p1, p3 )
call PPP ( r1, p3, p1 )
! Recompute length.
call PM ( p1, wr )
! Direction.
call PDP ( r1, a, w )
call SXP ( w, r1, p1 )
call SXP ( wr, a, p2 )
call PMP ( p2, p1, p3 )
call PPP ( r1, p3, pv )
! Derivative.
call PDP ( r1, a(1:3,2), w )
call SXP ( w, pv, p1 )
call SXP ( wr, a(1:3,2), p2 )
call PMP ( p2, p1, p3 )
call PPP ( r1(1,2), p3, pv(1,2) )
! Revert to catalog form.
call PV2S ( pv, r, d, w, ur, ud, rd )
if ( px>tiny ) then
rv = rd/pxvf
px = px/w
end if
! Return the results.
r1950 = ANP(r)
d1950 = d
dr1950 = ur/pmf
dd1950 = ud/pmf
p1950 = px
v1950 = rv
end subroutine FK524