subroutinesignature_argumentsprivate

subroutine signature_arguments(site, e, b)
    type(site_t), intent(in) :: site        !! the site
    type(entity_t), intent(in) :: e         !! the procedure
    type(buffer_t), intent(inout) :: b      !! the HTML
    integer :: k, id

    do k = 1, size(e%more%args)
        if (k > 1) call add(b, ', ')
        id = 0
        if (allocated(e%more%arg_ids)) then
            if (size(e%more%arg_ids) == size(e%more%args)) id = e%more%arg_ids(k)
        end if
        if (id > 0) then
            if (allocated(site%p%list%box(id)%e%intent)) then
                if (len(site%p%list%box(id)%e%intent) > 0) then
                    associate (intent => site%p%list%box(id)%e%intent)
                        call add(b, '<span class="intent attr-'//intent//'" title="intent('//intent//')">')
                        call html_escape(e%more%args(k)%s, b, .false.)
                        call add(b, '</span>')
                    end associate
                    cycle
                end if
            end if
        end if
        call html_escape(e%more%args(k)%s, b, .false.)
    end do
end subroutine signature_arguments