C2TXY Subroutine

  1. astro_module.f90
  2. astro_module
  3. C2TXY

public subroutine C2TXY(tta, ttb, uta, utb, x, y, xp, yp, rc2t)

Form the celestial to terrestrial matrix given the date, the UT1, the CIP coordinates and the polar motion. IAU 2000.

Status: support routine.

Notes

  1. The TT and UT1 dates TTA+TTB and UTA+UTB are Julian Dates, apportioned in any convenient way between the arguments UTA and UTB. For example, JD(UT1)=2450123.7 could be expressed in any of these ways, among others:

         UTA            UTB

 2450123.7D0        0D0        (JD method)
  2451545D0      -1421.3D0     (J2000 method)
 2400000.5D0     50123.2D0     (MJD method)
 2450123.5D0       0.2D0       (date & time method)

    The JD method is the most natural and convenient to use in cases where the loss of several decimal digits of resolution is acceptable. The J2000 and MJD methods are good compromises between resolution and convenience. In the case of UTA,UTB, the date & time method is best matched to the Earth rotation angle algorithm used: maximum accuracy (or, at least, minimum noise) is delivered when the UTA argument is for 0hrs UT1 on the day in question and the UTB argument lies in the range 0 to 1, or vice versa.

  2. The Celestial Intermediate Pole coordinates are the x,y components of the unit vector in the Geocentric Celestial Reference System.

  3. XP and YP are the coordinates (in radians) of the Celestial Intermediate Pole with respect to the International Terrestrial Reference System (see IERS Conventions 2003), measured along the meridians to 0 and 90 deg west respectively.

  4. The matrix RC2T transforms from celestial to terrestrial coordinates:

    [TRS]  =  RPOM * R_3(ERA) * RC2I * [CRS]

       =  RC2T * [CRS]

    where [CRS] is a vector in the Geocentric Celestial Reference System and [TRS] is a vector in the International Terrestrial Reference System (see IERS Conventions 2003), ERA is the Earth Rotation Angle and RPOM is the polar motion matrix.

  5. Although its name does not include "00", this routine is in fact specific to the IAU 2000 models.

Reference:

  • McCarthy, D. D., Petit, G. (eds.), IERS Conventions (2003), IERS Technical Note No. 32, BKG (2004)

History

  • IAU SOFA revision: 2009 April 1

Arguments

TypeIntentOptionalAttributesName
real(kind=wp), intent(in) :: tta

TT as a 2-part Julian Date (Note 1)
real(kind=wp), intent(in) :: ttb

TT as a 2-part Julian Date (Note 1)
real(kind=wp), intent(in) :: uta

UT1 as a 2-part Julian Date (Note 1)
real(kind=wp), intent(in) :: utb

UT1 as a 2-part Julian Date (Note 1)
real(kind=wp), intent(in) :: x

Celestial Intermediate Pole (Note 2)
real(kind=wp), intent(in) :: y

Celestial Intermediate Pole (Note 2)
real(kind=wp), intent(in) :: xp

coordinates of the pole (radians, Note 3)
real(kind=wp), intent(in) :: yp

coordinates of the pole (radians, Note 3)
real(kind=wp), intent(out), dimension(3,3):: rc2t

celestial-to-terrestrial matrix (Note 4)

Calls

proc~~c2txy~~CallsGraph proc~c2txy C2TXY proc~c2ixy C2IXY proc~c2txy->proc~c2ixy proc~era00 ERA00 proc~c2txy->proc~era00 proc~sp00 SP00 proc~c2txy->proc~sp00 proc~pom00 POM00 proc~c2txy->proc~pom00 proc~c2tcio C2TCIO proc~c2txy->proc~c2tcio proc~s00 S00 proc~c2ixy->proc~s00 proc~c2ixys C2IXYS proc~c2ixy->proc~c2ixys proc~anp ANP proc~era00->proc~anp proc~rx RX proc~pom00->proc~rx proc~ry RY proc~pom00->proc~ry proc~ir IR proc~pom00->proc~ir proc~rz RZ proc~pom00->proc~rz proc~c2tcio->proc~rz proc~rxr RXR proc~c2tcio->proc~rxr proc~faom03 FAOM03 proc~s00->proc~faom03 proc~falp03 FALP03 proc~s00->proc~falp03 proc~fae03 FAE03 proc~s00->proc~fae03 proc~fal03 FAL03 proc~s00->proc~fal03 proc~faf03 FAF03 proc~s00->proc~faf03 proc~fad03 FAD03 proc~s00->proc~fad03 proc~fave03 FAVE03 proc~s00->proc~fave03 proc~fapa03 FAPA03 proc~s00->proc~fapa03 proc~c2ixys->proc~ry proc~c2ixys->proc~ir proc~c2ixys->proc~rz

Contents

Source Code

C2TXY

Source Code

    subroutine C2TXY ( tta, ttb, uta, utb, x, y, xp, yp, rc2t )

    implicit none

    real(wp),intent(in) :: tta !! TT as a 2-part Julian Date (Note 1)
    real(wp),intent(in) :: ttb !! TT as a 2-part Julian Date (Note 1)
    real(wp),intent(in) :: uta !! UT1 as a 2-part Julian Date (Note 1)
    real(wp),intent(in) :: utb !! UT1 as a 2-part Julian Date (Note 1)
    real(wp),intent(in) :: x !! Celestial Intermediate Pole (Note 2)
    real(wp),intent(in) :: y !! Celestial Intermediate Pole (Note 2)
    real(wp),intent(in) :: xp !! coordinates of the pole (radians, Note 3)
    real(wp),intent(in) :: yp !! coordinates of the pole (radians, Note 3)
    real(wp),dimension(3,3),intent(out) :: rc2t !! celestial-to-terrestrial matrix (Note 4)

    real(wp) :: rc2i(3,3), era, sp, rpom(3,3)

    !  Form the celestial-to-intermediate matrix for this TT.
    call C2IXY ( tta, ttb, x, y, rc2i )

    !  Predict the Earth rotation angle for this UT1.
    era = ERA00 ( uta, utb )

    !  Estimate s'.
    sp = SP00 ( tta, ttb )

    !  Form the polar motion matrix.
    call POM00 ( xp, yp, sp, rpom )

    !  Combine to form the celestial-to-terrestrial matrix.
    call C2TCIO ( rc2i, era, rpom, rc2t )

    end subroutine C2TXY