APIO13 Subroutine

public subroutine APIO13(utc1, utc2, dut1, elong, phi, hm, xp, yp, phpa, tc, rh, wl, astrom, j)

For a terrestrial observer, prepare star-independent astrometry parameters for transformations between CIRS and observed coordinates. The caller supplies UTC, site coordinates, ambient air conditions and observing wavelength.

Status: support routine.

Notes

1. UTC1+UTC2 is quasi Julian Date (see Note 2), apportioned in any convenient way between the two arguments, for example where UTC1 is the Julian Day Number and UTC2 is the fraction of a day.

   However, JD cannot unambiguously represent UTC during a leap second unless special measures are taken. The convention in the present routine is that the JD day represents UTC days whether the length is 86399, 86400 or 86401 SI seconds.

   Applications should use the routine DTF2D to convert from calendar date and time of day into 2-part quasi Julian Date, as it implements the leap-second-ambiguity convention just described.

2. The warning status "dubious year" flags UTCs that predate the introduction of the time scale or that are too far in the future to be trusted. See DAT for further details.

3. UT1-UTC is tabulated in IERS bulletins. It increases by exactly one second at the end of each positive UTC leap second, introduced in order to keep UT1-UTC within +/- 0.9s. n.b. This practice is under review, and in the future UT1-UTC may grow essentially without limit.

4. The geographical coordinates are with respect to the WGS84 reference ellipsoid. TAKE CARE WITH THE LONGITUDE SIGN: the longitude required by the present routine is east-positive (i.e. right-handed), in accordance with geographical convention.

5. The polar motion XP,YP can be obtained from IERS bulletins. The values are the coordinates (in radians) of the Celestial Intermediate Pole with respect to the International Terrestrial Reference System (see IERS Conventions 2003), measured along the meridians 0 and 90 deg west respectively. For many applications, XP and YP can be set to zero.

   Internally, the polar motion is stored in a form rotated onto the local meridian.

6. If hm, the height above the ellipsoid of the observing station in meters, is not known but phpa, the pressure in hPa (=mB), is available, an adequate estimate of hm can be obtained from the expression

       hm = -29.3 * tsl * log ( phpa / 1013.25 );
   

   where tsl is the approximate sea-level air temperature in K (See Astrophysical Quantities, C.W.Allen, 3rd edition, section 52). Similarly, if the pressure phpa is not known, it can be estimated from the height of the observing station, hm, as follows:

       phpa = 1013.25 * exp ( -hm / ( 29.3 * tsl ) );
   

   Note, however, that the refraction is nearly proportional to the pressure and that an accurate phpa value is important for precise work.

7. The argument WL specifies the observing wavelength in micrometers. The transition from optical to radio is assumed to occur at 100 micrometers (about 3000 GHz).

8. It is advisable to take great care with units, as even unlikely values of the input parameters are accepted and processed in accordance with the models used.

9. In cases where the caller wishes to supply his own Earth rotation information and refraction constants, the routine APC can be used instead of the present routine.

10. This is one of several routines that inserts into the ASTROM array star-independent parameters needed for the chain of astrometric transformations ICRS <-> GCRS <-> CIRS <-> observed.

    The various routines support different classes of observer and portions of the transformation chain:

        routines           observer        transformation
    
    APCG APCG13    geocentric      ICRS <-> GCRS
    APCI APCI13    terrestrial     ICRS <-> CIRS
    APCO APCO13    terrestrial     ICRS <-> observed
    APCS APCS13    space           ICRS <-> GCRS
    APER APER13    terrestrial     update Earth rotation
    APIO APIO13    terrestrial     CIRS <-> observed
    

    Those with names ending in "13" use contemporary SOFA models to compute the various ephemerides. The others accept ephemerides supplied by the caller.

    The transformation from ICRS to GCRS covers space motion, parallax, light deflection, and aberration. From GCRS to CIRS comprises frame bias and precession-nutation. From CIRS to observed takes account of Earth rotation, polar motion, diurnal aberration and parallax (unless subsumed into the ICRS <-> GCRS transformation), and atmospheric refraction.

11. The context array ASTROM produced by this routine is used by ATIOQ and ATOIQ.

History

• IAU SOFA revision: 2013 September 25

Arguments

    subroutine APIO13 ( utc1, utc2, dut1, elong, phi, hm, xp, yp, &
                        phpa, tc, rh, wl, astrom, j )

    implicit none

    real(wp),intent(in) :: utc1 !! UTC as a 2-part...
    real(wp),intent(in) :: utc2 !! ...quasi Julian Date (Notes 1,2)
    real(wp),intent(in) :: dut1 !! UT1-UTC (seconds)
    real(wp),intent(in) :: elong !! longitude (radians, east +ve, Note 3)
    real(wp),intent(in) :: phi !! geodetic latitude (radians, Note 3)
    real(wp),intent(in) :: hm !! height above ellipsoid (m, geodetic Notes 4,6)
    real(wp),intent(in) :: xp !! polar motion x-coordinate (radians, Note 5)
    real(wp),intent(in) :: yp !! polar motion x-coordinate (radians, Note 5)
    real(wp),intent(in) :: phpa !! pressure at the observer (hPa = mB, Note 6)
    real(wp),intent(in) :: tc !! ambient temperature at the observer (deg C)
    real(wp),intent(in) :: rh !! relative humidity at the observer (range 0-1)
    real(wp),intent(in) :: wl !! wavelength (micrometers, Note 7)
    real(wp),dimension(30),intent(inout) :: astrom !! star-independent astrometry parameters:
                                                   !!
                                                   !! (1)      unchanged
                                                   !! (2-4)    unchanged
                                                   !! (5-7)    unchanged
                                                   !! (8)      unchanged
                                                   !! (9-11)   unchanged
                                                   !! (12)     unchanged
                                                   !! (13-21)  unchanged
                                                   !! (22)     longitude + s' (radians)
                                                   !! (23)     polar motion xp wrt local meridian (radians)
                                                   !! (24)     polar motion yp wrt local meridian (radians)
                                                   !! (25)     sine of geodetic latitude
                                                   !! (26)     cosine of geodetic latitude
                                                   !! (27)     magnitude of diurnal aberration vector
                                                   !! (28)     "local" Earth rotation angle (radians)
                                                   !! (29)     refraction constant A (radians)
                                                   !! (30)     refraction constant B (radians)
    integer,intent(out) :: j !! status:
                             !! * +1 = dubious year (Note 2)
                             !! *  0 = OK
                             !! * -1 = unacceptable date

    integer :: js
    real(wp) :: tai1, tai2, tt1, tt2, ut11, ut12, sp, theta, &
                refa, refb

    !  UTC to other time scales.
    call UTCTAI ( utc1, utc2, tai1, tai2, js )
    call TAITT ( tai1, tai2, tt1, tt2, js )
    call UTCUT1 ( utc1, utc2, dut1, ut11, ut12, js )

    !  Abort if error.
    if ( js>=0 ) then

      !  TIO locator s'.
      sp = SP00 ( tt1, tt2 )

      !  Earth rotation angle.
      theta = ERA00 ( ut11, ut12 )

      !  Refraction constants A and B.
      call REFCO ( phpa, tc, rh, wl, refa, refb )

      !  CIRS <-> observed astrometry parameters.
      call APIO ( sp, theta, elong, phi, hm, xp, yp, refa, refb, &
                      astrom )

    end if

    !  Return the status.
    j = js

    end subroutine APIO13