ICRS2G Subroutine

  1. astro_module.f90
  2. astro_module
  3. ICRS2G

public subroutine ICRS2G(dr, dd, dl, db)

Transformation from ICRS to Galactic Coordinates.

Status: support routine.

Notes

  1. The IAU 1958 system of Galactic coordinates was defined with respect to the now obsolete reference system FK4 B1950.0. When interpreting the system in a modern context, several factors have to be taken into account:

    • The inclusion in FK4 positions of the E-terms of aberration.

    • The distortion of the FK4 proper motion system by differential Galactic rotation.

    • The use of the B1950.0 equinox rather than the now-standard J2000.0.

    • The frame bias between ICRS and the J2000.0 mean place system.

    The Hipparcos Catalogue (Perryman & ESA 1997) provides a rotation matrix that transforms directly between ICRS and Galactic coordinates with the above factors taken into account. The matrix is derived from three angles, namely the ICRS coordinates of the Galactic pole and the longitude of the ascending node of the galactic equator on the ICRS equator. They are given in degrees to five decimal places and for canonical purposes are regarded as exact. In the Hipparcos Catalogue the matrix elements are given to 10 decimal places (about 20 microarcsec). In the present SOFA routine the matrix elements have been recomputed from the canonical three angles and are given to 30 decimal places.

  2. The inverse transformation is performed by the routine G2ICRS.

Reference

  • Perryman M.A.C. & ESA, 1997, ESA SP-1200, The Hipparcos and Tycho catalogues. Astrometric and photometric star catalogues derived from the ESA Hipparcos Space Astrometry Mission. ESA Publications Division, Noordwijk, Netherlands.

History

  • IAU SOFA revision: 2015 January 9

Arguments

TypeIntentOptionalAttributesName
real(kind=wp), intent(in) :: dr

ICRS right ascension (radians)
real(kind=wp), intent(in) :: dd

ICRS declination (radians)
real(kind=wp), intent(out) :: dl

galactic longitude (radians)
real(kind=wp), intent(out) :: db

galactic latitude (radians)

Calls

proc~~icrs2g~~CallsGraph proc~icrs2g ICRS2G proc~anpm ANPM proc~icrs2g->proc~anpm proc~c2s C2S proc~icrs2g->proc~c2s proc~rxp RXP proc~icrs2g->proc~rxp proc~anp ANP proc~icrs2g->proc~anp proc~s2c S2C proc~icrs2g->proc~s2c

Contents

Source Code

ICRS2G

Source Code

    subroutine ICRS2G ( dr, dd, dl, db )

    implicit none

    real(wp),intent(in) :: dr !! ICRS right ascension (radians)
    real(wp),intent(in) :: dd !! ICRS declination (radians)
    real(wp),intent(out) :: dl !! galactic longitude (radians)
    real(wp),intent(out) :: db !! galactic latitude (radians)

    real(wp) v1(3), v2(3)

    !
    !  L2,B2 system of galactic coordinates in the form presented in the
    !  Hipparcos Catalogue.  In degrees:
    !
    !  P = 192.85948    right ascension of the Galactic north pole in ICRS
    !  Q =  27.12825    declination of the Galactic north pole in ICRS
    !  R =  32.93192    longitude of the ascending node of the Galactic
    !                   plane on the ICRS equator
    !
    !  ICRS to galactic rotation matrix, obtained by computing
    !  R_3(-R) R_1(pi/2-Q) R_3(pi/2+P) to the full precision shown:
    !
    real(wp),dimension(3,3),parameter :: r = transpose(reshape([&
        -0.054875560416215368492398900454_wp, &
        -0.873437090234885048760383168409_wp, &
        -0.483835015548713226831774175116_wp, &
        +0.494109427875583673525222371358_wp, &
        -0.444829629960011178146614061616_wp, &
        +0.746982244497218890527388004556_wp, &
        -0.867666149019004701181616534570_wp, &
        -0.198076373431201528180486091412_wp, &
        +0.455983776175066922272100478348_wp ], [3,3]))

    !  Spherical to Cartesian.
    call S2C ( dr, dd, v1 )

    !  ICRS to Galactic.
    call RXP ( r, v1, v2 )

    !  Cartesian to spherical.
    call C2S ( v2, dl, db )

    !  Express in conventional ranges.
    dl = ANP ( dl )
    db = ANPM ( db )

    end subroutine ICRS2G