Time scale transformation: Universal Time, UT1, to Coordinated Universal Time, UTC.
Status: canonical.
UT11+UT12 is Julian Date, apportioned in any convenient way between the two arguments, for example where UT11 is the Julian Day Number and UT12 is the fraction of a day. The returned UTC1 and UTC2 form an analogous pair, except that a special convention is used, to deal with the problem of leap seconds - see Note 3.
Delta UT1 can be obtained from tabulations provided by the International Earth Rotation and Reference Systems Service. The value changes abruptly by 1s at a leap second; however, close to a leap second the algorithm used here is tolerant of the "wrong" choice of value being made.
JD cannot unambiguously represent UTC during a leap second unless special measures are taken. The convention in the present routine is that the returned quasi JD day UTC1+UTC2 represents UTC days whether the length is 86399, 86400 or 86401 SI seconds.
The routine D2DTF can be used to transform the UTC quasi-JD into calendar date and clock time, including UTC leap second handling.
The warning status "dubious year" flags UTCs that predate the introduction of the time scale or that are too far in the future to be trusted. See DAT for further details.
McCarthy, D. D., Petit, G. (eds.), IERS Conventions (2003), IERS Technical Note No. 32, BKG (2004)
Explanatory Supplement to the Astronomical Almanac, P. Kenneth Seidelmann (ed), University Science Books (1992)
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=wp), | intent(in) | :: | ut11 | UT1 as a 2-part Julian Date (Note 1) |
||
| real(kind=wp), | intent(in) | :: | ut12 | UT1 as a 2-part Julian Date (Note 1) |
||
| real(kind=wp), | intent(in) | :: | dut1 | Delta UT1: UT1-UTC in seconds (Note 2) |
||
| real(kind=wp), | intent(out) | :: | utc1 | UTC as a 2-part quasi Julian Date (Notes 3,4) |
||
| real(kind=wp), | intent(out) | :: | utc2 | UTC as a 2-part quasi Julian Date (Notes 3,4) |
||
| integer, | intent(out) | :: | j |
|
subroutine UT1UTC ( ut11, ut12, dut1, utc1, utc2, j )
implicit none
real(wp),intent(in) :: ut11 !! UT1 as a 2-part Julian Date (Note 1)
real(wp),intent(in) :: ut12 !! UT1 as a 2-part Julian Date (Note 1)
real(wp),intent(in) :: dut1 !! Delta UT1: UT1-UTC in seconds (Note 2)
real(wp),intent(out) :: utc1 !! UTC as a 2-part quasi Julian Date (Notes 3,4)
real(wp),intent(out) :: utc2 !! UTC as a 2-part quasi Julian Date (Notes 3,4)
integer,intent(out) :: j !! status:
!! * +1 = dubious year (Note 5)
!! * 0 = OK
!! * -1 = unacceptable date
logical :: big1
integer :: i, iy, im, id, js
real(wp) :: duts, u1, u2, d1, dats1, d2, fd, dats2, ddats, &
us1, us2, du
! UT1-UTC in seconds.
duts = dut1
! Put the two parts of the UT1 into big-first order.
big1 = abs(ut11) >= abs(ut12)
if ( big1 ) then
u1 = ut11
u2 = ut12
else
u1 = ut12
u2 = ut11
end if
! See if the UT1 can possibly be in a leap-second day.
d1 = u1
dats1 = 0.0_wp
do i=-1,3
d2 = u2 + real(i,wp)
call JD2CAL ( d1, d2, iy, im, id, fd, js )
if ( js/=0 ) then
j = js
return
end if
call DAT ( iy, im, id, 0.0_wp, dats2, js )
if ( js<0 ) then
j = js
return
end if
if ( i==-1 ) dats1 = dats2
ddats = dats2 - dats1
if ( abs(ddats)>=0.5_wp ) then
! Yes, leap second nearby: ensure UT1-UTC is "before" value.
if ( ddats*duts>=0.0_wp ) duts = duts-ddats
! UT1 for the start of the UTC day that ends in a leap.
call CAL2JD ( iy, im, id, d1, d2, js )
us1 = d1
us2 = d2 - 1.0_wp + duts/d2s
! Is the UT1 after this point?
du = u1 - us1
du = du + ( u2 - us2 )
if ( du>0.0_wp ) then
! Yes: fraction of the current UTC day that has elapsed.
fd = du * d2s / ( d2s + ddats )
! Ramp UT1-UTC to bring about SOFA's JD(UTC) convention.
duts = duts + ddats*min(fd,1.0_wp)
end if
! Break.
exit
end if
dats1 = dats2
end do
! Subtract the (possibly adjusted) UT1-UTC from UT1 to give UTC.
u2 = u2 - duts/d2s
! Result, safeguarding precision.
if ( big1 ) then
utc1 = u1
utc2 = u2
else
utc1 = u2
utc2 = u1
end if
! Return the status.
j = js
end subroutine UT1UTC