UTCTAI Subroutine

  1. astro_module.f90
  2. astro_module
  3. UTCTAI

public subroutine UTCTAI(utc1, utc2, tai1, tai2, j)

Time scale transformation: Coordinated Universal Time, UTC, to International Atomic Time, TAI.

Status: canonical.

Notes

  1. UTC1+UTC2 is quasi Julian Date (see Note 2), apportioned in any convenient way between the two arguments, for example where UTC1 is the Julian Day Number and UTC2 is the fraction of a day.

  2. JD cannot unambiguously represent UTC during a leap second unless special measures are taken. The convention in the present routine is that the JD day represents UTC days whether the length is 86399, 86400 or 86401 SI seconds. In the 1960-1972 era there were smaller jumps (in either direction) each time the linear UTC(TAI) expression was changed, and these "mini-leaps" are also included in the SOFA convention.

  3. The warning status "dubious year" flags UTCs that predate the introduction of the time scale or that are too far in the future to be trusted. See DAT for further details.

  4. The routine DTF2D converts from calendar date and time of day into 2-part Julian Date, and in the case of UTC implements the leap-second-ambiguity convention described above.

  5. The returned TAI1,TAI2 are such that their sum is the TAI Julian Date.

References

  • McCarthy, D. D., Petit, G. (eds.), IERS Conventions (2003), IERS Technical Note No. 32, BKG (2004)

  • Explanatory Supplement to the Astronomical Almanac, P. Kenneth Seidelmann (ed), University Science Books (1992)

History

  • IAU SOFA revision: 2019 June 20

Arguments

TypeIntentOptionalAttributesName
real(kind=wp), intent(in) :: utc1

UTC as a 2-part quasi Julian Date (Notes 1-4)
real(kind=wp), intent(in) :: utc2

UTC as a 2-part quasi Julian Date (Notes 1-4)
real(kind=wp), intent(out) :: tai1

TAI as a 2-part Julian Date (Note 5)
real(kind=wp), intent(out) :: tai2

TAI as a 2-part Julian Date (Note 5)
integer, intent(out) :: j
  • +1 = dubious year (Note 3)
  • 0 = OK
  • -1 = unacceptable date

Calls

proc~~utctai~~CallsGraph proc~utctai UTCTAI proc~jd2cal JD2CAL proc~utctai->proc~jd2cal proc~dat DAT proc~utctai->proc~dat proc~cal2jd CAL2JD proc~utctai->proc~cal2jd proc~dat->proc~cal2jd

Called by

proc~~utctai~~CalledByGraph proc~utctai UTCTAI proc~apco13 APCO13 proc~apco13->proc~utctai proc~utcut1 UTCUT1 proc~apco13->proc~utcut1 proc~apio13 APIO13 proc~apio13->proc~utctai proc~apio13->proc~utcut1 proc~utcut1->proc~utctai proc~taiutc TAIUTC proc~taiutc->proc~utctai proc~atco13 ATCO13 proc~atco13->proc~apco13 proc~atoi13 ATOI13 proc~atoi13->proc~apio13 proc~atio13 ATIO13 proc~atio13->proc~apio13 proc~atoc13 ATOC13 proc~atoc13->proc~apco13

Contents

Source Code

UTCTAI

Source Code

    subroutine UTCTAI ( utc1, utc2, tai1, tai2, j )

    implicit none

    real(wp),intent(in) :: utc1 !! UTC as a 2-part quasi Julian Date (Notes 1-4)
    real(wp),intent(in) :: utc2 !! UTC as a 2-part quasi Julian Date (Notes 1-4)
    real(wp),intent(out) :: tai1 !! TAI as a 2-part Julian Date (Note 5)
    real(wp),intent(out) :: tai2 !! TAI as a 2-part Julian Date (Note 5)
    integer,intent(out) :: j !! status:
                             !! * +1 = dubious year (Note 3)
                             !! * 0 = OK
                             !! * -1 = unacceptable date

    logical :: big1
    integer :: iy, im, id, js, iyt, imt, idt
    real(wp) :: u1, u2, fd, dat0, dat12, w, dat24, dlod, dleap, &
                z1, z2, a2

    !  Put the two parts of the UTC into big-first order.
    big1 = abs(utc1) >= abs(utc2)
    if ( big1 ) then
       u1 = utc1
       u2 = utc2
    else
       u1 = utc2
       u2 = utc1
    end if

    !  Get TAI-UTC at 0h today.
    call JD2CAL ( u1, u2, iy, im, id, fd, js )
    if ( js==0 ) then

      call DAT ( iy, im, id, 0.0_wp, dat0, js )
      if ( js>=0 ) then

        !  Get TAI-UTC at 12h today (to detect drift).
        call DAT ( iy, im, id, 0.5_wp, dat12, js )
        if ( js>=0 ) then

          !  Get TAI-UTC at 0h tomorrow (to detect jumps).
          call JD2CAL ( u1+1.5_wp, u2-fd, iyt, imt, idt, w, js )
          if ( js==0 ) then

            call DAT ( iyt, imt, idt, 0.0_wp, dat24, js )
            if ( js>=0 ) then

              !  Separate TAI-UTC change into per-day (DLOD) and any jump (DLEAP).
              dlod = 2.0_wp * ( dat12 - dat0 )
              dleap = dat24 - ( dat0 + dlod )

              !  Remove any scaling applied to spread leap into preceding day.
              fd = fd * (d2s+dleap)/d2s

              !  Scale from (pre-1972) UTC seconds to SI seconds.
              fd = fd * (d2s+dlod)/d2s

              !  Today's calendar date to 2-part JD.
              call CAL2JD ( iy, im, id, z1, z2, js )
              if ( js==0 ) then

                !  Assemble the TAI result, preserving the UTC split and order.
                a2 = z1 - u1
                a2 = ( a2 + z2 ) + ( fd + dat0/d2s )
                if ( big1 ) then
                  tai1 = u1
                  tai2 = a2
                else
                  tai1 = a2
                  tai2 = u1
                end if

              end if
            end if
          end if
        end if
      end if
    end if

    !  Status.
    j = js

    end subroutine UTCTAI