APCO13 Subroutine

  1. astro_module.f90
  2. astro_module
  3. APCO13

public subroutine APCO13(utc1, utc2, dut1, elong, phi, hm, xp, yp, phpa, tc, rh, wl, astrom, eo, j)

For a terrestrial observer, prepare star-independent astrometry parameters for transformations between ICRS and observed coordinates. The caller supplies UTC, site coordinates, ambient air conditions and observing wavelength, and SOFA models are used to obtain the Earth ephemeris, CIP/CIO and refraction constants.

The parameters produced by this routine are required in the parallax, light deflection, aberration, and bias-precession-nutation parts of the ICRS/CIRS transformations.

Status: support routine.

Notes

  1. UTC1+UTC2 is quasi Julian Date (see Note 2), apportioned in any convenient way between the two arguments, for example where UTC1 is the Julian Day Number and UTC2 is the fraction of a day.

    However, JD cannot unambiguously represent UTC during a leap second unless special measures are taken. The convention in the present routine is that the JD day represents UTC days whether the length is 86399, 86400 or 86401 SI seconds.

    Applications should use the routine DTF2D to convert from calendar date and time of day into 2-part quasi Julian Date, as it implements the leap-second-ambiguity convention just described.

  2. The warning status "dubious year" flags UTCs that predate the introduction of the time scale or that are too far in the future to be trusted. See DAT for further details.

  3. UT1-UTC is tabulated in IERS bulletins. It increases by exactly one second at the end of each positive UTC leap second, introduced in order to keep UT1-UTC within +/- 0.9s. n.b. This practice is under review, and in the future UT1-UTC may grow essentially without limit.

  4. The geographical coordinates are with respect to the WGS84 reference ellipsoid. TAKE CARE WITH THE LONGITUDE SIGN: the longitude required by the present routine is east-positive (i.e. right-handed), in accordance with geographical convention.

  5. The polar motion XP,YP can be obtained from IERS bulletins. The values are the coordinates (in radians) of the Celestial Intermediate Pole with respect to the International Terrestrial Reference System (see IERS Conventions 2003), measured along the meridians 0 and 90 deg west respectively. For many applications, XP and YP can be set to zero.

    Internally, the polar motion is stored in a form rotated onto the local meridian.

  6. If hm, the height above the ellipsoid of the observing station in meters, is not known but phpa, the pressure in hPa (=mB), is available, an adequate estimate of hm can be obtained from the expression

        hm = -29.3 * tsl * log ( phpa / 1013.25 );

    where tsl is the approximate sea-level air temperature in K (See Astrophysical Quantities, C.W.Allen, 3rd edition, section 52). Similarly, if the pressure phpa is not known, it can be estimated from the height of the observing station, hm, as follows:

        phpa = 1013.25 * exp ( -hm / ( 29.3 * tsl ) );

    Note, however, that the refraction is nearly proportional to the pressure and that an accurate phpa value is important for precise work.

  7. The argument WL specifies the observing wavelength in micrometers. The transition from optical to radio is assumed to occur at 100 micrometers (about 3000 GHz).

  8. It is advisable to take great care with units, as even unlikely values of the input parameters are accepted and processed in accordance with the models used.

  9. In cases where the caller wishes to supply his own Earth ephemeris, Earth rotation information and refraction constants, the routine APCO can be used instead of the present routine.

  10. This is one of several routines that inserts into the ASTROM array star-independent parameters needed for the chain of astrometric transformations ICRS <-> GCRS <-> CIRS <-> observed.

    The various routines support different classes of observer and portions of the transformation chain:

        routines           observer        transformation

APCG APCG13    geocentric      ICRS <-> GCRS
APCI APCI13    terrestrial     ICRS <-> CIRS
APCO APCO13    terrestrial     ICRS <-> observed
APCS APCS13    space           ICRS <-> GCRS
APER APER13    terrestrial     update Earth rotation
APIO APIO13    terrestrial     CIRS <-> observed

    Those with names ending in "13" use contemporary SOFA models to compute the various ephemerides. The others accept ephemerides supplied by the caller.

    The transformation from ICRS to GCRS covers space motion, parallax, light deflection, and aberration. From GCRS to CIRS comprises frame bias and precession-nutation. From CIRS to observed takes account of Earth rotation, polar motion, diurnal aberration and parallax (unless subsumed into the ICRS <-> GCRS transformation), and atmospheric refraction.

  11. The context array ASTROM produced by this routine is used by ATIOQ, ATOIQ, ATCIQ and ATICQ.

History

  • IAU SOFA revision: 2013 December 5

Arguments

TypeIntentOptionalAttributesName
real(kind=wp), intent(in) :: utc1

UTC as a 2-part...
real(kind=wp), intent(in) :: utc2
real(kind=wp), intent(in) :: dut1

UT1-UTC (seconds, Note 3)
real(kind=wp), intent(in) :: elong

longitude (radians, east +ve, Note 4)
real(kind=wp), intent(in) :: phi

latitude (geodetic, radians, Note 4)
real(kind=wp), intent(in) :: hm

height above ellipsoid (m, geodetic, Notes 4,6)
real(kind=wp), intent(in) :: xp

