TPORS Subroutine

public subroutine TPORS(xi, eta, a, b, a01, b01, a02, b02, n)

In the tangent plane projection, given the rectangular coordinates of a star and its spherical coordinates, determine the spherical coordinates of the tangent point.

Status: support routine.

Notes

1. The tangent plane projection is also called the "gnomonic projection" and the "central projection".

2. The eta axis points due north in the adopted coordinate system. If the spherical coordinates are observed (RA,Dec), the tangent plane coordinates (xi,eta) are conventionally called the "standard coordinates". If the spherical coordinates are with respect to a right-handed triad, (xi,eta) are also right-handed. The units of (xi,eta) are, effectively, radians at the tangent point.

3. All angular arguments are in radians.

4. The angles A01 and A02 are returned in the range 0-2pi. The angles B01 and B02 are returned in the range +/-pi, but in the usual, non-pole-crossing, case, the range is +/-pi/2.

5. Cases where there is no solution can arise only near the poles. For example, it is clearly impossible for a star at the pole itself to have a non-zero xi value, and hence it is meaningless to ask where the tangent point would have to be to bring about this combination of xi and dec.

6. Also near the poles, cases can arise where there are two useful solutions. The returned value N indicates whether the second of the two solutions returned is useful; N=1 indicates only one useful solution, the usual case.

7. The basis of the algorithm is to solve the spherical triangle PSC, where P is the north celestial pole, S is the star and C is the tangent point. The spherical coordinates of the tangent point are [a0,b0]; writing rho^2 = (xi^2+eta^2) and r^2 = (1+rho^2), side c is then (pi/2-b), side p is sqrt(xi^2+eta^2) and side s (to be found) is (pi/2-b0). Angle C is given by sin(C) = xi/rho and cos(C) = eta/rho. Angle P (to be found) is the longitude difference between star and tangent point (a-a0).

8. This routine is a member of the following set:

    spherical       vector       solve for
   
    TPXES      TPXEV      xi,eta
    TPSTS      TPSTV       star
   

   TPORS < TPORV origin

References

• Calabretta M.R. & Greisen, E.W., 2002, "Representations of celestial coordinates in FITS", Astron.Astrophys. 395, 1077

• Green, R.M., "Spherical Astronomy", Cambridge University Press, 1987, Chapter 13.

History

• IAU SOFA revision: 2018 January 2

Arguments

    subroutine TPORS ( xi, eta, a, b, a01, b01, a02, b02, n )

    implicit none

    real(wp),intent(in) :: xi !! rectangular coordinates of star image (Note 2)
    real(wp),intent(in) :: eta !! rectangular coordinates of star image (Note 2)
    real(wp),intent(in) :: a !! star's spherical coordinates (Note 3)
    real(wp),intent(in) :: b !! star's spherical coordinates (Note 3)
    real(wp),intent(out) :: a01 !! tangent point's spherical coordinates, Soln. 1
    real(wp),intent(out) :: b01 !! tangent point's spherical coordinates, Soln. 1
    real(wp),intent(out) :: a02 !! tangent point's spherical coordinates, Soln. 2
    real(wp),intent(out) :: b02 !! tangent point's spherical coordinates, Soln. 2
    integer,intent(out) :: n !! number of solutions:
                             !! * 0 = no solutions returned (Note 5)
                             !! * 1 = only the first solution is useful (Note 6)
                             !! * 2 = both solutions are useful (Note 6)

    real(wp) :: xi2, r, sb, cb, rsb, rcb, w2, w, s, c

    xi2 = xi*xi
    r = sqrt(1.0_wp+xi2+eta*eta)
    sb = sin(b)
    cb = cos(b)
    rsb = r*sb
    rcb = r*cb
    w2 = rcb*rcb - xi2
    if ( w2 >= 0.0_wp ) then
       w = sqrt(w2)
       s = rsb - eta*w
       c = rsb*eta + w
       if ( xi == 0.0_wp .and. w == 0.0_wp ) w = 1.0_wp
       a01 = ANP(a - atan2(xi,w))
       b01 = atan2(s,c)
       w = -w
       s = rsb - eta*w
       c = rsb*eta + w
       a02 = ANP(a - atan2(xi,w))
       b02 = atan2(s,c)
       if ( abs(rsb) < 1.0_wp ) then
          n = 1
       else
          n = 2
       end if
    else
       n = 0
    end if

    end subroutine TPORS