Transform a Hipparcos star position into FK5 J2000.0, assuming zero Hipparcos proper motion.
Status: support routine.
The TDB date DATE1+DATE2 is a Julian Date, apportioned in any convenient way between the two arguments. For example, JD(TDB)=2450123.7 could be expressed in any of these ways, among others:
DATE1 DATE2
2450123.7D0 0D0 (JD method)
2451545D0 -1421.3D0 (J2000 method)
2400000.5D0 50123.2D0 (MJD method)
2450123.5D0 0.2D0 (date & time method)
The JD method is the most natural and convenient to use in cases where the loss of several decimal digits of resolution is acceptable. The J2000 method is best matched to the way the argument is handled internally and will deliver the optimum resolution. The MJD method and the date & time methods are both good compromises between resolution and convenience.
The proper motion in RA is dRA/dt rather than cos(Dec)*dRA/dt.
The FK5 to Hipparcos transformation is modeled as a pure rotation and spin; zonal errors in the FK5 catalogue are not taken into account.
It was the intention that Hipparcos should be a close approximation to an inertial frame, so that distant objects have zero proper motion; such objects have (in general) non-zero proper motion in FK5, and this routine returns those fictitious proper motions.
The position returned by this routine is in the FK5 J2000.0 reference system but at date DATE1+DATE2.
See also FK52H, H2FK5, FK5ZHZ.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=wp), | intent(in) | :: | rh | Hipparcos RA (radians) |
||
| real(kind=wp), | intent(in) | :: | dh | Hipparcos Dec (radians) |
||
| real(kind=wp), | intent(in) | :: | date1 | TDB date (Note 1) |
||
| real(kind=wp), | intent(in) | :: | date2 | TDB date (Note 1) |
||
| real(kind=wp), | intent(out) | :: | r5 | RA (radians) [FK5, equinox J2000.0, date DATE1+DATE2] |
||
| real(kind=wp), | intent(out) | :: | d5 | Dec (radians) [FK5, equinox J2000.0, date DATE1+DATE2] |
||
| real(kind=wp), | intent(out) | :: | dr5 | FK5 RA proper motion (rad/year, Note 4) [FK5, equinox J2000.0, date DATE1+DATE2] |
||
| real(kind=wp), | intent(out) | :: | dd5 | Dec proper motion (rad/year, Note 4) [FK5, equinox J2000.0, date DATE1+DATE2] |
subroutine HFK5Z ( rh, dh, date1, date2, r5, d5, dr5, dd5 )
implicit none
real(wp),intent(in) :: rh !! Hipparcos RA (radians)
real(wp),intent(in) :: dh !! Hipparcos Dec (radians)
real(wp),intent(in) :: date1 !! TDB date (Note 1)
real(wp),intent(in) :: date2 !! TDB date (Note 1)
real(wp),intent(out) :: r5 !! RA (radians) [FK5, equinox J2000.0, date DATE1+DATE2]
real(wp),intent(out) :: d5 !! Dec (radians) [FK5, equinox J2000.0, date DATE1+DATE2]
real(wp),intent(out) :: dr5 !! FK5 RA proper motion (rad/year, Note 4) [FK5, equinox J2000.0, date DATE1+DATE2]
real(wp),intent(out) :: dd5 !! Dec proper motion (rad/year, Note 4) [FK5, equinox J2000.0, date DATE1+DATE2]
real(wp) :: t, ph(3), r5h(3,3), s5h(3), sh(3), vst(3), &
rst(3,3), r5ht(3,3), pv5e(3,2), vv(3), &
w, r, v
! Time interval from fundamental epoch J2000.0 to given date (JY).
t = ( ( date1-dj00 ) + date2 ) / djy
! Hipparcos barycentric position vector (normalized).
call S2C ( rh, dh, ph )
! FK5 to Hipparcos orientation matrix and spin vector.
call FK5HIP ( r5h, s5h )
! Rotate the spin into the Hipparcos system.
call RXP ( r5h, s5h, sh )
! Accumulated Hipparcos wrt FK5 spin over that interval.
call SXP ( t, s5h, vst )
! Express the accumulated spin as a rotation matrix.
call RV2M ( vst, rst )
! Rotation matrix: accumulated spin, then FK5 to Hipparcos.
call RXR ( r5h, rst, r5ht )
! De-orient & de-spin the Hipparcos position into FK5 J2000.0.
call TRXP ( r5ht, ph, pv5e )
! Apply spin to the position giving a space motion.
call PXP ( sh, ph, vv )
! De-orient & de-spin the Hipparcos space motion into FK5 J2000.0.
call TRXP ( r5ht, vv, pv5e(1,2) )
! FK5 position/velocity pv-vector to spherical.
call PV2S ( pv5e, w, d5, r, dr5, dd5, v )
r5 = ANP ( w )
end subroutine HFK5Z