Precession angles, IAU 2006, equinox based.
Status: canonical models.
The TT date DATE1+DATE2 is a Julian Date, apportioned in any convenient way between the two arguments. For example, JD(TT)=2450123.7 could be expressed in any of these ways, among others
DATE1 DATE2
2450123.7D0 0D0 (JD method)
2451545D0 -1421.3D0 (J2000 method)
2400000.5D0 50123.2D0 (MJD method)
2450123.5D0 0.2D0 (date & time method)
The JD method is the most natural and convenient to use in cases where the loss of several decimal digits of resolution is acceptable. The J2000 method is best matched to the way the argument is handled internally and will deliver the optimum resolution. The MJD method and the date & time methods are both good compromises between resolution and convenience.
This routine returns the set of equinox based angles for the Capitaine et al. "P03" precession theory, adopted by the IAU in
EPS0 epsilon_0 obliquity at J2000.0 PSIA psi_A luni-solar precession OMA omega_A inclination of equator wrt J2000.0 ecliptic BPA P_A ecliptic pole x, J2000.0 ecliptic triad BQA Q_A ecliptic pole -y, J2000.0 ecliptic triad PIA pi_A angle between moving and J2000.0 ecliptics BPIA Pi_A longitude of ascending node of the ecliptic EPSA epsilon_A obliquity of the ecliptic CHIA chi_A planetary precession ZA z_A equatorial precession: -3rd 323 Euler angle ZETAA zeta_A equatorial precession: -1st 323 Euler angle THETAA theta_A equatorial precession: 2nd 323 Euler angle PA p_A general precession GAM gamma_J2000 J2000.0 RA difference of ecliptic poles PHI phi_J2000 J2000.0 codeclination of ecliptic pole PSI psi_J2000 longitude difference of equator poles, J2000.0
The returned values are all radians.
Hilton et al. (2006) Table 1 also contains angles that depend on models distinct from the P03 precession theory itself, namely the IAU 2000A frame bias and nutation. The quoted polynomials are used in other SOFA routines:
XY06 contains the polynomial parts of the X and Y series.
S06 contains the polynomial part of the s+XY/2 series.
PFW06 implements the series for the Fukushima-Williams angles that are with respect to the GCRS pole (i.e. the variants that include frame bias).
The IAU resolution stipulated that the choice of parameterization was left to the user, and so an IAU compliant precession implementation can be constructed using various combinations of the angles returned by the present routine.
The parameterization used by SOFA is the version of the Fukushima- Williams angles that refers directly to the GCRS pole. These angles may be calculated by calling the routine PFW06. SOFA also supports the direct computation of the CIP GCRS X,Y by series, available by calling XY06.
The agreement between the different parameterizations is at the 1 microarcsecond level in the present era.
When constructing a precession formulation that refers to the GCRS pole rather than the dynamical pole, it may (depending on the choice of angles) be necessary to introduce the frame bias explicitly.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=wp), | intent(in) | :: | date1 | TT as a 2-part Julian Date (Note 1) |
||
| real(kind=wp), | intent(in) | :: | date2 | TT as a 2-part Julian Date (Note 1) |
||
| real(kind=wp), | intent(out) | :: | eps0 | epsilon_0 [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | psia | psi_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | oma | omega_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | bpa | P_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | bqa | Q_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | pia | pi_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | bpia | Pi_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | epsa | obliquity epsilon_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | chia | chi_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | za | z_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | zetaa | zeta_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | thetaa | theta_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | pa | p_A [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | gam | F-W angle gamma_J2000 [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | phi | F-W angle phi_J2000 [see Note 2] |
||
| real(kind=wp), | intent(out) | :: | psi | F-W angle psi_J2000 [see Note 2] |
subroutine P06E ( date1, date2, &
eps0, psia, oma, bpa, bqa, pia, bpia, &
epsa, chia, za, zetaa, thetaa, pa, &
gam, phi, psi )
implicit none
real(wp),intent(in) :: date1 !! TT as a 2-part Julian Date (Note 1)
real(wp),intent(in) :: date2 !! TT as a 2-part Julian Date (Note 1)
real(wp),intent(out) :: eps0 !! epsilon_0 [see Note 2]
real(wp),intent(out) :: psia !! psi_A [see Note 2]
real(wp),intent(out) :: oma !! omega_A [see Note 2]
real(wp),intent(out) :: bpa !! P_A [see Note 2]
real(wp),intent(out) :: bqa !! Q_A [see Note 2]
real(wp),intent(out) :: pia !! pi_A [see Note 2]
real(wp),intent(out) :: bpia !! Pi_A [see Note 2]
real(wp),intent(out) :: epsa !! obliquity epsilon_A [see Note 2]
real(wp),intent(out) :: chia !! chi_A [see Note 2]
real(wp),intent(out) :: za !! z_A [see Note 2]
real(wp),intent(out) :: zetaa !! zeta_A [see Note 2]
real(wp),intent(out) :: thetaa !! theta_A [see Note 2]
real(wp),intent(out) :: pa !! p_A [see Note 2]
real(wp),intent(out) :: gam !! F-W angle gamma_J2000 [see Note 2]
real(wp),intent(out) :: phi !! F-W angle phi_J2000 [see Note 2]
real(wp),intent(out) :: psi !! F-W angle psi_J2000 [see Note 2]
real(wp) :: t
! Interval between fundamental date J2000.0 and given date (JC).
t = ( ( date1-dj00 ) + date2 ) / djc
! Obliquity at J2000.0.
eps0 = 84381.406_wp * das2r
! Luni-solar precession.
psia = ( 5038.481507_wp + &
( -1.0790069_wp + &
( -0.00114045_wp + &
( 0.000132851_wp + &
( -0.0000000951_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
! Inclination of mean equator with respect to the J2000.0 ecliptic.
oma = eps0 + ( -0.025754_wp + &
( 0.0512623_wp + &
( -0.00772503_wp + &
( -0.000000467_wp + &
( 0.0000003337_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
! Ecliptic pole x, J2000.0 ecliptic triad.
bpa = ( 4.199094_wp + &
( 0.1939873_wp + &
( -0.00022466_wp + &
( -0.000000912_wp + &
( 0.0000000120_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
! Ecliptic pole -y, J2000.0 ecliptic triad.
bqa = ( -46.811015_wp + &
( 0.0510283_wp + &
( 0.00052413_wp + &
( -0.000000646_wp + &
( -0.0000000172_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
! Angle between moving and J2000.0 ecliptics.
pia = ( 46.998973_wp + &
( -0.0334926_wp + &
( -0.00012559_wp + &
( 0.000000113_wp + &
( -0.0000000022_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
! Longitude of ascending node of the moving ecliptic.
bpia = ( 629546.7936_wp + &
( -867.95758_wp + &
( 0.157992_wp + &
( -0.0005371_wp + &
( -0.00004797_wp + &
( 0.000000072_wp ) &
* t ) * t ) * t ) * t ) * t ) * das2r
! Mean obliquity of the ecliptic.
epsa = OBL06 ( date1, date2 )
! Planetary precession.
chia = ( 10.556403_wp + &
( -2.3814292_wp + &
( -0.00121197_wp + &
( 0.000170663_wp + &
( -0.0000000560_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
! Equatorial precession: minus the third of the 323 Euler angles.
za = ( -2.650545_wp + &
( 2306.077181_wp + &
( 1.0927348_wp + &
( 0.01826837_wp + &
( -0.000028596_wp + &
( -0.0000002904_wp ) &
* t ) * t ) * t ) * t ) * t ) * das2r
! Equatorial precession: minus the first of the 323 Euler angles.
zetaa = ( 2.650545_wp + &
( 2306.083227_wp + &
( 0.2988499_wp + &
( 0.01801828_wp + &
( -0.000005971_wp + &
( -0.0000003173_wp ) &
* t ) * t ) * t ) * t ) * t ) * das2r
! Equatorial precession: second of the 323 Euler angles.
thetaa = ( 2004.191903_wp + &
( -0.4294934_wp + &
( -0.04182264_wp + &
( -0.000007089_wp + &
( -0.0000001274_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
! General precession.
pa = ( 5028.796195_wp + &
( 1.1054348_wp + &
( 0.00007964_wp + &
( -0.000023857_wp + &
( 0.0000000383_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
! Fukushima-Williams angles for precession.
gam = ( 10.556403_wp + &
( 0.4932044_wp + &
( -0.00031238_wp + &
( -0.000002788_wp + &
( 0.0000000260_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
phi = eps0 + ( -46.811015_wp + &
( 0.0511269_wp + &
( 0.00053289_wp + &
( -0.000000440_wp + &
( -0.0000000176_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
psi = ( 5038.481507_wp + &
( 1.5584176_wp + &
( -0.00018522_wp + &
( -0.000026452_wp + &
( -0.0000000148_wp ) &
* t ) * t ) * t ) * t ) * t * das2r
end subroutine P06E