Determine the constants A and B in the atmospheric refraction model dZ = A tan Z + B tan^3 Z.
Z is the "observed" zenith distance (i.e. affected by refraction) and dZ is what to add to Z to give the "topocentric" (i.e. in vacuo) zenith distance.
Status: support routine.
The model balances speed and accuracy to give good results in applications where performance at low altitudes is not paramount. Performance is maintained across a range of conditions, and applies to both optical/IR and radio.
The model omits the effects of (i) height above sea level (apart from the reduced pressure itself), (ii) latitude (i.e. the flattening of the Earth), (iii) variations in tropospheric lapse rate and (iv) dispersive effects in the radio.
The model was tested using the following range of conditions:
The accuracy with respect to raytracing through a model atmosphere was as follows:
worst RMS
optical/IR 62 mas 8 mas
radio 319 mas 49 mas
For this particular set of conditions:
* lapse rate 0.0065 K/meter
* latitude 50 degrees
* sea level
* pressure 1005 mb
* temperature 280.15 K
* humidity 80%
* wavelength 5740 Angstroms
the results were as follows:
ZD raytrace REFCO Saastamoinen
10 10.27 10.27 10.27
20 21.19 21.20 21.19
30 33.61 33.61 33.60
40 48.82 48.83 48.81
45 58.16 58.18 58.16
50 69.28 69.30 69.27
55 82.97 82.99 82.95
60 100.51 100.54 100.50
65 124.23 124.26 124.20
70 158.63 158.68 158.61
72 177.32 177.37 177.31
74 200.35 200.38 200.32
76 229.45 229.43 229.42
78 267.44 267.29 267.41
80 319.13 318.55 319.10
deg arcsec arcsec arcsec
The values for Saastamoinen's formula (which includes terms
up to tan^5) are taken from Hohenkerk and Sinclair (1985).
A WL value in the range 0-100 selects the optical/IR case and is wavelength in micrometers. Any value outside this range selects the radio case.
Outlandish input parameters are silently limited to mathematically safe values. Zero pressure is permissible, and causes zeroes to be returned.
The algorithm draws on several sources, as follows:
a) The formula for the saturation vapour pressure of water as a function of temperature and temperature is taken from Equations (A4.5-A4.7) of Gill (1982).
b) The formula for the water vapour pressure, given the saturation pressure and the relative humidity, is from Crane (1976), Equation (2.5.5).
c) The refractivity of air is a function of temperature, total pressure, water-vapour pressure and, in the case of optical/IR, wavelength. The formulae for the two cases are developed from Hohenkerk & Sinclair (1985) and Rueger (2002).
d) The formula for beta, the ratio of the scale height of the atmosphere to the geocentric distance of the observer, is an adaption of Equation (9) from Stone (1996). The adaptations, arrived at empirically, consist of (i) a small adjustment to the coefficient and (ii) a humidity term for the radio case only.
e) The formulae for the refraction constants as a function of n-1 and beta are from Green (1987), Equation (4.31).
Crane, R.K., Meeks, M.L. (ed), "Refraction Effects in the Neutral Atmosphere", Methods of Experimental Physics: Astrophysics 12B, Academic Press, 1976.
Gill, Adrian E., "Atmosphere-Ocean Dynamics", Academic Press, 1982.
Green, R.M., "Spherical Astronomy", Cambridge University Press, 1987.
Hohenkerk, C.Y., & Sinclair, A.T., NAO Technical Note No. 63, 1985.
Rueger, J.M., "Refractive Index Formulae for Electronic Distance Measurement with Radio and Millimetre Waves", in Unisurv Report S-68, School of Surveying and Spatial Information Systems, University of New South Wales, Sydney, Australia, 2002.
Stone, Ronald C., P.A.S.P. 108, 1051-1058, 1996.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=wp), | intent(in) | :: | phpa | pressure at the observer (hPa = millibar) |
||
| real(kind=wp), | intent(in) | :: | tc | ambient temperature at the observer (deg C) |
||
| real(kind=wp), | intent(in) | :: | rh | relative humidity at the observer (range 0-1) |
||
| real(kind=wp), | intent(in) | :: | wl | wavelength (micrometers) |
||
| real(kind=wp), | intent(out) | :: | refa | tan Z coefficient (radians) |
||
| real(kind=wp), | intent(out) | :: | refb | tan^3 Z coefficient (radians) |
subroutine REFCO ( phpa, tc, rh, wl, refa, refb )
implicit none
real(wp),intent(in) :: phpa !! pressure at the observer (hPa = millibar)
real(wp),intent(in) :: tc !! ambient temperature at the observer (deg C)
real(wp),intent(in) :: rh !! relative humidity at the observer (range 0-1)
real(wp),intent(in) :: wl !! wavelength (micrometers)
real(wp),intent(out) :: refa !! tan Z coefficient (radians)
real(wp),intent(out) :: refb !! tan^3 Z coefficient (radians)
logical :: optic
real(wp) :: p, t, r, w, ps, pw, tk, wlsq, gamma, beta
! Decide whether optical/IR or radio case: switch at 100 microns.
optic = wl<=100.0_wp
! Restrict parameters to safe values.
t = min(max(tc,-150.0_wp),200.0_wp)
p = min(max(phpa,0.0_wp),10000.0_wp)
r = min(max(rh,0.0_wp),1.0_wp)
w = min(max(wl,0.1_wp),1.0e6_wp)
! Water vapour pressure at the observer.
if (p>0.0_wp) then
ps = 10.0_wp**((0.7859_wp+0.03477_wp*t)/(1.0_wp+0.00412_wp*t))* &
(1.0_wp+p*(4.5e-6_wp+6e-10_wp*t*t))
pw = r*ps/(1.0_wp-(1.0_wp-r)*ps/p)
else
pw = 0.0_wp
end if
! Refractive index minus 1 at the observer.
tk = t + 273.15_wp
if (optic) then
wlsq = w*w
gamma = ((77.53484e-6_wp+(4.39108e-7_wp+3.666e-9_wp/wlsq)/wlsq)*p &
-11.2684e-6_wp*pw)/tk
else
gamma = (77.6890e-6_wp*p-(6.3938e-6_wp-0.375463_wp/tk)*pw)/tk
end if
! Formula for beta adapted from Stone, with empirical adjustments.
beta=4.4474e-6_wp*tk
if (.not.optic) beta=beta-0.0074_wp*pw*beta
! Refraction constants from Green.
refa = gamma*(1.0_wp-beta)
refb = -gamma*(beta-gamma/2.0_wp)
end subroutine REFCO