polar motion coordinate (radians, Note 5)
real(kind=wp), intent(in) :: yp

polar motion coordinate (radians, Note 5)
real(kind=wp), intent(in) :: phpa

pressure at the observer (hPa = mB, Note 6)
real(kind=wp), intent(in) :: tc

ambient temperature at the observer (deg C)
real(kind=wp), intent(in) :: rh

relative humidity at the observer (range 0-1)
real(kind=wp), intent(in) :: wl

wavelength (micrometers, Note 7)
real(kind=wp), intent(out), dimension(30):: astrom

star-independent astrometry parameters:

(1) PM time interval (SSB, Julian years) (2-4) SSB to observer (vector, au) (5-7) Sun to observer (unit vector) (8) distance from Sun to observer (au) (9-11) v: barycentric observer velocity (vector, c) (12) sqrt(1-|v|^2): reciprocal of Lorenz factor (13-21) bias-precession-nutation matrix (22) longitude + s' (radians) (23) polar motion xp wrt local meridian (radians) (24) polar motion yp wrt local meridian (radians) (25) sine of geodetic latitude (26) cosine of geodetic latitude (27) magnitude of diurnal aberration vector (28) "local" Earth rotation angle (radians) (29) refraction constant A (radians) (30) refraction constant B (radians)
real(kind=wp), intent(out) :: eo

equation of the origins (ERA-GST)
integer, intent(out) :: j

0 = OK -1 = unacceptable date

Calls

proc~~apco13~~CallsGraph proc~apco13 APCO13 proc~utcut1 UTCUT1 proc~apco13->proc~utcut1 proc~pnm06a PNM06A proc~apco13->proc~pnm06a proc~eors EORS proc~apco13->proc~eors proc~s06 S06 proc~apco13->proc~s06 proc~utctai UTCTAI proc~apco13->proc~utctai proc~epv00 EPV00 proc~apco13->proc~epv00 proc~taitt TAITT proc~apco13->proc~taitt proc~bpn2xy BPN2XY proc~apco13->proc~bpn2xy proc~era00 ERA00 proc~apco13->proc~era00 proc~sp00 SP00 proc~apco13->proc~sp00 proc~refco REFCO proc~apco13->proc~refco proc~apco APCO proc~apco13->proc~apco proc~utcut1->proc~utctai proc~dat DAT proc~utcut1->proc~dat proc~jd2cal JD2CAL proc~utcut1->proc~jd2cal proc~taiut1 TAIUT1 proc~utcut1->proc~taiut1 proc~pfw06 PFW06 proc~pnm06a->proc~pfw06 proc~fw2m FW2M proc~pnm06a->proc~fw2m proc~nut06a NUT06A proc~pnm06a->proc~nut06a proc~fae03 FAE03 proc~s06->proc~fae03 proc~faf03 FAF03 proc~s06->proc~faf03 proc~faom03 FAOM03 proc~s06->proc~faom03 proc~fal03 FAL03 proc~s06->proc~fal03 proc~fave03 FAVE03 proc~s06->proc~fave03 proc~falp03 FALP03 proc~s06->proc~falp03 proc~fad03 FAD03 proc~s06->proc~fad03 proc~fapa03 FAPA03 proc~s06->proc~fapa03 proc~utctai->proc~dat proc~utctai->proc~jd2cal proc~cal2jd CAL2JD proc~utctai->proc~cal2jd proc~anp ANP proc~era00->proc~anp proc~cr CR proc~apco->proc~cr proc~pvtob PVTOB proc~apco->proc~pvtob proc~apcs APCS proc~apco->proc~apcs proc~trxpv TRXPV proc~apco->proc~trxpv proc~c2ixys C2IXYS proc~apco->proc~c2ixys proc~aper APER proc~apco->proc~aper proc~dat->proc~cal2jd proc~obl06 OBL06 proc~pfw06->proc~obl06 proc~gd2gc GD2GC proc~pvtob->proc~gd2gc proc~pom00 POM00 proc~pvtob->proc~pom00 proc~trxp TRXP proc~pvtob->proc~trxp proc~pn PN proc~apcs->proc~pn proc~ir IR proc~apcs->proc~ir proc~rx RX proc~fw2m->proc~rx proc~fw2m->proc~ir proc~rz RZ proc~fw2m->proc~rz proc~rxpv RXPV proc~trxpv->proc~rxpv proc~tr TR proc~trxpv->proc~tr proc~ry RY proc~c2ixys->proc~ry proc~c2ixys->proc~ir proc~c2ixys->proc~rz proc~nut00a NUT00A proc~nut06a->proc~nut00a proc~gd2gce GD2GCE proc~gd2gc->proc~gd2gce proc~zp ZP proc~gd2gc->proc~zp proc~eform EFORM proc~gd2gc->proc~eform proc~sxp SXP proc~pn->proc~sxp proc~pn->proc~zp proc~rxp RXP proc~rxpv->proc~rxp proc~nut00a->proc~fae03 proc~nut00a->proc~faf03 proc~nut00a->proc~faom03 proc~nut00a->proc~fal03 proc~nut00a->proc~fave03 proc~nut00a->proc~fapa03 proc~fame03 FAME03 proc~nut00a->proc~fame03 proc~faju03 FAJU03 proc~nut00a->proc~faju03 proc~fasa03 FASA03 proc~nut00a->proc~fasa03 proc~fama03 FAMA03 proc~nut00a->proc~fama03 proc~faur03 FAUR03 proc~nut00a->proc~faur03 proc~pom00->proc~rx proc~pom00->proc~ry proc~pom00->proc~ir proc~pom00->proc~rz proc~trxp->proc~tr proc~trxp->proc~rxp

