Encode date and time fields into 2-part Julian Date (or in the case of UTC a quasi-JD form that includes special provision for leap seconds).
Status: support routine.
SCALE identifies the time scale. Only the value 'UTC' (in upper case) is significant, and enables handling of leap seconds (see Note 4).
For calendar conventions and limitations, see CAL2JD.
The sum of the results, D1+D2, is Julian Date, where normally D1 is the Julian Day Number and D2 is the fraction of a day. In the case of UTC, where the use of JD is problematical, special conventions apply: see the next note.
JD cannot unambiguously represent UTC during a leap second unless special measures are taken. The SOFA internal convention is that the quasi-JD day represents UTC days whether the length is 86399, 86400 or 86401 SI seconds. In the 1960-1972 era there were smaller jumps (in either direction) each time the linear UTC(TAI) expression was changed, and these "mini-leaps" are also included in the SOFA convention.
The warning status "time is after end of day" usually means that the SEC argument is greater than 60D0. However, in a day ending in a leap second the limit changes to 61D0 (or 59D0 in the case of a negative leap second).
The warning status "dubious year" flags UTCs that predate the introduction of the time scale or that are too far in the future to be trusted. See DAT for further details.
Only in the case of continuous and regular time scales (TAI, TT, TCG, TCB and TDB) is the result D1+D2 a Julian Date, strictly speaking. In the other cases (UT1 and UTC) the result must be used with circumspection; in particular the difference between two such results cannot be interpreted as a precise time interval.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| character(len=*), | intent(in) | :: | scale | time scale ID (Note 1) |
||
| integer, | intent(in) | :: | iy | year in Gregorian calendar (Note 2) |
||
| integer, | intent(in) | :: | im | month in Gregorian calendar (Note 2) |
||
| integer, | intent(in) | :: | id | day in Gregorian calendar (Note 2) |
||
| integer, | intent(in) | :: | ihr | hour |
||
| integer, | intent(in) | :: | imn | minute |
||
| real(kind=wp), | intent(in) | :: | sec | seconds |
||
| real(kind=wp), | intent(out) | :: | d1 | 2-part Julian Date (Notes 3,4) |
||
| real(kind=wp), | intent(out) | :: | d2 | 2-part Julian Date (Notes 3,4) |
||
| integer, | intent(out) | :: | j |
|
subroutine DTF2D ( scale, iy, im, id, ihr, imn, sec, &
d1, d2, j )
implicit none
character(len=*),intent(in) :: scale !! time scale ID (Note 1)
integer,intent(in) :: iy !! year in Gregorian calendar (Note 2)
integer,intent(in) :: im !! month in Gregorian calendar (Note 2)
integer,intent(in) :: id !! day in Gregorian calendar (Note 2)
integer,intent(in) :: ihr !! hour
integer,intent(in) :: imn !! minute
real(wp),intent(in) :: sec !! seconds
real(wp),intent(out) :: d1 !! 2-part Julian Date (Notes 3,4)
real(wp),intent(out) :: d2 !! 2-part Julian Date (Notes 3,4)
integer,intent(out) :: j !! status:
!! * +3 = both of next two
!! * +2 = time is after end of day (Note 5)
!! * +1 = dubious year (Note 6)
!! * 0 = OK
!! * -1 = bad year
!! * -2 = bad month
!! * -3 = bad day
!! * -4 = bad hour
!! * -5 = bad minute
!! * -6 = bad second (<0)
integer :: js, iy2, im2, id2
real(wp) :: dj, w, day, seclim, dat0, dat12, dat24, &
dleap, time
main : block
! Today's Julian Day Number.
call CAL2JD ( iy, im, id, dj, w, js )
if ( js/=0 ) exit main
dj = dj + w
! Day length and final minute length in seconds (provisional).
day = d2s
seclim = 60.0_wp
! Deal with the UTC leap second case.
if ( scale=='UTC' ) then
! TAI-UTC at 0h today.
call DAT ( iy, im, id, 0.0_wp, dat0, js )
if ( js<0 ) exit main
! TAI-UTC at 12h today (to detect drift).
call DAT ( iy, im, id, 0.5_wp, dat12, js )
if ( js<0 ) exit main
! TAI-UTC at 0h tomorrow (to detect jumps).
call JD2CAL ( dj, 1.5_wp, iy2, im2, id2, w, js )
if ( js/=0 ) exit main
call DAT ( iy2, im2, id2, 0.0_wp, dat24, js )
if ( js<0 ) exit main
! Any sudden change in TAI-UTC between today and tomorrow.
dleap = dat24 - ( 2.0_wp * dat12 - dat0 )
! If leap second day, correct the day and final minute lengths.
day = day + dleap
if ( ihr==23 .and. imn==59 ) seclim = seclim + dleap
! End of UTC-specific actions.
end if
! Validate the time.
if ( ihr>=0 .and. ihr<=23 ) then
if ( imn>=0 .and. imn<=59 ) then
if ( sec>=0.0_wp ) then
if ( sec>=seclim ) then
js = js + 2
end if
else
js = -6
end if
else
js = -5
end if
else
js = -4
end if
if ( js<0 ) exit main
! The time in days.
time = (60.0_wp*real(60*ihr+imn, wp)+sec) / day
! Return the date and time.
d1 = dj
d2 = time
end block main
! Return the status.
j = js
end subroutine DTF2D