TPSTS Subroutine

public subroutine TPSTS(xi, eta, a0, b0, a, b)

In the tangent plane projection, given the star's rectangular coordinates and the spherical coordinates of the tangent point, solve for the spherical coordinates of the star.

Status: support routine.

1. The tangent plane projection is also called the "gnomonic projection" and the "central projection".

2. The eta axis points due north in the adopted coordinate system. If the spherical coordinates are observed (RA,Dec), the tangent plane coordinates (xi,eta) are conventionally called the "standard coordinates". If the direction cosines are with respect to a right-handed triad, (xi,eta) are also right-handed. The units of (xi,eta) are, effectively, radians at the tangent point.

3. All angular arguments are in radians.

4. This routine is a member of the following set:

    spherical       vector       solve for
   
    TPXES      TPXEV      xi,eta
   

   TPSTS < TPSTV star TPORS TPORV origin

References

• Calabretta M.R. & Greisen, E.W., 2002, "Representations of celestial coordinates in FITS", Astron.Astrophys. 395, 1077

• Green, R.M., "Spherical Astronomy", Cambridge University Press, 1987, Chapter 13.

History

• IAU SOFA revision: 2018 January 2

Arguments

    subroutine TPSTS ( xi, eta, a0, b0, a, b )

    implicit none

    real(wp),intent(in) :: xi !! rectangular coordinates of star image (Note 2)
    real(wp),intent(in) :: eta !! rectangular coordinates of star image (Note 2)
    real(wp),intent(in) :: a0 !! tangent point's spherical coordinates
    real(wp),intent(in) :: b0 !! tangent point's spherical coordinates
    real(wp),intent(out) :: a !! star's spherical coordinates
    real(wp),intent(out) :: b !! star's spherical coordinates

    real(wp) :: sb0, cb0, d

    sb0 = sin(b0)
    cb0 = cos(b0)
    d = cb0 - eta*sb0
    a = ANP(atan2(xi,d)+a0)
    b = atan2(sb0+eta*cb0,sqrt(xi*xi+d*d))

    end subroutine TPSTS