GMST00 Function

  1. astro_module.f90
  2. astro_module
  3. GMST00

public function GMST00(uta, utb, tta, ttb) result(gmst)

Greenwich Mean Sidereal Time (model consistent with IAU 2000 resolutions).

Status: canonical model.

Notes

  1. The UT1 and TT dates UTA+UTB and TTA+TTB respectively, are both Julian Dates, apportioned in any convenient way between the argument pairs. For example, JD=2450123.7 could be expressed in any of these ways, among others:

        Part A         Part B

 2450123.7D0        0D0        (JD method)
  2451545D0      -1421.3D0     (J2000 method)
 2400000.5D0     50123.2D0     (MJD method)
 2450123.5D0       0.2D0       (date & time method)

    The JD method is the most natural and convenient to use in cases where the loss of several decimal digits of resolution is acceptable (in the case of UT; the TT is not at all critical in this respect). The J2000 and MJD methods are good compromises between resolution and convenience. For UT, the date & time method is best matched to the algorithm that is used by the Earth Rotation Angle routine, called internally: maximum accuracy (or, at least, minimum noise) is delivered when the UTA argument is for 0hrs UT1 on the day in question and the UTB argument lies in the range 0 to 1, or vice versa.

  2. Both UT1 and TT are required, UT1 to predict the Earth rotation and TT to predict the effects of precession. If UT1 is used for both purposes, errors of order 100 microarcseconds result.

  3. This GMST is compatible with the IAU 2000 resolutions and must be used only in conjunction with other IAU 2000 compatible components such as precession-nutation and equation of the equinoxes.

  4. The result is returned in the range 0 to 2pi.

  5. The algorithm is from Capitaine et al. (2003) and IERS Conventions 2003.

References

  • Capitaine, N., Wallace, P.T. and McCarthy, D.D., "Expressions to implement the IAU 2000 definition of UT1", Astronomy & Astrophysics, 406, 1135-1149 (2003)

  • McCarthy, D. D., Petit, G. (eds.), IERS Conventions (2003), IERS Technical Note No. 32, BKG (2004)

History

  • IAU SOFA revision: 2009 December 15

Arguments

TypeIntentOptionalAttributesName
real(kind=wp), intent(in) :: uta

UT1 as a 2-part Julian Date (Notes 1,2)
real(kind=wp), intent(in) :: utb

UT1 as a 2-part Julian Date (Notes 1,2)
real(kind=wp), intent(in) :: tta

TT as a 2-part Julian Date (Notes 1,2)
real(kind=wp), intent(in) :: ttb

TT as a 2-part Julian Date (Notes 1,2)

Return Value real(kind=wp)

Greenwich mean sidereal time (radians)


Calls

proc~~gmst00~~CallsGraph proc~gmst00 GMST00 proc~anp ANP proc~gmst00->proc~anp proc~era00 ERA00 proc~gmst00->proc~era00 proc~era00->proc~anp

Called by

proc~~gmst00~~CalledByGraph proc~gmst00 GMST00 proc~gst00a GST00A proc~gst00a->proc~gmst00 proc~gst00b GST00B proc~gst00b->proc~gmst00 proc~c2tpe C2TPE proc~c2tpe->proc~gmst00

Contents

Source Code

GMST00

Source Code

    function GMST00 ( uta, utb, tta, ttb ) result(gmst)

    implicit none

    real(wp),intent(in) :: uta !! UT1 as a 2-part Julian Date (Notes 1,2)
    real(wp),intent(in) :: utb !! UT1 as a 2-part Julian Date (Notes 1,2)
    real(wp),intent(in) :: tta !! TT as a 2-part Julian Date (Notes 1,2)
    real(wp),intent(in) :: ttb !! TT as a 2-part Julian Date (Notes 1,2)
    real(wp) :: gmst !! Greenwich mean sidereal time (radians)

    real(wp) :: t

    !  TT Julian centuries since J2000.0.
    t = ( ( tta-dj00 ) + ttb ) / djc

    !  Greenwich Mean Sidereal Time, IAU 2000.
    gmst = ANP ( ERA00 ( uta, utb ) + &
                       (    0.014506_wp   + &
                       ( 4612.15739966_wp + &
                       (  + 1.39667721_wp + &
                       (  - 0.00009344_wp + &
                       (  + 0.00001882_wp ) &
                           * t ) * t ) * t ) * t ) * das2r )

    end function GMST00