TCBTDB Subroutine

  1. astro_module.f90
  2. astro_module
  3. TCBTDB

public subroutine TCBTDB(tcb1, tcb2, tdb1, tdb2, j)

Time scale transformation: Barycentric Coordinate Time, TCB, to Barycentric Dynamical Time, TDB.

Status: canonical.

Notes

  1. TCB1+TCB2 is Julian Date, apportioned in any convenient way between the two arguments, for example where TCB1 is the Julian Day Number and TCB2 is the fraction of a day. The returned TDB1,TDB2 follow suit.

  2. The 2006 IAU General Assembly introduced a conventional linear transformation between TDB and TCB. This transformation compensates for the drift between TCB and terrestrial time TT, and keeps TDB approximately centered on TT. Because the relationship between TT and TCB depends on the adopted solar system ephemeris, the degree of alignment between TDB and TT over long intervals will vary according to which ephemeris is used. Former definitions of TDB attempted to avoid this problem by stipulating that TDB and TT should differ only by periodic effects. This is a good description of the nature of the relationship but eluded precise mathematical formulation. The conventional linear relationship adopted in 2006 sidestepped these difficulties whilst delivering a TDB that in practice was consistent with values before that date.

  3. TDB is essentially the same as Teph, the time argument for the JPL solar system ephemerides.

Reference

  • IAU 2006 Resolution B3

History

  • IAU SOFA revision: 2019 June 20

Arguments

TypeIntentOptionalAttributesName
real(kind=wp), intent(in) :: tcb1

TCB as a 2-part Julian Date
real(kind=wp), intent(in) :: tcb2

TCB as a 2-part Julian Date
real(kind=wp), intent(out) :: tdb1

TDB as a 2-part Julian Date
real(kind=wp), intent(out) :: tdb2

TDB as a 2-part Julian Date
integer, intent(out) :: j

Contents

Source Code

TCBTDB

Source Code

    subroutine TCBTDB ( tcb1, tcb2, tdb1, tdb2, j )

    implicit none

    real(wp),intent(in) :: tcb1 !! TCB as a 2-part Julian Date
    real(wp),intent(in) :: tcb2 !! TCB as a 2-part Julian Date
    real(wp),intent(out) :: tdb1 !! TDB as a 2-part Julian Date
    real(wp),intent(out) :: tdb2 !! TDB as a 2-part Julian Date
    integer,intent(out) :: j !! status:  0 = OK

    !  1977 Jan 1.0 TAI = 1977/1/1 00:00:32.184 TCB, as two-part JD
    real(wp),parameter :: t77td = 2443144.0_wp
    real(wp),parameter :: t77tf = 0.5003725_wp

    !  L_B, and TDB0 (d)
    real(wp),parameter :: elb = 1.550519768e-8_wp
    real(wp),parameter :: tdb0 = -6.55e-5_wp/86400.0_wp

    real(wp) :: d

    !  Result, safeguarding precision.
    if ( abs(tcb1)>abs(tcb2) ) then
       d = tcb1 - t77td
       tdb1 = tcb1
       tdb2 = tcb2 + tdb0 - ( d + ( tcb2-t77tf ) ) * elb
    else
       d = tcb2 - t77td
       tdb1 = tcb1 + tdb0 - ( d + ( tcb1-t77tf ) ) * elb
       tdb2 = tcb2
    end if

    !  Status (always OK).
    j = 0

    end subroutine TCBTDB