For an observer whose geocentric position and velocity are known, prepare star-independent astrometry parameters for transformations between ICRS and GCRS. The Earth ephemeris is supplied by the caller.
The parameters produced by this routine are required in the space motion, parallax, light deflection and aberration parts of the astrometric transformation chain.
Status: support routine.
The TDB date DATE1+DATE2 is a Julian Date, apportioned in any convenient way between the two arguments. For example, JD(TDB)=2450123.7 could be expressed in any of these ways, among others:
DATE1 DATE2
2450123.7D0 0D0 (JD method)
2451545D0 -1421.3D0 (J2000 method)
2400000.5D0 50123.2D0 (MJD method)
2450123.5D0 0.2D0 (date & time method)
The JD method is the most natural and convenient to use in cases where the loss of several decimal digits of resolution is acceptable. The J2000 method is best matched to the way the argument is handled internally and will deliver the optimum resolution. The MJD method and the date & time methods are both good compromises between resolution and convenience. For most applications of this routine the choice will not be at all critical.
TT can be used instead of TDB without any significant impact on accuracy.
All the vectors are with respect to BCRS axes.
Providing separate arguments for (i) the observer's geocentric position and velocity and (ii) the Earth ephemeris is done for convenience in the geocentric, terrestrial and Earth orbit cases. For deep space applications it maybe more convenient to specify zero geocentric position and velocity and to supply the observer's position and velocity information directly instead of with respect to the Earth. However, note the different units: m and m/s for the geocentric vectors, au and au/day for the heliocentric and barycentric vectors.
In cases where the caller does not wish to provide the Earth ephemeris, the routine APCS13 can be used instead of the present routine. This computes the Earth ephemeris using the SOFA routine EPV00.
This is one of several routines that inserts into the ASTROM array star-independent parameters needed for the chain of astrometric transformations ICRS <-> GCRS <-> CIRS <-> observed.
The various routines support different classes of observer and portions of the transformation chain:
routines observer transformation
APCG APCG13 geocentric ICRS <-> GCRS
APCI APCI13 terrestrial ICRS <-> CIRS
APCO APCO13 terrestrial ICRS <-> observed
APCS APCS13 space ICRS <-> GCRS
APER APER13 terrestrial update Earth rotation
APIO APIO13 terrestrial CIRS <-> observed
Those with names ending in "13" use contemporary SOFA models to compute the various ephemerides. The others accept ephemerides supplied by the caller.
The transformation from ICRS to GCRS covers space motion, parallax, light deflection, and aberration. From GCRS to CIRS comprises frame bias and precession-nutation. From CIRS to observed takes account of Earth rotation, polar motion, diurnal aberration and parallax (unless subsumed into the ICRS <-> GCRS transformation), and atmospheric refraction.
The context array ASTROM produced by this routine is used by ATCIQ and ATICQ.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=wp), | intent(in) | :: | date1 | TDB as a 2-part... |
||
| real(kind=wp), | intent(in) | :: | date2 | |||
| real(kind=wp), | intent(in), | dimension(3,2) | :: | pv | observer's geocentric pos/vel (m, m/s) |
|
| real(kind=wp), | intent(in), | dimension(3,2) | :: | ebpv | Earth barycentric position/velocity (au, au/day) |
|
| real(kind=wp), | intent(in), | dimension(3) | :: | ehp | Earth heliocentric position (au) |
|
| real(kind=wp), | intent(inout), | dimension(30) | :: | astrom | star-independent astrometry parameters: (1) PM time interval (SSB, Julian years) (2-4) SSB to observer (vector, au) (5-7) Sun to observer (unit vector) (8) distance from Sun to observer (au) (9-11) v: barycentric observer velocity (vector, c) (12) sqrt(1-|v|^2): reciprocal of Lorenz factor (13-21) bias-precession-nutation matrix (22) unchanged (23) unchanged (24) unchanged (25) unchanged (26) unchanged (27) unchanged (28) unchanged (29) unchanged (30) unchanged |
subroutine APCS ( date1, date2, pv, ebpv, ehp, astrom )
implicit none
real(wp),intent(in) :: date1 !! TDB as a 2-part...
real(wp),intent(in) :: date2 !! ...Julian Date (Note 1)
real(wp),dimension(3,2),intent(in) :: pv !! observer's geocentric pos/vel (m, m/s)
real(wp),dimension(3,2),intent(in) :: ebpv !! Earth barycentric position/velocity (au, au/day)
real(wp),dimension(3),intent(in) :: ehp !! Earth heliocentric position (au)
real(wp),dimension(30),intent(inout) :: astrom !! star-independent astrometry parameters:
!!
!! (1) PM time interval (SSB, Julian years)
!! (2-4) SSB to observer (vector, au)
!! (5-7) Sun to observer (unit vector)
!! (8) distance from Sun to observer (au)
!! (9-11) v: barycentric observer velocity (vector, c)
!! (12) sqrt(1-|v|^2): reciprocal of Lorenz factor
!! (13-21) bias-precession-nutation matrix
!! (22) unchanged
!! (23) unchanged
!! (24) unchanged
!! (25) unchanged
!! (26) unchanged
!! (27) unchanged
!! (28) unchanged
!! (29) unchanged
!! (30) unchanged
! Astronomical unit (m, IAU 2012)
real(wp),parameter :: aum = 149597870.7d3
! Light time for 1 au (s)
real(wp),parameter :: ault = aum/cmps
! au/d to m/s
real(wp),parameter :: audms = aum/d2s
! Light time for 1 au (day)
real(wp),parameter :: cr = ault/d2s
integer :: i
real(wp) :: dp, dv, pb(3), vb(3), ph(3), v2, w
! Time since reference epoch, years (for proper motion calculation).
astrom(1) = ( ( date1 - dj00 ) + date2 ) / djy
! Adjust Earth ephemeris to observer.
do i=1,3
dp = pv(i,1) / aum
dv = pv(i,2) / audms
pb(i) = ebpv(i,1) + dp
vb(i) = ebpv(i,2) + dv
ph(i) = ehp(i) + dp
end do
! Barycentric position of observer (au).
call CP ( pb, astrom(2) )
! Heliocentric direction and distance (unit vector and au).
call PN ( ph, astrom(8), astrom(5) )
! Barycentric vel. in units of c, and reciprocal of Lorenz factor.
v2 = 0.0_wp
do i=1,3
w = vb(i) * cr
astrom(8+i) = w
v2 = v2 + w*w
end do
astrom(12) = sqrt ( 1.0_wp - v2 )
! Reset the NPB matrix.
call IR ( astrom(13) )
end subroutine APCS