Called by

proc~~apco13~~CalledByGraph proc~apco13 APCO13 proc~atco13 ATCO13 proc~atco13->proc~apco13 proc~atoc13 ATOC13 proc~atoc13->proc~apco13

Contents

Source Code

APCO13

Source Code

    subroutine APCO13 ( utc1, utc2, dut1, elong, phi, hm, xp, yp, &
                        phpa, tc, rh, wl, astrom, eo, j )

    implicit none

    real(wp),intent(in) :: utc1 !! UTC as a 2-part...
    real(wp),intent(in) :: utc2 !! ...quasi Julian Date (Notes 1,2)
    real(wp),intent(in) :: dut1 !! UT1-UTC (seconds, Note 3)
    real(wp),intent(in) :: elong !! longitude (radians, east +ve, Note 4)
    real(wp),intent(in) :: phi !! latitude (geodetic, radians, Note 4)
    real(wp),intent(in) :: hm !! height above ellipsoid (m, geodetic, Notes 4,6)
    real(wp),intent(in) :: xp !! polar motion coordinate (radians, Note 5)
    real(wp),intent(in) :: yp !! polar motion coordinate (radians, Note 5)
    real(wp),intent(in) :: phpa !! pressure at the observer (hPa = mB, Note 6)
    real(wp),intent(in) :: tc !! ambient temperature at the observer (deg C)
    real(wp),intent(in) :: rh !! relative humidity at the observer (range 0-1)
    real(wp),intent(in) :: wl !! wavelength (micrometers, Note 7)
    real(wp),dimension(30),intent(out) :: astrom !! star-independent astrometry parameters:
                                                 !!
                                                 !! (1)      PM time interval (SSB, Julian years)
                                                 !! (2-4)    SSB to observer (vector, au)
                                                 !! (5-7)    Sun to observer (unit vector)
                                                 !! (8)      distance from Sun to observer (au)
                                                 !! (9-11)   v: barycentric observer velocity (vector, c)
                                                 !! (12)     sqrt(1-|v|^2): reciprocal of Lorenz factor
                                                 !! (13-21)  bias-precession-nutation matrix
                                                 !! (22)     longitude + s' (radians)
                                                 !! (23)     polar motion xp wrt local meridian (radians)
                                                 !! (24)     polar motion yp wrt local meridian (radians)
                                                 !! (25)     sine of geodetic latitude
                                                 !! (26)     cosine of geodetic latitude
                                                 !! (27)     magnitude of diurnal aberration vector
                                                 !! (28)     "local" Earth rotation angle (radians)
                                                 !! (29)     refraction constant A (radians)
                                                 !! (30)     refraction constant B (radians)
    real(wp),intent(out) :: eo !! equation of the origins (ERA-GST)
    integer,intent(out) :: j !! status: +1 = dubious year (Note 2)
                             !!  0 = OK
                             !! -1 = unacceptable date

    integer :: js, jw
    real(wp) :: tai1, tai2, tt1, tt2, ut11, ut12, &
                ehpv(3,2), ebpv(3,2), r(3,3), x, y, s, theta, &
                sp, refa, refb

    !  UTC to other time scales.
    call UTCTAI ( utc1, utc2, tai1, tai2, js )
    if ( js>=0 ) then

      call TAITT ( tai1, tai2, tt1, tt2, js )
      call UTCUT1 ( utc1, utc2, dut1, ut11, ut12, js )
      if ( js>=0 ) then

        !  Earth barycentric & heliocentric position/velocity (au, au/d).
        call EPV00 ( tt1, tt2, ehpv, ebpv, jw )

        !  Form the equinox based BPN matrix, IAU 2006/2000A.
        call PNM06A ( tt1, tt2, r )

        !  Extract CIP X,Y.
        call BPN2XY ( r, x, y )

        !  Obtain CIO locator s.
        s = S06 ( tt1, tt2, x, y )

        !  Earth rotation angle.
        theta = ERA00 ( ut11, ut12 )

        !  TIO locator s'.
        sp = SP00 ( tt1, tt2 )

        !  Refraction constants A and B.
        call REFCO ( phpa, tc, rh, wl, refa, refb )

        !  Compute the star-independent astrometry parameters.
        call APCO ( tt1, tt2, ebpv, ehpv, x, y, s, theta, &
                        elong, phi, hm, xp, yp, sp, refa, refb, &
                        astrom )

        !  Equation of the origins.
        eo = EORS ( r, s )

      end if

    end if

    !  Return the status.
    j = js

    end subroutine APCO13