PREC76 Subroutine

public subroutine PREC76(date01, date02, date11, date12, zeta, z, theta)

IAU 1976 precession model.

This routine forms the three Euler angles which implement general precession between two dates, using the IAU 1976 model (as for the FK5 catalog).

Status: canonical model.

Notes

1. The dates DATE01+DATE02 and DATE11+DATE12 are Julian Dates, apportioned in any convenient way between the arguments DATEn1 and DATEn2. For example, JD(TDB)=2450123.7 could be expressed in any of these ways, among others:

      DATEn1         DATEn2
   
    2450123.7D0        0D0        (JD method)
     2451545D0      -1421.3D0     (J2000 method)
    2400000.5D0     50123.2D0     (MJD method)
    2450123.5D0       0.2D0       (date & time method)
   

   The JD method is the most natural and convenient to use in cases where the loss of several decimal digits of resolution is acceptable. The J2000 method is best matched to the way the argument is handled internally and will deliver the optimum optimum resolution. The MJD method and the date & time methods are both good compromises between resolution and convenience. The two dates may be expressed using different methods, but at the risk of losing some resolution.

2. The accumulated precession angles zeta, z, theta are expressed through canonical polynomials which are valid only for a limited time span. In addition, the IAU 1976 precession rate is known to be imperfect. The absolute accuracy of the present formulation is better than 0.1 arcsec from 1960AD to 2040AD, better than 1 arcsec from 1640AD to 2360AD, and remains below 3 arcsec for the whole of the period 500BC to 3000AD. The errors exceed 10 arcsec outside the range 1200BC to 3900AD, exceed 100 arcsec outside 4200BC to 5600AD and exceed 1000 arcsec outside 6800BC to 8200AD.

3. The three angles are returned in the conventional order, which is not the same as the order of the corresponding Euler rotations. The precession matrix is R_3(-z) x R_2(+theta) x R_3(-zeta).

Reference

• Lieske, J.H., 1979, Astron.Astrophys. 73, 282. equations (6) & (7), p283.

History

• IAU SOFA revision: 2013 November 19

Arguments

    subroutine PREC76 ( date01, date02, date11, date12, &
                        zeta, z, theta )

    implicit none

    real(wp),intent(in) :: date01 !! TDB starting date (Note 1)
    real(wp),intent(in) :: date02 !! TDB starting date (Note 1)
    real(wp),intent(in) :: date11 !! TDB ending date (Note 1)
    real(wp),intent(in) :: date12 !! TDB ending date (Note 1)
    real(wp),intent(out) :: zeta !! 1st rotation: radians clockwise around z
    real(wp),intent(out) :: z !! 3rd rotation: radians clockwise around z
    real(wp),intent(out) :: theta !! 2nd rotation: radians counterclockwise around y

    real(wp) :: t0, t, tas2r, w

    !  Interval between fundamental epoch J2000.0 and start date (JC).
    t0 = ( ( date01-dj00 ) + date02 ) / djc

    !  Interval over which precession required (JC).
    t = ( ( date11-date01 ) + ( date12-date02 ) ) / djc

    !  Euler angles.
    tas2r = t * das2r
    w = 2306.2181_wp + ( &
           1.39656_wp &
         - 0.000139_wp * t0 ) * t0

    zeta = ( w + ( ( 0.30188_wp &
                   - 0.000344_wp * t0 ) &
                   + 0.017998_wp * t ) * t ) * tas2r

    z = ( w + ( ( 1.09468_wp &
                + 0.000066_wp * t0 ) &
                + 0.018203_wp * t ) * t ) * tas2r

    theta = ( ( 2004.3109_wp + ( &
                 - 0.85330_wp &
                 - 0.000217_wp * t0 ) * t0 ) + ( ( &
                 - 0.42665_wp &
                 - 0.000217_wp * t0 ) &
                 - 0.041833_wp * t ) * t ) * tas2r

    end subroutine PREC76