GMST82 Function

  1. astro_module.f90
  2. astro_module
  3. GMST82

public function GMST82(dj1, dj2) result(gmst)

Universal Time to Greenwich Mean Sidereal Time (IAU 1982 model).

Status: canonical model.

Notes

  1. The UT1 epoch DJ1+DJ2 is a Julian Date, apportioned in any convenient way between the arguments DJ1 and DJ2. For example, JD(UT1)=2450123.7 could be expressed in any of these ways, among others:

         DJ1            DJ2

 2450123.7D0        0D0        (JD method)
  2451545D0      -1421.3D0     (J2000 method)
 2400000.5D0     50123.2D0     (MJD method)
 2450123.5D0       0.2D0       (date & time method)

    The JD method is the most natural and convenient to use in cases where the loss of several decimal digits of resolution is acceptable. The J2000 and MJD methods are good compromises between resolution and convenience. The date & time method is best matched to the algorithm used: maximum accuracy (or, at least, minimum noise) is delivered when the DJ1 argument is for 0hrs UT1 on the day in question and the DJ2 argument lies in the range 0 to 1, or vice versa.

  2. The algorithm is based on the IAU 1982 expression. This is always described as giving the GMST at 0 hours UT1. In fact, it gives the difference between the GMST and the UT, the steady 4-minutes-per-day drawing-ahead of ST with respect to UT. When whole days are ignored, the expression happens to equal the GMST at 0 hours UT1 each day.

  3. In this routine, the entire UT1 (the sum of the two arguments DJ1 and DJ2) is used directly as the argument for the standard formula, the constant term of which is adjusted by 12 hours to take account of the noon phasing of Julian Date. The UT1 is then added, but omitting whole days to conserve accuracy.

  4. The result is returned in the range 0 to 2pi.

References

  • Transactions of the International Astronomical Union, XVIII B, 67 (1983).

  • Aoki et al., Astron.Astrophys., 105, 359-361 (1982).

History

  • IAU SOFA revision: 2017 October 12

Arguments

TypeIntentOptionalAttributesName
real(kind=wp), intent(in) :: dj1

UT1 Julian Date (see note)
real(kind=wp), intent(in) :: dj2

UT1 Julian Date (see note)

Return Value real(kind=wp)

Greenwich mean sidereal time (radians)


Calls

proc~~gmst82~~CallsGraph proc~gmst82 GMST82 proc~anp ANP proc~gmst82->proc~anp

Called by

proc~~gmst82~~CalledByGraph proc~gmst82 GMST82 proc~gst94 GST94 proc~gst94->proc~gmst82

Contents

Source Code

GMST82

Source Code

    function GMST82 ( dj1, dj2 ) result(gmst)

    implicit none

    real(wp),intent(in) :: dj1 !! UT1 Julian Date (see note)
    real(wp),intent(in) :: dj2 !! UT1 Julian Date (see note)
    real(wp) :: gmst !! Greenwich mean sidereal time (radians)

    !  Coefficients of IAU 1982 GMST-UT1 model
    real(wp),parameter :: a = 24110.54841_wp - d2s/2.0_wp
    real(wp),parameter :: b = 8640184.812866_wp
    real(wp),parameter :: c = 0.093104_wp
    real(wp),parameter :: d = -6.2e-6_wp

    !  Note: the first constant, A, has to be adjusted by 12 hours because
    !  the UT1 is supplied as a Julian date, which begins at noon.

    real(wp) :: d1, d2, t, f

    !  Julian centuries since fundamental epoch.
    if ( dj1 < dj2 ) then
       d1 = dj1
       d2 = dj2
    else
       d1 = dj2
       d2 = dj1
    end if
    t = ( d1 + ( d2-dj00 ) ) / djc

    !  Fractional part of JD(UT1), in seconds.
    f = d2s * ( mod(d1,1.0_wp) + mod(d2,1.0_wp) )

    !  GMST at this UT1.
    gmst = ANP ( ds2r * ( (a+(b+(c+d*t)*t)*t) + f ) )

    end function GMST82