For a given UTC date, calculate Delta(AT) = TAI-UTC.
:------------------------------------------:
: :
: IMPORTANT :
: :
: A new version of this routine must be :
: produced whenever a new leap second is :
: announced. There are five items to :
: change on each such occasion: :
: :
: 1) The parameter NDAT must be :
: increased by 1. :
: :
: 2) The set of DATA statements that :
: initialize the arrays IDAT and :
: DATS must be extended by one line. :
: :
: 3) The parameter IYV must be set to :
: the current year. :
: :
: 4) The "Latest leap second" comment :
: below must be set to the new leap :
: second date. :
: :
: 5) The "This revision" comment, later, :
: must be set to the current date. :
: :
: Change (3) must also be carried out :
: whenever the routine is re-issued, :
: even if no leap seconds have been :
: added. :
: :
: Latest leap second: 2016 December 31 :
: :
:__________________________________________:
Status: user-replaceable support routine.
UTC began at 1960 January 1.0 (JD 2436934.5) and it is improper to call the routine with an earlier date. If this is attempted, zero is returned together with a warning status.
Because leap seconds cannot, in principle, be predicted in advance, a reliable check for dates beyond the valid range is impossible. To guard against gross errors, a year five or more after the release year of the present routine (see parameter IYV) is considered dubious. In this case a warning status is returned but the result is computed in the normal way.
For both too-early and too-late years, the warning status is J=+1. This is distinct from the error status J=-1, which signifies a year so early that JD could not be computed.
If the specified date is for a day which ends with a leap second, the TAI-UTC value returned is for the period leading up to the leap second. If the date is for a day which begins as a leap second ends, the TAI-UTC returned is for the period following the leap second.
The day number must be in the normal calendar range, for example 1 through 30 for April. The "almanac" convention of allowing such dates as January 0 and December 32 is not supported in this routine, in order to avoid confusion near leap seconds.
The fraction of day is used only for dates before the introduction of leap seconds, the first of which occurred at the end of 1971. It is tested for validity (0 to 1 is the valid range) even if not used; if invalid, zero is used and status J=-4 is returned. For many applications, setting FD to zero is acceptable; the resulting error is always less than 3 ms (and occurs only pre-1972).
The status value returned in the case where there are multiple errors refers to the first error detected. For example, if the month and day are 13 and 32 respectively, J=-2 (bad month) will be returned. The "internal error" status refers to a case that is impossible but causes some compilers to issue a warning.
In cases where a valid result is not available, zero is returned.
For dates from 1961 January 1 onwards, the expressions from the file ftp://maia.usno.navy.mil/ser7/tai-utc.dat are used.
The 5ms timestep at 1961 January 1 is taken from 2.58.1 (p87) of the 1992 Explanatory Supplement.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| integer, | intent(in) | :: | iy | UTC: year (Notes 1 and 2) |
||
| integer, | intent(in) | :: | im | UTC: month (Note 2) |
||
| integer, | intent(in) | :: | id | UTC: day (Notes 2 and 3) |
||
| real(kind=wp), | intent(in) | :: | fd | UTC: fraction of day (Note 4) |
||
| real(kind=wp), | intent(out) | :: | deltat | TAI minus UTC, seconds |
||
| integer, | intent(out) | :: | j | status (Note 5):
|
subroutine DAT ( iy, im, id, fd, deltat, j )
implicit none
integer,intent(in) :: iy !! UTC: year (Notes 1 and 2)
integer,intent(in) :: im !! UTC: month (Note 2)
integer,intent(in) :: id !! UTC: day (Notes 2 and 3)
real(wp),intent(in) :: fd !! UTC: fraction of day (Note 4)
real(wp),intent(out) :: deltat !! TAI minus UTC, seconds
integer,intent(out) :: j !! status (Note 5):
!!
!! * 1 = dubious year (Note 1)
!! * 0 = OK
!! * -1 = bad year
!! * -2 = bad month
!! * -3 = bad day (Note 3)
!! * -4 = bad fraction (Note 4)
!! * -5 = internal error (Note 5)
! Release year for this version of DAT
integer,parameter :: iyv = 2019
! Number of Delta(AT) changes (increase by 1 for each new leap second)
integer,parameter :: ndat = 42
! Number of Delta(AT) expressions before leap seconds were introduced
integer,parameter :: nera1 = 14
! Dates (year, month) on which new Delta(AT) came into force
integer,dimension(2,ndat),parameter :: idat = reshape([ 1960, 1, &
1961, 1, &
1961, 8, &
1962, 1, &
1963, 11, &
1964, 1, &
1964, 4, &
1964, 9, &
1965, 1, &
1965, 3, &
1965, 7, &
1965, 9, &
1966, 1, &
1968, 2, &
1972, 1, &
1972, 7, &
1973, 1, &
1974, 1, &
1975, 1, &
1976, 1, &
1977, 1, &
1978, 1, &
1979, 1, &
1980, 1, &
1981, 7, &
1982, 7, &
1983, 7, &
1985, 7, &
1988, 1, &
1990, 1, &
1991, 1, &
1992, 7, &
1993, 7, &
1994, 7, &
1996, 1, &
1997, 7, &
1999, 1, &
2006, 1, &
2009, 1, &
2012, 7, &
2015, 7, &
2017, 1], [2,ndat])
! New Delta(AT) which came into force on the given dates
real(wp),dimension(ndat),parameter :: dats = [1.4178180_wp,&
1.4228180_wp,&
1.3728180_wp,&
1.8458580_wp,&
1.9458580_wp,&
3.2401300_wp,&
3.3401300_wp,&
3.4401300_wp,&
3.5401300_wp,&
3.6401300_wp,&
3.7401300_wp,&
3.8401300_wp,&
4.3131700_wp,&
4.2131700_wp,&
10.0_wp,&
11.0_wp,&
12.0_wp,&
13.0_wp,&
14.0_wp,&
15.0_wp,&
16.0_wp,&
17.0_wp,&
18.0_wp,&
19.0_wp,&
20.0_wp,&
21.0_wp,&
22.0_wp,&
23.0_wp,&
24.0_wp,&
25.0_wp,&
26.0_wp,&
27.0_wp,&
28.0_wp,&
29.0_wp,&
30.0_wp,&
31.0_wp,&
32.0_wp,&
33.0_wp,&
34.0_wp,&
35.0_wp,&
36.0_wp,&
37.0_wp]
! Reference dates (MJD) and drift rates (s/day), pre leap seconds
real(wp),dimension(2,nera1),parameter :: drift = reshape([37300.0_wp, 0.001296_wp, &
37300.0_wp, 0.001296_wp, &
37300.0_wp, 0.001296_wp, &
37665.0_wp, 0.0011232_wp, &
37665.0_wp, 0.0011232_wp, &
38761.0_wp, 0.001296_wp, &
38761.0_wp, 0.001296_wp, &
38761.0_wp, 0.001296_wp, &
38761.0_wp, 0.001296_wp, &
38761.0_wp, 0.001296_wp, &
38761.0_wp, 0.001296_wp, &
38761.0_wp, 0.001296_wp, &
39126.0_wp, 0.002592_wp, &
39126.0_wp, 0.002592_wp ], [2,nera1])
! Miscellaneous local variables
logical :: more
integer :: js, m, n, is
real(wp) :: da, djm0, djm
main : block
! Initialize the result to zero and the status to OK.
da = 0.0_wp
js = 0
! If invalid fraction of a day, set error status and give up.
if ( fd<0.0_wp .or. fd>1.0_wp ) then
js = -4
exit main
end if
! Convert the date into an MJD.
call CAL2JD ( iy, im, id, djm0, djm, js )
! If invalid year, month, or day, give up.
if ( js < 0 ) exit main
! If pre-UTC year, set warning status and give up.
if ( iy < idat(1,1) ) then
js = 1
exit main
end if
! If suspiciously late year, set warning status but proceed.
if ( iy > iyv+5 ) js = 1
! Combine year and month.
m = 12*iy+im
! Find the most recent table entry.
is = 0
more = .true.
do n=ndat,1,-1
if ( more ) then
is = n
more = m < ( 12*idat(1,n) + idat(2,n) )
end if
end do
! Prevent underflow warnings.
if ( is < 1 ) then
js = -5
exit main
end if
! Get the Delta(AT).
da = dats(is)
! If pre-1972, adjust for drift.
if ( is <= nera1 ) da = da + &
( djm + fd - drift(1,is) ) * drift(2,is)
end block main
! Return the Delta(AT) value and the status.
deltat = da
j = js
end subroutine DAT